#include "textures.inc"

global_settings { assumed_gamma 1.5 }

sky_sphere { pigment { rgb 0.75 } }

plane { <0, 1, 0>, 0  pigment { rgb 0.18 }
   normal { Tiles_Ptrn()
      slope_map {
         [ 0 <0, 0> ]
         [ 0.05 <0.75, 0> ]
      }
      rotate x*90
   }
   finish {  Phong_Glossy }
   translate y*(-1)
}

union { box { // Pictureframe
      <-0.5, -0.5, -0.05>, <0.5, 0.5, 0.05>
      pigment { rgb <0.309804, 0.192157, 0.156863> }
      normal { boxed
         slope_map { //Definition of the frame-profile
            [ 0 <0, 0> ]
            [ 0.05 <0.5, 0> ]
            [ 0.1 <1, 0> ]
            [ 0.15 <0.75, 0> ]
            [ 0.2 <0.5, 0>  ]
         }
         scale <0.5, 0.5, 1>
      }
      scale <2, 2, 1>
   }

   box { // Picture shown in the pictureframe
      <-0.5, -0.5, -0.001>, <0.5, 0.5, 0.001>
      pigment {
        image_map {
            png  "mypicture.png"
            map_type 0
         }
         translate <0.5, 0.5, 0>
      }
      finish { Phong_Glossy }
      scale <1.705, 1.705, 1>
      translate z*(-0.04901)
   }
   rotate x*10
}

light_source { <4, 3, -5>, 1
   spotlight radius 7 falloff 32 tightness 0
   point_at 0
   area_light <6, 0, 0>, <0, 6, 0>, 9, 9
   adaptive 2 circular orient }

light_source {<-4, 3, -5>, 0.5
   shadowless media_interaction off }

camera { location <2, 2, -3> look_at 0 }

Post a reply to this message

Attachments:
Download 'frames.png' (175 KB)

Preview of image 'frames.png'