|
 |
This is the basic laser test scene file referred to in p.g message
http://news.povray.org/web.47af1f65c0351d35b05f96f70%40news.povray.org
#version 3.61;
#declare Use_Photons = yes;
#declare Load_Photons = no;
#declare Photon_File = "laser_test.ph";
#include "colors.inc"
global_settings {
assumed_gamma 1.0
max_trace_level 7
#if(Use_Photons)
photons {
spacing 0.05
media 200
//max_trace_level 10
//radius ,,10,1
#if(Load_Photons & file_exists(Photon_File))
load_file Photon_File
#else
save_file Photon_File
#end
}
#end
}
camera {
location <0, 0, -25>
up y
right x * image_width/image_height
look_at x * -9
}
light_source {
x * 30, Red * 10
cylinder
point_at x * 24
radius 0.1
falloff 0.5
tightness 0.25
photons {
reflection on
refraction on
}
}
box {
<-0.5, -4, -4>, <0, 4, 4>
hollow
pigment { White }
finish {
reflection { 1 }
}
photons {
target
reflection on
refraction on
}
rotate z * 45
translate x * -9
}
box {
<-0.5, -8, -8>, <0.5, 8, 8>
pigment { White }
rotate z * 90
translate <-9, 9, 0>
}
#declare Scatter_M =
material {
texture {
pigment { rgbt 1 }
finish {
ambient 0
diffuse 0
}
}
interior {
media {
method 3
intervals 1
samples 70, 1000
scattering {
1, rgb 0.1
extinction 0.00001
}
}
}
}
sphere {
0, 40
hollow
material { Scatter_M }
photons {
pass_through
}
}
Post a reply to this message
|
|
