So without the meshes, of course, here's the settings I've been using recently.
Lots of fine adjustments required and very scale-dependent.  Shadowing and
render times are a problem also.  Hmm.

 - Ricky


#declare al_on=0;
camera{
    perspective
    location <2.4,1.6,-4.5>
    up y*4/3
    right x
    angle 50
    look_at <0,.15,0>
}

light_source{<-5,3,1> rgb 1.4
#if(al_on)
 area_light 1.5*x,1.5*z, al_on,al_on
 circular
 orient
 jitter
 adaptive 2
#end
 media_interaction on
 media_attenuation on
}

//BACKDROP:
sky_sphere{
    pigment{
        gradient y
        color_map{
            [0.0 rgb 0.0]
            [0.09 rgb 0.0]
            [0.21 rgb <.45,.4,.35>]
            [0.325 rgb 0.95]
         [0.365 rgb 1.0]
            [1.0 rgb 0]
        }
    turbulence 0.15
        scale <1,2.1*2,1>
        translate -y*1.05*1.21
        rotate y*10
    }
    pigment{
     granite
     color_map{
      [0 rgbf <0,0,.4,0.9>]
      [1 rgbf <1,1,1.2,0.9>]
     }
     turbulence 0.7
    }
}

//CROSS:
object{
  merge{
   #declare rad=0.08;
     cylinder{-z,z,rad}
     cylinder{-x,x,rad}
     sphere{-z,rad}
     sphere{z,rad}
     sphere{-x,rad}
     sphere{x,rad}
     translate -y*(1.0-rad)
  }
    material{
        texture{
        pigment{rgbt <1.0,0.87,0.75,0>*1.2 + <0,0,0,.95>*1}
         finish{
             diffuse 8.0
             ambient 0
             specular 0.05
             roughness 0.03
         }
      normal{
       crackle
       bump_size 0.4
       scale 0.025
      }
     }
     interior{
      ior 2.0
      media{
       #declare col = <.89,.75,.5>;
       #declare sc = 200;
        scattering {5, rgb (1-col)*sc extinction 0.75 eccentricity -.1}
        emission <1,.5,.3>*2.4
        absorption (<1,3,7>*4.2)
        intervals 1
        samples 500
        method 3
      }
    }
    }
   hollow
}

//TORI:
object{
 #declare rad = 0.04;
   merge{
     torus{.5,rad rotate x*90}
     torus{.5,rad rotate x*90+y*90 translate -y*rad*2}
     torus{.5,rad translate -rad*2*(x+z)}
    }
    material{
        texture{
         pigment{rgbt <1,1,1,1>}
         finish{
             diffuse 1.0
             ambient 0
             specular 0.5
             roughness 0.01
         }
     }
     interior{
      ior 2.0
      media{
       #declare col = <.78,.74,.7>;
       #declare sc = 150;
       #declare ex = 0.8;
        scattering {5, rgb ((1-col)+<0,0,0>)*sc extinction ex eccentricity 0}
        emission <3,3,3>
        absorption (<2,2.3,2.6>)
        intervals 1
        samples 100
        method 3
      }
    }
    }
   hollow
   translate y*1.2
   scale 1.3
   translate -y*1.2
}
//BLOCK:
#declare sc=1.2;
superellipsoid{0.05
 scale 1.2
 translate -y*(2.22)
 material{
        texture{
          pigment{rgbt <0,0,0,1> + <.7,0.1,0.0,0>*1}
         finish{
             diffuse 1.0
             ambient 0
             specular 0.5
             roughness 0.01
             reflection 0.05
         }
     }
     interior{
      ior 2
      media{
       #declare col = <.8,.6,.5>;
       #declare sc = 20;
       #declare ex = 1.3;
        scattering {5, rgb ((1-col)+<0,0,0>)*sc extinction ex eccentricity 0}
        emission <.3,0,0>
        absorption <0,15,50>*5
        intervals 1
        samples 300
        method 3
      }
    }
    }
   hollow
}

Post a reply to this message