|
 |
From p.b.i (remember to un-break lines when copy/pasting):
//START
global_settings {
charset utf8
ambient_light 1
adc_bailout 0.001
max_trace_level 10
}
//
// ******* I N C L U D E S *******
//
#include "colors.inc"
#include "textures.inc"
//
// ******* C A M E R A *******
//
#declare LO=<400,2000,-3000>;
#declare LA=<0,0,-500>;
camera{
up y
right x*image_width/image_height
angle 60
location LO
look_at LA
}
//
// ******* L I G H T S *******
//
#declare LB=box{<-800,-1200,0>,<800,1200,1> texture{pigment{rgb 1}
finish{diffuse 0 ambient 40}}}
light_source{
0,
rgb 2
area_light
<1600,2400,0> <0,0,8>
4, 4
adaptive 0
jitter
looks_like{LB}
fade_power 2
fade_distance 6000
translate <-200,4200,4000>
}
light_source{
0,
rgb 2
area_light
<1600,2400,0> <0,0,8>
4, 4
adaptive 0
jitter
looks_like{LB}
fade_power 2
fade_distance 6000
translate <-3200,4200,4000>
}
//
// ******* T E X T U R E S *******
//
#default{finish{ambient 0 diffuse 0.5}}
#declare BM="wood-33_b.jpg";//bump map
#declare DM="wood-33_d.jpg";//diffuse map
#declare SM="wood-33_r.jpg";//specular/reflective map
#declare Scl=<6000,15,6000>; //tile size (the arroway site has this for
the samples)
#declare Spec=0.15; //specular/reflective strength (again you
can use arroway's info)
#declare DifMn=0.0;//Min diffuse value
#declare DifMx=1.0;//Max diffuse value
#macro SMap(Ref,Dif)//Reflectivity mapping
pigment {image_map { jpeg DM map_type 0 interpolate 2 once }}
finish {
ambient 0 diffuse Dif
conserve_energy
reflection{0 Ref fresnel on metallic 0}
}
// normal{bump_map {jpeg BM map_type 0 interpolate 0 once}}//uncomment for
bumpmap
#end
#macro DMap(Ref,Dif)//Diffuse mapping
image_pattern { jpeg SM map_type 0 interpolate 2 once }
texture_map{
[0 SMap(0,Dif)]
[1 SMap(Ref,Dif)]
}
#end
#declare FloorMat=
material{
texture{
image_pattern { jpeg DM map_type 0 interpolate 2 once}
texture_map{
[0 DMap(Spec,DifMn)]
[1 DMap(Spec,DifMx)]
}
rotate x*90
}
interior{ior 1.36}//using fresnel reflection, vary ior accordingly
}
//
// ******* O B J E C T S *******
//
#declare Tile=height_field{jpeg BM material{FloorMat}}//Using heightfield
#declare Tile2=box{0,<1,-1,1> material{FloorMat}} //Using bumpmap
//
// ******* S C E N E *******
//
#declare Siz=6;//creating a 6x6 tiling of the tile
union{
#declare i=1;#while (i<Siz)
#declare j=1;#while (j<Siz)
object{Tile translate <-i,0,-j>}
#declare j=j+1;#end
#declare i=i+1;#end
translate <Siz/2,0,Siz/2>
scale Scl
rotate y*90
}
//END
Post a reply to this message
|
|
|
|
"JSR" <jsr### [at] gmail com> wrote:
> "Trevor G Quayle" <Tin### [at] hotmailcom> wrote:
>
> > #declare Spec=0.15; //specular/reflective strength
>
> Thanks for your help,
>
> Where did you found the information about "specular strength" inside arroway
> webside? I can't find it...
>
> > interior{ior 1.36}//using fresnel reflection, vary ior accordingly
>
> Why do you use "ior"? ior is only for transparent objects, or not?
>
> Joel.
Actually now that I look, Arroway doesn't have the specular strength for the
particular wood volume. Look at samples of some of the other volumes for
examples.
Ior is also used for the fresnel variable reflection model and is supposed
to give a better representation than the regular variable reflection model.
I know it seems odd to give ior values to solid objects, but I've gotten
used to it. For relative reflectivities, you can refer to actual
substances and their ior values, ie, assume the floor has a coat of varnish
similar to acrylic: ior~1.49.
-tgq
Post a reply to this message
|
|
