In addition to playing with the random seed, try using different (small!)
values for j.

#macro Arabesque2( Param )
  #declare Sd = seed(Param);
  #declare Rv = <rand(Sd),rand(Sd),rand(Sd)>*500;
  #local C=pigment{crackle solid 
    color_map{
      [1/12 red 1]
      [1/12 red 1 green 1][3/12 red 1 green 1]
      [3/12 green 1][5/12 green 1]
      [5/12 green 1 blue 1][7/12 green 1 blue 1]
      [7/12 blue 1][9/12 blue 1]
      [9/12 blue 1 red 1][11/12 blue 1 red 1]
      [11/12 red 1]
    }
  } 
  #local G=pigment{crackle
    pigment_map{[.05 rgb 0][.05 C]}
    scale .1
    translate Rv
    warp {repeat 2*z flip z}
  }      
        
  radial 
  pigment_map{
    #local i=0;  
    #local j=8;
    #while(i<j)
      [i/j G rotate(180/j+360/j*i)*y]
      [(i+1)/j G rotate(180/j+360/j*i)*y]
      #local i=i+1;
    #end
  }

  warp{repeat .5*x flip x}
  warp{repeat .5*z flip z}
#end


plane {y 0 pigment {Arabesque2(8192)} finish {ambient 1}}
camera {location 3*y sky z look_at 0}


-- 
Ron Parker   http://www2.fwi.com/~parkerr/traces.html
My opinions.  Mine.  Not anyone else's.

Post a reply to this message

Ron Parker <ron### [at] povrayorg> wrote:

> In addition to playing with the random seed, try using different (small!)
> values for j.

Yep.  When you posted the 12 sided thing, I saw exactly what you were doing,
and did this myself.  Kinda fun to try different shapes.  Larger than about
30 and things start to blend out, though.

Geoff

Post a reply to this message

On 19 Apr 2001 13:56:54 -0400, Geoff Wedig wrote:
>Ron Parker <ron### [at] povrayorg> wrote:
>
>> In addition to playing with the random seed, try using different (small!)
>> values for j.
>
>Yep.  When you posted the 12 sided thing, I saw exactly what you were doing,
>and did this myself.  Kinda fun to try different shapes.  Larger than about
>30 and things start to blend out, though.

This one's different, though.  This one has rectangular tiling, where the
other one was hexagonal.  The results are similar, though.

-- 
Ron Parker   http://www2.fwi.com/~parkerr/traces.html
My opinions.  Mine.  Not anyone else's.

Post a reply to this message

Ron Parker <ron### [at] povrayorg> wrote:

> On 19 Apr 2001 13:56:54 -0400, Geoff Wedig wrote:
>>Ron Parker <ron### [at] povrayorg> wrote:
>>
>>> In addition to playing with the random seed, try using different (small!)
>>> values for j.
>>
>>Yep.  When you posted the 12 sided thing, I saw exactly what you were doing,
>>and did this myself.  Kinda fun to try different shapes.  Larger than about
>>30 and things start to blend out, though.

> This one's different, though.  This one has rectangular tiling, where the
> other one was hexagonal.  The results are similar, though.

Ah, I see.  Yeah, neat.  Now do octagons and squares combined. ;)

Geoff

Post a reply to this message

On 19 Apr 2001 14:18:41 -0400, Geoff Wedig wrote:
>Ron Parker <ron### [at] povrayorg> wrote:
>
>> On 19 Apr 2001 13:56:54 -0400, Geoff Wedig wrote:
>>>Ron Parker <ron### [at] povrayorg> wrote:
>>>
>>>> In addition to playing with the random seed, try using different (small!)
>>>> values for j.
>>>
>>>Yep.  When you posted the 12 sided thing, I saw exactly what you were doing,
>>>and did this myself.  Kinda fun to try different shapes.  Larger than about
>>>30 and things start to blend out, though.
>
>> This one's different, though.  This one has rectangular tiling, where the
>> other one was hexagonal.  The results are similar, though.
>
>Ah, I see.  Yeah, neat.  Now do octagons and squares combined. ;)

That was what I tried to do with this, but I messed some things up.  Use
the definitions from before for Sd, Rv, and C and try this:

  #local G=pigment{crackle
    pigment_map{[.05 rgb 0][.05 C]}
    scale .2
    translate Rv
    warp {repeat 2*z flip z}
  } 
  #local H=pigment {
    gradient x
    pigment_map {
      [.5 G][.5 G translate -.5*x scale <1-sqrt(2),1,1> translate .5*x]
    }
  }
        
  radial 
  #local i=0;  
  #local j=8;
  pigment_map{
    #while(i<j)
      [i/j H rotate(180/j+360/j*i)*y]
      [(i+1)/j H rotate(180/j+360/j*i)*y]
      #local i=i+1;
    #end
  }

  rotate 180/j*y

  warp{repeat .5*x flip x}
  warp{repeat .5*z flip z}


-- 
Ron Parker   http://www2.fwi.com/~parkerr/traces.html
My opinions.  Mine.  Not anyone else's.

Post a reply to this message