 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
A little something I've been messing around with... try different numbers
for the 91671 in the second-to-last line. Requires some flavor of MegaPOV
(though if you don't have MegaPOV you can still play... just delete the
pigment called C and replace the [.05 C] with [.05 rgb 1] )
#macro Arabesque( Param )
#declare Sd = seed(Param);
#declare Rv = <rand(Sd),rand(Sd),rand(Sd)>*500;
#local C=pigment{crackle solid
color_map{
[1/12 red 1]
[1/12 red 1 green 1][3/12 red 1 green 1]
[3/12 green 1][5/12 green 1]
[5/12 green 1 blue 1][7/12 green 1 blue 1]
[7/12 blue 1][9/12 blue 1]
[9/12 blue 1 red 1][11/12 blue 1 red 1]
[11/12 red 1]
}
}
#local G=pigment{crackle
pigment_map{[.05 rgb 0][.05 C]}
scale .2
translate Rv
warp {repeat z flip z}
}
#local B=pigment{
radial
pigment_map{
#local i=0;
#while(i<6)
[i/6 G rotate(30+60*i)*y]
[(i+1)/6 G rotate(30+60*i)*y]
#local i=i+1;
#end
}
}
#local T2=sqrt(3)/2;
radial
pigment_map{
[1/3 B translate<.5,0,-T2>]
[1/3 B translate<-1,0,0>]
[2/3 B translate<-1,0,0>]
[2/3 B translate<.5,0,T2>]
}
translate x
warp{repeat 1.5*x flip x}
warp{repeat .5*sqrt(3)*z flip z}
#end
plane {y 0 pigment {Arabesque(91671)} finish {ambient 1}}
camera {location 5*y sky z look_at 0}
--
Ron Parker http://www2.fwi.com/~parkerr/traces.html
My opinions. Mine. Not anyone else's.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
in <slr### [at] fwi com> Ron Parker wrote:
> A little something I've been messing around with...
Ahhh, I like! It will be disected first thing tomorrw morning.
A very small rotation around x or z gives a nice "fading" effect.
Ingo
--
Photography: http://members.home.nl/ingoogni/
Pov-Ray : http://members.home.nl/seed7/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 18 Apr 2001 17:10:07 -0400, ingo wrote:
>in <slr### [at] fwicom> Ron Parker wrote:
>
>> A little something I've been messing around with...
>
>Ahhh, I like! It will be disected first thing tomorrw morning.
>A very small rotation around x or z gives a nice "fading" effect.
Hey, that's pretty cool. Now I know why I keep posting stuff like this
here; it always seems to grow.
Try replacing this bit:
#while(i<6)
[i/6 G rotate(30+60*i)*y]
[(i+1)/6 G rotate(30+60*i)*y]
#local i=i+1;
#end
with this:
#while(i<12)
[i/12 G rotate(15+30*i)*y]
[(i+1)/12 G rotate(15+30*i)*y]
#local i=i+1;
#end
--
Ron Parker http://www2.fwi.com/~parkerr/traces.html
My opinions. Mine. Not anyone else's.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Ron Parker wrote:
> Hey, that's pretty cool. Now I know why I keep posting stuff like this
> here; it always seems to grow.
I'm not sure I can make it grow but I am sure I can damage it :)
--
Ken Tyler
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Ken wrote:
>
> Ron Parker wrote:
>
> > Hey, that's pretty cool. Now I know why I keep posting stuff like this
> > here; it always seems to grow.
>
> I'm not sure I can make it grow but I am sure I can damage it :)
Ok, I damaged it...
P.S. A little rotation and a bit of turbulence makes a passing chipboard
pigment for the wood crafters in the group.
-----------------------------------
#declare P1=pigment { wood turbulence .05
color_map {
[ 0 rgb<.35,.20,.15>]
[.5 rgb<.50,.35,.23>]
[ 1 rgb<.35,.20,.15>]
}
}
#declare P2=pigment { wood turbulence .05
color_map {
[ 0 rgb<.45,.30,.25>]
[.5 rgb<.60,.45,.33>]
[ 1 rgb<.45,.30,.25>]
}
}
#declare P3=pigment { wood turbulence .05
color_map {
[ 0 rgb<.55,.40,.35>]
[.5 rgb<.70,.55,.43>]
[ 1 rgb<.55,.40,.35>]
}
}
#declare P4=pigment { wood turbulence .05
color_map {
[ 0 rgb<.65,.50,.45>]
[.5 rgb<.80,.65,.53>]
[ 1 rgb<.65,.50,.45>]
}
}
#declare P5=pigment { wood turbulence .05
color_map {
[ 0 rgb<.75,.60,.55>]
[.5 rgb<.90,.75,.63>]
[ 1 rgb<.75,.60,.55>]
}
}
#declare P6=pigment { wood turbulence .05
color_map {
[ 0 rgb<.85,.70,.65>]
[.5 rgb<.90,.85,.73>]
[ 1 rgb<.85,.70,.65>]
}
}
#macro Arabesque( Param )
#declare Sd = seed(Param);
#declare Rv = <rand(Sd),rand(Sd),rand(Sd)>*500;
#local C=pigment{crackle solid
pigment_map{
[1/12 P1 scale .10]
[1/12 P1 scale .10]
[3/12 P2 scale .10]
[3/12 P2 scale .10]
[5/12 P3 scale .10]
[5/12 P3 scale .10]
[7/12 P4 scale .10]
[7/12 P4 scale .10]
[9/12 P5 scale .10]
[9/12 P5 scale .10]
[11/12 P6 scale .10]
[11/12 P6 scale .10]
}
}
#local G=pigment{crackle
pigment_map{[.05 rgb 0][.05 C]}
scale .2
translate Rv
warp {repeat z flip z}
}
#local B=pigment{
radial
pigment_map{
#local i=0;
#while(i<6)
[i/6 G rotate(30+60*i)*y]
[(i+1)/6 G rotate(30+60*i)*y]
#local i=i+1;
#end
}
}
#local T2=sqrt(3)/2;
radial
pigment_map{
[1/3 B translate<.5,0,-T2>]
[1/3 B translate<-1,0,0>]
[2/3 B translate<-1,0,0>]
[2/3 B translate<.5,0,T2>]
}
translate x
warp{repeat 1.5*x flip x}
warp{repeat .5*sqrt(3)*z flip z}
#end
plane {y 0 pigment {Arabesque(91671) turbulence 0 rotate 0} finish {ambient 1}}
camera {location 5*y sky z look_at 0}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
In article <slr### [at] fwicom>, Ron Parker says...
> A little something I've been messing around with... try different numbers
> for the 91671 in the second-to-last line. Requires some flavor of MegaPOV
> (though if you don't have MegaPOV you can still play... just delete the
> pigment called C and replace the [.05 C] with [.05 rgb 1] )
>
It's neat! I don't grasp the code, but why does the pattern widen
towards the left?
--
Regards, Sander
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
For a nice variation, try replacing the plane with this one:
plane
{ y 0 pigment {Arabesque(91671) warp{black_hole 0,3 strength -1}}
finish {ambient 1}}
--
char*i="b[7FK@`3NB6>B:b3O6>:B:b3O6><`3:;8:6f733:>::b?7B>:>^B>C73;S1";
main(_,c,m){for(m=32;c=*i++-49;c&m?puts(""):m)for(_=(
c/4)&7;putchar(m),_--?m:(_=(1<<(c&3))-1,(m^=3)&3););} /*- Warp -*/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Ron Parker <ron### [at] povrayorg> wrote:
> A little something I've been messing around with... try different numbers
> for the 91671 in the second-to-last line. Requires some flavor of MegaPOV
> (though if you don't have MegaPOV you can still play... just delete the
> pigment called C and replace the [.05 C] with [.05 rgb 1] )
Very, very clever. I like it a lot. Looking over the code, I can see how
it's done, but not how you came up with it. Changing from a material map to
a pigment map could easily allow for all kinds of tiling patterns.
Now I want to do an Arabian Nights style image.... ;)
Geoff
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 19 Apr 2001 07:59:14 -0400, Geoff Wedig wrote:
>Very, very clever. I like it a lot. Looking over the code, I can see how
>it's done, but not how you came up with it.
Well, the inspiration came from a paper I ran across, about a third of the
way down this page:
http://www.iro.umontreal.ca/~ostrom/publications/abstracts.html
under the heading "Mathematical Tools for Computer-Generated Ornamental
Patterns."
The actual implementation was ripped off from my hextiles pattern of long
ago, which I'd been working on this week for unspecified reasons. The
combination of the two gave rise to this.
--
Ron Parker http://www2.fwi.com/~parkerr/traces.html
My opinions. Mine. Not anyone else's.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
