Just put together this scene file for some cute Jack-O-Lantern wallpaper.  
I'm running Linux here at work, but at home, I could run POV-Ray 3.1 and 
add media, with light beams shining out of the faces.  

Let me know if you come up with any improvements...

John Pitney

--- begin jack-o-lantern.pov ---
// Jack-O-Lantern scene by John Pitney (pit### [at] uiucedu)
// Visit my web pages (http://www.physics.uiuc.edu/~pitney/) for more!
//

#include "colors.inc"
#include "finish.inc"

global_settings
{
    assumed_gamma 2.2
}

#declare Pumpkin_Outside_Texture =
texture
{
    pigment { color rgb <255, 136, 0>/255 }
    finish { Shiny diffuse 0.9 }
}

#declare Pumpkin_Inside_Texture =
texture
{
    pigment { color rgb <255, 150, 0>/255 }
    finish { ambient 0.3 diffuse 0.5 }
}

#declare Pumpkin =
difference
{
    sphere 
    { 
        0, 0.5 
        texture { Pumpkin_Outside_Texture } 
        normal
        {
            radial
            frequency 16
            scallop_wave
        }
    }
    sphere { 0, 0.4 texture { Pumpkin_Inside_Texture } }
}

#declare Tri_Eye =
prism
{
    linear_sweep
    linear_spline
    0, 2, 4
    0.12 * <0, 1>, 
    0.12 * <-cos(pi/6), -sin(pi/6)>,
    0.12 * < cos(pi/6), -sin(pi/6)>,
    0.12 * <0, 1>
    texture { Pumpkin_Inside_Texture }
}

#declare Mouth_1 =
prism
{
    linear_sweep
    linear_spline
    0, 2, 9
    0.1 * <-3, 1>, 
    0.1 * <-3, -1>,
    0.1 * < 3, -1>,
    0.1 * < 3, 1>,
    0.1 * < 2.2, 1>,
    0.1 * < 2.2, 0>,
    0.1 * <-2.2, 0>,
    0.1 * <-2.2, 1>,
    0.1 * <-3, 1>
    texture { Pumpkin_Inside_Texture }
}

camera
{
    location <0, 1, -200>
    look_at 0
    angle 10
}

light_source { <300, 200, -700> color rgb <1,1,1> }

#declare Stem_Texture =
texture 
{
    pigment { color rgb <0.2, 0.7, 0.2> }
    normal { radial frequency 50 ramp_wave }
}

#declare Jack_1 =
union
{
    difference
    {
        object { Pumpkin }
        object { Tri_Eye rotate -90*x scale <1.3,1,1>  }
        object { Tri_Eye rotate -90*x scale <1,1.3,1> rotate 20*y rotate 30*x}
        object { Tri_Eye rotate -90*x scale <1,1.3,1> rotate -20*y rotate 30*x}
        object { Mouth_1 rotate -110*x scale <1,1,1> }
    }
// Turn on the lights, but take a hit in rendering speed!
//    light_source { 0 color rgb <1,1,0> }
    cylinder 
    { 
        0, 0.2*y, 0.04 
        texture { Stem_Texture } 
        rotate -10*z
        translate 0.5*y
    }
    scale 0.67*<6,5,6>
}

#declare R = seed(0)
#declare i=0
#declare j=0
#while (i<6)
    #while (j<5)
        object 
        { 
            Jack_1 
            rotate (0.5 - rand(R))*50*y
            rotate (0.5 - rand(R))*50*x
            translate 5*(i-2.5)*x 
            translate 5*(j-2)*y 
        }
        #declare j=j+1
    #end
    #declare j=0
    #declare i=i+1
#end

#declare Floor_Texture =
texture {
    pigment 
    {
        bozo
        frequency 3
        color_map
        {
            [0 color Red]
            [0.33 color Blue]
            [0.66 color Yellow]
            [1.0 color Red]
        }
    }
    finish
    {
        ambient 1
        diffuse 0
    }
    scale 10
}

plane { -z, -5 texture { Floor_Texture } }

--- end ---

Post a reply to this message

I put up a rendered jpg of this on my web page.  It's at 

  http://www.physics.uiuc.edu/~pitney/raytr.html

John

Post a reply to this message

Very catchy.  I zapped the "Shiny" keyword but otherwise
like it the way it was shipped.

John Pitney wrote in message ...
>Just put together this scene file for some cute Jack-O-Lantern wallpaper.

Post a reply to this message

On Fri, 30 Oct 1998 19:16:37 -0500, Spock <spo### [at] entrustcom> wrote:
>Very catchy.  I zapped the "Shiny" keyword but otherwise
>like it the way it was shipped.

Yep, I like it better non-Shiny, too.  Thanks for checking it out!

John

Post a reply to this message