I hope this is the right place to post this if not no offence is intended.

I model a lot of outdoor stuff and use the excellent SunPos macro to 
calculate the position of the sun. I would like to animate this by 
altering the sun's position, this of course I can do easily, however the 
sky_sphere colour won't match the sun position( blue sky at sunset etc.)

Using the old adage of try and work it out yourself, I have written a 
little macro that seems to solve this. Before I get too involved with it, 
altering light colour and creating a much better sun, I would really like 
to get some comments as to my script and the colours used.

All comments are appreciated.

--
Phil

-- 
Using M2, Opera's revolutionary e-mail client: http://www.opera.com/m2/


//code start
#version 3.5;
global_settings{assumed_gamma 1}

#include "sunpos.inc"

//just to initiate SunPos
#declare lightposition = SunPos(2003, 10, 2, 06, 00, 0, 51.4667, 0.00);

//RERUN SolarPostion but bring in by a factor of 100 to see Sphere
#declare newSolarPosition=vrotate(<0,0,10000000>,<-Al,Az,0>);

#macro SunColourMacro()
#switch (newSolarPosition.y)

#range(-3000000, -2500000)
#declare Skycolour =
colour_map{
[0 rgb <1,0,0>]
[0.15 rgb <1,0.5,0.1>]
[0.2 rgb <172,163,146>/255]
[0.4 rgb <0,0,0>]};
#break

#range(-2500000, -1500000)
#declare Skycolour =
colour_map{
[0 rgb <1,0,0>]
[0.3 rgb <1,0.5,0.1>]
[0.4 rgb <172,163,146>/255]
[0.6 rgb <0,0,0>]};
#break

#range(-1500000,-1000000)
#declare Skycolour =
colour_map{
[0 rgb <1,0,0>]
[0.45 rgb <1,0.5,0.1>]
[0.6 rgb <172,163,146>/255]
[0.8 rgb <0,0,0>]};
#break

#range(-1000000,1000000)
#declare Skycolour =
colour_map{
[0 rgb <1,0,0>]
[0.6 rgb <1,0.5,0.1>]
[0.8 rgb <0,0,1>]
[1 rgb <0,0,0>]};
#break

#range(1000000,3000000)
#declare Skycolour =
colour_map{
[0 rgb <1,0,0>]
[0.6 rgb <1,0.5,0.1>]
[0.8 rgb <0,0,1>]
[1 rgb <0,0,0>]};
#break

#range(3000000,4500000)
#declare Skycolour =
colour_map{
[0 rgb <1,0,0>]
[0.4 rgb <1,0.5,0.1>]
[0.5 rgb <172,163,146>/255]
[1 rgb <0,0,1>]
[1 rgb <0,0,0>]};
#break

#range(4500000,9000000)
#declare Skycolour =
colour_map{
[0 rgb <1,0,0>]
[0.4 rgb <1,0.5,0.1>]
[0.4 rgb <172,163,146>/255]
[1 rgb <0,0,1>]
[1 rgb <0,0,0>]};
#break
#end
#end


//sky
#declare MySkySphere=
sky_sphere{
SunColourMacro()
pigment{
gradient y
colour_map{
Skycolour}
scale 2 translate -1}};
sky_sphere{MySkySphere}

//clouds
plane{<0,1,0>,1 texture{
pigment{bozo warp{turbulence 0.4 octaves 6  omega 0.7 lambda 2}
colour_map{
[0.0 rgb <0.95, 0.95, 0.95>]
[0.1 rgb <0.85, 0.85, 0.85>]
[0.5 rgbt <1, 1, 1, 1> ]
[1.0 rgbt <1, 1, 1, 1> ]}
rotate<10,20,0>
scale <0.3, 0.4, 0.3>*3 }
finish {ambient 1 diffuse 0}}
scale 1000}

#declare Suncolour = rgb<247/255,255/255,58/255>;

//adjust sphere to match apparent size
#declare MySphere= sphere{<0,0,0> 250000 pigment{colour Suncolour} 
finish{ambient 1 diffuse 0}}

//Use rejigged SolarPosition
light_source {newSolarPosition rgb 1 looks_like {MySphere}}

camera{
location <0,10,-150>
look_at <0,10,10>
}


plane{y,0 texture {pigment{rgb <0.6,0.8,0.196078>*0.9} normal {bumps 0.5 
scale 0.01} finish {ambient 0.45 diffuse 0.55}}}
//code end

Post a reply to this message

"Phil Cook" <phi### [at] deckingdealscouk> wrote in message
news:oprwfbhgleeybzwd@news.povray.org...
>
> I model a lot of outdoor stuff and use the excellent SunPos macro to
> calculate the position of the sun. I would like to animate this by
> altering the sun's position, this of course I can do easily, however the
> sky_sphere colour won't match the sun position( blue sky at sunset etc.)
>
> Using the old adage of try and work it out yourself, I have written a
> little macro that seems to solve this. Before I get too involved with it,
> altering light colour and creating a much better sun, I would really like
> to get some comments as to my script and the colours used.

Looks like a great idea. If you add one more color_map following after the
last #break, and add #else before the color_map, it'll be valid for all
times not within the ranges given. That way you get the night sky at 3 a.m.
too, which is one of the times I tried.

Sky coloring is always difficult. Right away I thought the purple didn't
seem correct for the sunrise/sunset. Although, I think if a layer of thin
clouds or water droplets were present in the air this is the color that
might be seen. I'm just guessing, but perhaps a result of the very wide area
it covers it looks out of place. The bright blue above it looks wrong to me
too, too blue without other colors mixed in to offset it. Most times I think
of the real sky colors as muted in some sense, except perhaps the Sun itself
and intensely lit clouds. A bit of imaginative perception can enhance the
coloring. I see a lot of sunrises from my location on a NE facing hillside,
not as many sunsets, and yet I don't believe I could accurately reproduce it
from memory in POV-Ray.

Overall I'd say you have too much red mixed into the blue in those color
maps.

Anyway, I'd suggest the orange range be thinner, closer to the horizon.
Here's my attempt at adjusting all the sky colors. Use them if you wish to,
change them some more, whatever. It's only my interpretation of sky
coloring.

#declare Skycolour = // sunrise
colour_map{
[0 rgb <1,0.1,0.1>]
[0.5125 rgb <1.5,0.2,0.1>]
[0.55 rgb <1,0.8,0.2>]
[0.575 rgb <1,0.6,0.3>]
[0.6 rgb <0.9,0.6,0.6>]
[0.65 rgb <0.25,0.35,0.75>]
[0.725 rgb <0.1,0.2,0.8>]
[1 rgb <0.1,0.1,0.3>]}

#declare Skycolour = // sunset
colour_map{
[0 rgb <1,0.1,0.1>]
[0.5125 rgb <0.9,0.2,0.2>]
[0.55 rgb <0.95,0.75,0.4>]
[0.575 rgb <1,0.6,0.3>]
[0.6 rgb <0.8,0.6,0.5>]
[0.65 rgb <0.2,0.5,0.7>]
[0.725 rgb <0.1,0.4,0.8>]
[1 rgb <0.1,0.2,0.3>]}


#declare Skycolour = // early morning/late afternoon
colour_map{
[0 rgb <1,0,0>]
[0.5 rgb <0.65,0.6,0.9>]
[0.525 rgb <0.35,0.6,0.9>]
[0.6 rgb <0.3,0.55,0.8>]
[0.8 rgb <0.1,0.3,0.9>]
[1 rgb <0.2,0.3,0.7>]}

#declare Skycolour = // midmorning/afternoon
colour_map{
[0 rgb <1,0,0>]
[0.5 rgb <0.6,0.7,0.8>]
[0.525 rgb <0.35,0.55,0.9>]
[0.575 rgb <0.25,0.45,0.8>]
[0.7 rgb <0.2,0.3,1>]
[1 rgb <0.1,0.4,0.7>]}

#declare Skycolour = // noon
colour_map{
[0 rgb <1,0,0>]
[0.5 rgb <0.75,0.75,0.7>]
[0.55 rgb <0.3,0.7,0.9>]
[0.65 rgb <0.15,0.6,0.8>]
[0.8 rgb <0.2,0.4,0.9>]
[1 rgb <0.2,0.3,0.7>]}

#declare Skycolour = // night
colour_map{
[0 rgb <1,0,0>]
[0.5 rgb <0.05,0.075,0.075>]
[0.525 rgb <0.025,0.025,0.1>]
[1 rgb <0,0,0>]}

Oh, and semicolons aren't required for those declares.  :-)  I realize all
you asked for was an opinion but I love to try sky colors myself.

Bob H.

Post a reply to this message

On Thu, 2 Oct 2003 15:12:45 -0500, Hughes, B. <omn### [at] charternet> 
wrote:

>
> "Phil Cook" <phi### [at] deckingdealscouk> wrote in message
> news:oprwfbhgleeybzwd@news.povray.org...
>>
>> I model a lot of outdoor stuff and use the excellent SunPos macro to
>> calculate the position of the sun. I would like to animate this by
>> altering the sun's position, this of course I can do easily, however the
>> sky_sphere colour won't match the sun position( blue sky at sunset etc.)
>>
>> Using the old adage of try and work it out yourself, I have written a
>> little macro that seems to solve this. Before I get too involved with 
>> it,
>> altering light colour and creating a much better sun, I would really 
>> like
>> to get some comments as to my script and the colours used.
>
> Looks like a great idea. If you add one more color_map following after 
> the
> last #break, and add #else before the color_map, it'll be valid for all
> times not within the ranges given. That way you get the night sky at 3 
> a.m.
> too, which is one of the times I tried.

Hmmm yes I forgot to test it during winter, the values only ran down to -3 
million. Writes out 100 times "I must remember to trap errors"

>
> Sky coloring is always difficult. Right away I thought the purple didn't
> seem correct for the sunrise/sunset. Although, I think if a layer of thin
> clouds or water droplets were present in the air this is the color that
> might be seen. I'm just guessing, but perhaps a result of the very wide 
> area
> it covers it looks out of place. The bright blue above it looks wrong to 
> me
> too, too blue without other colors mixed in to offset it. Most times I 
> think
> of the real sky colors as muted in some sense, except perhaps the Sun 
> itself
> and intensely lit clouds. A bit of imaginative perception can enhance the
> coloring. I see a lot of sunrises from my location on a NE facing 
> hillside,
> not as many sunsets, and yet I don't believe I could accurately 
> reproduce it
> from memory in POV-Ray.
>
> Overall I'd say you have too much red mixed into the blue in those color
> maps.

Thanks, mixing colours is difficult. If I recall my physics correctly the 
blue is due to atmospheric scattering when passing through all the atmos' 
then as the sun sets the blue diminishes as green is added to make cyan 
than the blue goes and the green is added to red to make yellow and then 
finally the green goes to leave red. Taking the cyan out of the sunsets 
does produce that magenta colour, but leaving it in seems to produce 
either banding or unrealistic colours.

>
> Anyway, I'd suggest the orange range be thinner, closer to the horizon.
> Here's my attempt at adjusting all the sky colors. Use them if you wish 
> to,
> change them some more, whatever. It's only my interpretation of sky
> coloring.
>
> #declare Skycolour = // sunrise
> colour_map{
> [0 rgb <1,0.1,0.1>]
> [0.5125 rgb <1.5,0.2,0.1>]
> [0.55 rgb <1,0.8,0.2>]
> [0.575 rgb <1,0.6,0.3>]
> [0.6 rgb <0.9,0.6,0.6>]
> [0.65 rgb <0.25,0.35,0.75>]
> [0.725 rgb <0.1,0.2,0.8>]
> [1 rgb <0.1,0.1,0.3>]}
>
> #declare Skycolour = // sunset
> colour_map{
> [0 rgb <1,0.1,0.1>]
> [0.5125 rgb <0.9,0.2,0.2>]
> [0.55 rgb <0.95,0.75,0.4>]
> [0.575 rgb <1,0.6,0.3>]
> [0.6 rgb <0.8,0.6,0.5>]
> [0.65 rgb <0.2,0.5,0.7>]
> [0.725 rgb <0.1,0.4,0.8>]
> [1 rgb <0.1,0.2,0.3>]}
>
>
> #declare Skycolour = // early morning/late afternoon
> colour_map{
> [0 rgb <1,0,0>]
> [0.5 rgb <0.65,0.6,0.9>]
> [0.525 rgb <0.35,0.6,0.9>]
> [0.6 rgb <0.3,0.55,0.8>]
> [0.8 rgb <0.1,0.3,0.9>]
> [1 rgb <0.2,0.3,0.7>]}
>
> #declare Skycolour = // midmorning/afternoon
> colour_map{
> [0 rgb <1,0,0>]
> [0.5 rgb <0.6,0.7,0.8>]
> [0.525 rgb <0.35,0.55,0.9>]
> [0.575 rgb <0.25,0.45,0.8>]
> [0.7 rgb <0.2,0.3,1>]
> [1 rgb <0.1,0.4,0.7>]}
>
> #declare Skycolour = // noon
> colour_map{
> [0 rgb <1,0,0>]
> [0.5 rgb <0.75,0.75,0.7>]
> [0.55 rgb <0.3,0.7,0.9>]
> [0.65 rgb <0.15,0.6,0.8>]
> [0.8 rgb <0.2,0.4,0.9>]
> [1 rgb <0.2,0.3,0.7>]}
>
> #declare Skycolour = // night
> colour_map{
> [0 rgb <1,0,0>]
> [0.5 rgb <0.05,0.075,0.075>]
> [0.525 rgb <0.025,0.025,0.1>]
> [1 rgb <0,0,0>]}

Which means adding a conditional to check if time is over 12 to 
differentiate between sunset and sunrise, easy enough. Nice colours, still 
seem to get than annoying banding between blue and orange though.

>
> Oh, and semicolons aren't required for those declares.  :-)

I know, I know, I tend to stick them on out of habit :)

> I realize all
> you asked for was an opinion but I love to try sky colors myself.
>
> Bob H.
>
>
I was inspired after driving home this week by all the beautiful sunsets.

I must admit I was suprised not to see anything about this on the net or 
ng's it seemed rather obvious to me to try and tie SunPos and sky_sphere 
together expecially for doing animations.

The next stage after messing with colours and #range's is some clouds with 
depth to reflect the sun properly and of course the sun itself which I 
can't seem to get right,ah well back to dabbling with media.

--
Phil

-- 
Using M2, Opera's revolutionary e-mail client: http://www.opera.com/m2/

Post a reply to this message

On Fri, 03 Oct 2003 10:49:40 +0100, Phil Cook <phi### [at] deckingdealscouk> 
wrote:

> On Thu, 2 Oct 2003 15:12:45 -0500, Hughes, B. <omn### [at] charternet> 
> wrote:
>
>>
>> "Phil Cook" <phi### [at] deckingdealscouk> wrote in message
>> news:oprwfbhgleeybzwd@news.povray.org...

<snip me>
>>
>> Looks like a great idea. If you add one more color_map following after 
>> the
>> last #break, and add #else before the color_map, it'll be valid for all
>> times not within the ranges given. That way you get the night sky at 3 
>> a.m.
>> too, which is one of the times I tried.
>
> Hmmm yes I forgot to test it during winter, the values only ran down to 
> -3 million. Writes out 100 times "I must remember to trap errors"
>
>>
>> Sky coloring is always difficult. Right away I thought the purple didn't
>> seem correct for the sunrise/sunset. Although, I think if a layer of 
>> thin
>> clouds or water droplets were present in the air this is the color that
>> might be seen. I'm just guessing, but perhaps a result of the very wide 
>> area
>> it covers it looks out of place. The bright blue above it looks wrong 
>> to me
>> too, too blue without other colors mixed in to offset it. Most times I 
>> think
>> of the real sky colors as muted in some sense, except perhaps the Sun 
>> itself
>> and intensely lit clouds. A bit of imaginative perception can enhance 
>> the
>> coloring. I see a lot of sunrises from my location on a NE facing 
>> hillside,
>> not as many sunsets, and yet I don't believe I could accurately 
>> reproduce it
>> from memory in POV-Ray.
>>
>> Overall I'd say you have too much red mixed into the blue in those color
>> maps.
>
> Thanks, mixing colours is difficult. If I recall my physics correctly 
> the blue is due to atmospheric scattering when passing through all the 
> atmos' then as the sun sets the blue diminishes as green is added to 
> make cyan than the blue goes and the green is added to red to make 
> yellow and then finally the green goes to leave red. Taking the cyan out 
> of the sunsets does produce that magenta colour, but leaving it in seems 
> to produce either banding or unrealistic colours.
>
>>
>> Anyway, I'd suggest the orange range be thinner, closer to the horizon.
>> Here's my attempt at adjusting all the sky colors. Use them if you wish 
>> to,
>> change them some more, whatever. It's only my interpretation of sky
>> coloring.
>>
<snip code>
>
>>
>> Oh, and semicolons aren't required for those declares.  :-)
>
> I know, I know, I tend to stick them on out of habit :)
>
>> I realize all
>> you asked for was an opinion but I love to try sky colors myself.
>>
>> Bob H.
>>
>>
> I was inspired after driving home this week by all the beautiful sunsets.
>
> I must admit I was suprised not to see anything about this on the net or 
> ng's it seemed rather obvious to me to try and tie SunPos and sky_sphere 
> together expecially for doing animations.
>
> The next stage after messing with colours and #range's is some clouds 
> with depth to reflect the sun properly and of course the sun itself 
> which I can't seem to get right,ah well back to dabbling with media.
>
> --
> Phil
>

This may be a backwards step but simplfying the colours seemed to produce 
interesting results:

//start code
global_settings{assumed_gamma 1}

#include "sunpos.inc"

//just to initiate SunPos
#declare lightposition = SunPos(2003, 7, 7, 5, 30, 0, 51.4667, 0.00);

//RERUN SolarPostion but bring in by a factor of 100
#declare newSolarPosition=vrotate(<0,0,10000000>,<-Al,Az,0>);

#macro SunColourMacro()
#switch (newSolarPosition.y)

#range(-9000000, -1250000)
#declare Skycolour =
colour_map{
[0 rgb <0,0,0>]
[1 rgb <0,0,0>]}
#break

#range(-1250000, 0)
#declare Skycolour =
colour_map{
[0 rgb <1,0,0>]
[0.7 rgb <0,0,0>]}
#break

#range(0, 1250000)
#declare Skycolour =
colour_map{
[0.5 rgb <1,0.25,0>]
[0.55 rgb <1,0.5,0>]
[0.8 rgb <0,0,0>]}
#break

#range(1250000, 2500000)
#declare Skycolour =
colour_map{
[0.4 rgb <1,0.5,0>]
[0.55 rgb <1,1,0.5>]
[0.8 rgb <0.5,0.5,1>]}
#break

#range(2500000, 5000000)
#declare Skycolour =
colour_map{
[0 rgb <0.5,1,1>]
[1 rgb <0.5,0.5,1>]}
#break

#range(5000000, 9000000)
#declare Skycolour =
colour_map{
[0 rgb <0.5,0.5,1>]
[1 rgb <0,0.5,1>]}
#break

#else

#declare Skycolour =
colour_map{
[0 rgb <0.5,0.5,1>]
[1 rgb <0,0.5,1>]}
#break
#end
#end


//sky
#declare MySkySphere=
sky_sphere{
SunColourMacro()
pigment{
gradient y
colour_map{
Skycolour}
scale 2 translate -1}};

sky_sphere{MySkySphere}


//clouds
plane{<0,1,0>,1 texture{
pigment{bozo warp{turbulence 0.4 octaves 6  omega 0.7 lambda 2}
colour_map{
[0.0 rgb <0.95, 0.95, 0.95>]
[0.1 rgb <0.85, 0.85, 0.85>]
[0.5 rgbt <1, 1, 1, 1> ]
[1.0 rgbt <1, 1, 1, 1> ]}
rotate<10,20,0>
scale <0.3, 0.4, 0.3>*3 }
finish {ambient 1 diffuse 0}}
scale 1000}

#declare Suncolour = rgb<247/255,255/255,58/255>;

//adjust sphere to match apparent size
#declare MySphere= sphere{<0,0,0> 250000 pigment{colour Suncolour} 
finish{ambient 1 diffuse 0}}

//Use rejigged SolarPosition
light_source {newSolarPosition rgb 1 looks_like {MySphere}}

camera{
location <0,10,-150>
look_at <0,10,10>
}


plane{y,0 texture {pigment{rgb <0.6,0.8,0.196078>*0.9} normal {bumps 0.5 
scale 0.01} finish {ambient 0.45 diffuse 0.55}}}
//end code

This is set to summer times sunrise approx 4.00 I quite like the effect of 
this, not happy around 5.30 yellow seems a bit wishy washy.

Remembered to error trap this time:) Wish I could use some sort of formula 
to alter the colours rather than range jumps though perhaps later.

I think I'll work with these colours for the time being (unless anyone can 
alter these for the better) and start work on a better sun and clouds, 
anyone got any tips?

--
Phil
-- 
Using M2, Opera's revolutionary e-mail client: http://www.opera.com/m2/

Post a reply to this message

Wish I had my camera with me when I went out to the store the day after I
last posted a reply here. The sunset was one of those beauts with plenty of
color. A very large blanket of clouds covered most of the sky and was only a
faint lavender color before the sun dropped below it, the air itself looking
lit by yellow sunlight, then it changed to purple with brilliant orange-reds
on the parts underneath. What made it interesting to me more than the colors
was how that single-layered cloud looked upside-down. It was as if it were
bubbling downward, with an appearance like cumulonimbus cloudtops jutting
out below and into the sunshine out of the ever-darker purple. Whole event
lasted maybe 10 minutes.

Anyway, yeah, if you could get clouds together with the background sky it'd
be a vast improvement.

In your pov script, which I tried again, I pointed the camera higher up
rather than straight ahead. Your sunrise/sunset times (4:30 and 19:30) has a
black sky overhead, fairly sharp boundry too. IRL it never does that, unless
perhaps while in a high altitude airplane.

Something to consider might be azimuth of sun position so that one side of
the sky has brighter colors than the opposite side. Just an additional
semi-transparent pigment layer overlaid the main sky color pigment could be
used for that. Looks like that could be added at the final skysphere using
the Az variable which Sunpos() macro returns.

Bob H.

Post a reply to this message

On Mon, 6 Oct 2003 18:12:43 -0500, Hughes, B. <omn### [at] charternet> 
wrote:

> Wish I had my camera with me when I went out to the store the day after I
> last posted a reply here. The sunset was one of those beauts with plenty 
> of
> color. A very large blanket of clouds covered most of the sky and was 
> only a
> faint lavender color before the sun dropped below it, the air itself 
> looking
> lit by yellow sunlight, then it changed to purple with brilliant 
> orange-reds
> on the parts underneath. What made it interesting to me more than the 
> colors
> was how that single-layered cloud looked upside-down. It was as if it 
> were
> bubbling downward, with an appearance like cumulonimbus cloudtops jutting
> out below and into the sunshine out of the ever-darker purple. Whole 
> event
> lasted maybe 10 minutes.
>

I'm in the UK so weather here is completely predictable in being 
completely unpredicatable:)


> Anyway, yeah, if you could get clouds together with the background sky 
> it'd
> be a vast improvement.

As I said clouds and sun are the next step <sigh>

>
> In your pov script, which I tried again, I pointed the camera higher up
> rather than straight ahead. Your sunrise/sunset times (4:30 and 19:30) 
> has a
> black sky overhead, fairly sharp boundry too. IRL it never does that, 
> unless
> perhaps while in a high altitude airplane.

Hmm I could switch it for a dark blue

>
> Something to consider might be azimuth of sun position so that one side 
> of
> the sky has brighter colors than the opposite side. Just an additional
> semi-transparent pigment layer overlaid the main sky color pigment could 
> be
> used for that. Looks like that could be added at the final skysphere 
> using
> the Az variable which Sunpos() macro returns.
>
> Bob H.
>
>

Yeah something I realised this morning when watching the sunrise, 
colour_map runs right round the sphere so it's red or yellow opposite the 
sun as well which is not IRL. I was considering using the Az variable to 
tie into the colour_map settings or just tilt the map, but your way would 
be better.

What do you think, using -Al and Az as direction with a red, orange, 
yellow type texture, as the sun rises the texture sinks? That may allow 
the sky_sphere to just shift from blues to blacks.

Hmmm I'll give it a try when I've some time, completely rewriting a 
company website at the moment brains gone numb.

--
Phil

-- 
Using M2, Opera's revolutionary e-mail client: http://www.opera.com/m2/

Post a reply to this message