// Persistence of Vision Ray Tracer Scene Description File
// File: MotionBlurTest.pov
// Date: 12/16/1999
// Author: Chris Huff
// Desc: A test of different motion blur methods.
//*******************************************
#include "colors.inc"
//-------------------------------------------
#declare motBlurSamps = 25;
#declare ShutterSpeed = 1;
global_settings {
   motion_blur motBlurSamps, ShutterSpeed
}

camera {
   location < 0, 5.0, -8>
   angle 35
   up y*image_height/image_width right x*1
   look_at < 0, 0, 0>
}

//*******************************************
#declare BallTex =
texture {
   pigment {wrinkles
      color_map {
         [ 0.000 rgbft <1.0, 0.5, 1.0, 0.0, 0.0> ] //violet 1
         [ 0.100 rgbft <1.0, 0.5, 1.0, 0.0, 0.0> ] //violet 2
         [ 0.214 rgbft <0.5, 0.5, 1.0, 0.0, 0.0> ] //indigo
         [ 0.328 rgbft <0.2, 0.2, 1.0, 0.0, 0.0> ] //blue
         [ 0.442 rgbft <0.2, 1.0, 1.0, 0.0, 0.0> ] //cyan
         [ 0.556 rgbft <0.2, 1.0, 0.2, 0.0, 0.0> ] //green
         [ 0.670 rgbft <1.0, 1.0, 0.2, 0.0, 0.0> ] //yellow
         [ 0.784 rgbft <1.0, 0.5, 0.2, 0.0, 0.0> ] //orange
         [ 0.900 rgbft <1.0, 0.2, 0.2, 0.0, 0.0> ] //red1
         [ 1.000 rgbft <1.0, 0.2, 0.2, 0.0, 0.0> ] //red2
      }
   }
}


motion_blur {
   sphere {< 0, 0, 0>, 0.5
      texture {BallTex}
      translate x*clock
      translate y*1.25
   }
}
#declare C=0;
motion_blur {
   sphere {< 0, 0, 0>, 0.5
      texture {BallTex}
      translate x*(C/(motBlurSamps-1))
      translate -x*0.5
   }
   #declare C=C+1;
}
#declare C=0;
motion_blur {
   sphere {< 0, 0, 0>, 0.5
      texture {BallTex}
      translate x*pow(C/(motBlurSamps-1), 3)
      translate -y*1.25 -x*0.5
   }
   #declare C=C+1;
}

//*******************************************

light_source {<-20, 25, -100 > color White}

//-------------------------------------------

-- 
Chris Huff
e-mail: chr### [at] yahoocom
Web page: http://chrishuff.dhs.org/

Post a reply to this message