//A glass hummingbird I have hanging in a window.
//I am right in the middle of working on it, so things
//may be arranged strangely, and the model is unfinished.
//There is code for photon mapping, which currently is
//turned off, and some variables from the Multipatch,
//but it won't be hard to modify the code to work with
//the official version.

#include "colors.inc"
#include "metals.inc"
#include "glass.inc"
#version 3.1;
//#version 3.14159;

global_settings {
   assumed_gamma 1
   max_trace_level 16
   #declare phd = 0.15; //used in photons
// photons {
//    gather 20, 100
//    radius 0.2*phd, 2, 0.2*phd
//    adc_bailout 1/128
//    autostop 45
////     save_file "hummingbird.ph"
//    load_file "hummingbird.ph"
// }
}

sky_sphere {
   pigment {gradient y
      color_map {
         [0 color Blue*0.6]
         [1 color White]
      }
   }
}
// ----------------------------------------
light_source {<-30, 30, 10> color White}
camera {
   perspective 
   location <0.0, 1.5,-5>
   up y*image_height right x*image_width
   angle 35
   look_at <0, 0, 0>
}
// ----------------------------------------
plane {y,-1
   pigment {checker color White color Gray60}
   finish {ambient 0 diffuse 1}
}

#declare whiteTex =
texture {
   pigment {color White filter 0.9}
   finish {specular 1 roughness 0.002 reflection 0.1}
}
#declare BlueTex =
texture {
   pigment {color rgbf < 0.75, 0.85, 1, 0.9>}
   finish {specular 1 roughness 0.002 reflection 0.1}
}

#declare Hummingbird =
union {
   blob {
      sphere {<0, 0, 0>, 1, strength 2//The body
         texture {whiteTex}
         scale < 1, 0.35, 0.4>
         rotate z*45
      }
      sphere {<0, 0, 0>, 0.3, strength 1.5//The head
         texture {whiteTex}
         translate < 0.5, 0.2, 0>
      }
      cylinder {<0,-0.1, 0>, <0.7, 0, 0>, 0.04, strength 2//The beak
         texture {T_Gold_3C
   //       pigment {color rgb < 1, 1, 0>}
         }
         rotate -z*60
         translate < 0.5, 0.2, 0>
      }
      
   // sphere {<-0.12, 0, 0>, 0.15, strength 2
   //    texture {whiteTex}
   //    scale < 1, 0.7, 0.7>
   //    translate <-0.4, 0, 0> rotate z*45
   // }
      //START the tail
      cylinder {< 0, 0, 0>, <-1,-1, 0>*0.5, 0.05, strength 1.5
         texture {BlueTex}
         scale < 1, 1, 2>
         translate -x*0.5 rotate z*45
      }
      cylinder {< 0.1, 0, 0.025>, <-1,-1, 0.135>*0.5, 0.05, strength 1.5
         texture {BlueTex}
         scale < 1, 1, 2>
         translate -x*0.5 rotate z*45
      }
      cylinder {< 0.1, 0,-0.025>, <-1,-1,-0.135>*0.5, 0.05, strength 1.5
         texture {BlueTex}
         scale < 1, 1, 2>
         translate -x*0.5 rotate z*45
      }
      //END the tail
      //START the right wing
      cylinder {< 0, 0, 0>, <-0.75, 0.75,-0.25>, 0.1, strength 1.5
         texture {BlueTex}
         scale < 1, 1, 0.5> 
         translate -z*0.15 rotate -z*25
      }
      cylinder {< 0, 0, 0>, <-0.75, 0.75,-0.25>*0.7, 0.1, strength 1.5
         texture {BlueTex}
         scale < 1, 1, 0.5>
         translate -z*0.15 rotate -z*17.5
      }
      cylinder {< 0, 0, 0>, <-0.75, 0.75,-0.25>*0.55, 0.1, strength 1.5
         texture {BlueTex}
         scale < 1, 1, 0.5>
         translate -z*0.15 rotate -z*7
      }
      cylinder {< 0, 0, 0>, <-0.75, 0.75,-0.25>*0.45, 0.1, strength 1.5
         texture {BlueTex}
         scale < 1, 1, 0.5>
         translate -z*0.15 rotate z*5
      }
      //END the right wing
      //START the left wing
      cylinder {< 0, 0, 0>, <-0.75, 0.75, 0.25>, 0.1, strength 1.5
         texture {BlueTex}
         scale < 1, 1, 0.5> 
         translate z*0.15 rotate -z*25
      }
      cylinder {< 0, 0, 0>, <-0.75, 0.75, 0.25>*0.7, 0.1, strength 1.5
         texture {BlueTex}
         scale < 1, 1, 0.5>
         translate z*0.15 rotate -z*17.5
      }
      cylinder {< 0, 0, 0>, <-0.75, 0.75, 0.25>*0.55, 0.1, strength 1.5
         texture {BlueTex}
         scale < 1, 1, 0.5>
         translate z*0.15 rotate -z*7
      }
      cylinder {< 0, 0, 0>, <-0.75, 0.75, 0.25>*0.45, 0.1, strength 1.5
         texture {BlueTex}
         scale < 1, 1, 0.5>
         translate z*0.15 rotate z*5
      }
      //END the right wing
      threshold 1
      interior {I_Glass caustics 1}
      sturm
   }
   sphere {< 0, 0,-0.15>, 0.05
      texture {T_Gold_3C}
      rotate x*20
      translate < 0.4, 0.2, 0>
   }
   sphere {< 0, 0, 0.15>, 0.05
      texture {T_Gold_3C}
      rotate -x*20
      translate < 0.4, 0.2, 0>
   }
// rotate y*90//front view
// rotate -y*90//back view
   photons {
      separation 0.02*phd
      refraction on reflection off
      ignore_photons
   }
}


object {Hummingbird
   rotate y*170
   translate y*0.15
}
// ----------------------------------------

-- 
Chris Huff
e-mail: chr### [at] yahoocom
Web page: http://chrishuff.dhs.org/

Post a reply to this message