// File: Bucket.pov

#declare Photons = true;
#declare Radiosity = true;

#include "colors.inc"

#version unofficial MegaPOV 0.7;

global_settings {
    assumed_gamma 1.8
    #if(Photons)
        photons {
            #if(1)
                save_file "Bucket.ph"
            #else
                load_file "Bucket.ph"
            #end
            spacing 0.005
            autostop 0
            jitter 0
        }
    #end
    #if(Radiosity)
        radiosity {}
    #end
}

sky_sphere {
    pigment {gradient y
        color_map {
            [0 color rgb < 0.75, 0.8, 1>]
            [1 color rgb < 0.5, 0.6, 0.75>]
        }
    }
}

#declare CamPos = < 0.75, 5,-4>;

camera {
    location CamPos
    look_at < 0, 3, 0>
    angle 45
}

light_source {<-100, 300,-200>, color White
    photons {reflection on}
}
#if(!Radiosity)
    light_source {CamPos, color Gray30}
#end


box {<-100,-1,-100>, < 100, 0, 100>
    texture {
        pigment {color White}
        finish {ambient 0}
    }
}
box {<-5, 0,-1>, < 5, 0.5, 1>
    texture {
        pigment {wood
            rotate y*90 scale 0.0075
            rotate z*5
            warp {turbulence 0.03}
            color_map {
                [0 color rgb < 0.8, 0.7, 0.5>]
                [1 color rgb < 1, 0.85, 0.75>]
            }
        }
        finish {ambient 0}
    }
}
box {<-5, 0, 1>, < 5, 5, 1.5>
    texture {
        pigment {color rgb < 1, 0.9, 0.75>}
        finish {ambient 0}
    }
}

#declare in = 1/12;
#declare RS = seed(87048741);
 
union {
    #declare N = 24;
    #declare J = 0;
    #while(J < N)
        box {<-0.5, 0,-0.1>*in, < 0.5, 8, 0.1>*in
            texture {
                pigment {wood
                    rotate x*90 scale 0.0065
                    warp {turbulence 0.03}
                    color_map {
                        [0 color rgb < 0.8, 0.7, 0.5>*0.75]
                        [1 color rgb < 0.8, 0.7, 0.5>]
                    }
                }
                finish {ambient 0}
                translate < rand(RS), rand(RS), rand(RS)>*8
            }
            translate -z*3.9*in
            rotate y*360*J/N
        }
        #declare J=J+1;
    #end
    #declare Hoop =
    difference {
        cylinder {< 0, 0, 0>, < 0, 1*in, 0>, 4.1*in}
        cylinder {< 0,-1, 0>, < 0, 1.1*in, 0>, 4*in}
        texture {
            pigment {color Gray10}
            finish {ambient 0}
        }
    }
    object {Hoop translate y*5.5*in}
    object {Hoop translate y*1.5*in}
    merge {
        cylinder {< 0, 0.02, 0>, < 0, 7*in, 0>, 3.99*in
            texture {
                pigment {color White filter 1}
                finish {
                    ambient 0 diffuse 0 reflection 0.45
                    specular 1 roughness 0.01
                }
                normal {bumps bump_size 0.15 scale 0.05}
            }
            interior {
                ior 1.33
                fade_color color rgb < 0.65, 0.8, 1>
                fade_distance 15
                fade_power 5000
            }
            photons {target reflection on refraction on}
        }
        cylinder {< 0, 0.01, 0>, < 0, 6.99*in, 0>, 4*in
            texture {
                pigment {color Black}
                finish {ambient 0}
            }
        }
    }
    cylinder {< 0, 0, 0>, < 0, 0.1, 0>, 4*in
        texture {
            pigment {wood scale 0.0065
                warp {turbulence 0.03}
                color_map {
                    [0 color rgb < 0.8, 0.7, 0.5>*0.75]
                    [1 color rgb < 0.8, 0.7, 0.5>]
                }
            }
            finish {ambient 0}
            translate < rand(RS), rand(RS), rand(RS)>*8
        }
    }
    scale 2
    translate < 1, 0.5, 0>
} 
union {
    #declare N = 24;
    #declare J = 0;
    #while(J < N)
        box {<-0.5, 0,-0.1>*in, < 0.5, 8, 0.1>*in
            texture {
                pigment {wood
                    rotate x*90 scale 0.0065
                    warp {turbulence 0.03}
                    color_map {
                        [0 color rgb < 0.8, 0.7, 0.5>*0.75]
                        [1 color rgb < 0.8, 0.7, 0.5>]
                    }
                }
                finish {ambient 0}
                translate < rand(RS), rand(RS), rand(RS)>*8
            }
            translate -z*3.9*in
            rotate y*360*J/N
        }
        #declare J=J+1;
    #end
    #declare Hoop =
    difference {
        cylinder {< 0, 0, 0>, < 0, 1*in, 0>, 4.1*in}
        cylinder {< 0,-1, 0>, < 0, 1.1*in, 0>, 4*in}
        texture {
            pigment {color Gray10}
            finish {ambient 0}
        }
    }
    object {Hoop translate y*5.5*in}
    object {Hoop translate y*1.5*in}
    merge {
        cylinder {< 0, 0.02, 0>, < 0, 5*in, 0>, 3.99*in
            texture {
                pigment {color White filter 1}
                finish {
                    ambient 0 diffuse 0 reflection 0.45
                    specular 1 roughness 0.01
                }
                normal {bumps bump_size 0.15 scale 0.05}
            }
            interior {
                ior 1.33
                fade_color color rgb < 0.65, 0.8, 1>
                fade_distance 15
                fade_power 5000
            }
            photons {target reflection on refraction on}
        }
        cylinder {< 0, 0.01, 0>, < 0, 4.99*in, 0>, 4*in
            texture {
                pigment {color Black}
                finish {ambient 0}
            }
        }
    }
    cylinder {< 0, 0, 0>, < 0, 0.1, 0>, 4*in
        texture {
            pigment {wood scale 0.0065
                warp {turbulence 0.03}
                color_map {
                    [0 color rgb < 0.8, 0.7, 0.5>*0.75]
                    [1 color rgb < 0.8, 0.7, 0.5>]
                }
            }
            finish {ambient 0}
            translate < rand(RS), rand(RS), rand(RS)>*8
        }
    }
    scale 2
    translate <-1, 0.5, 0>
}

-- 
Christopher James Huff
Personal: chr### [at] maccom, http://homepage.mac.com/chrishuff/
TAG: chr### [at] tagpovrayorg, http://tag.povray.org/

<><

Post a reply to this message