They look kind of like the business end of a mace...they will need some 
tweaking, but here they are, spikey balls.

#include "functions.inc"

global_settings {assumed_gamma 1}

camera {
    location < 0, 0,-6>
    look_at < 0, 0, 0>
    right x up y*9/16
    angle 45
}

light_source {<-50, 50,-50>, color rgb 1}
light_source {< 0, 0,-8>, color rgb 0.05}

isosurface {
    function {
        f_r(x, y, z) - 0.75 -
        pow(sin(atan2(x, z)*16)*sin(atan2(sqrt(x*x + z*z), y)*16), 
2)*0.25
    }
    threshold 0
    max_gradient 5
    contained_by {sphere {0, 1}}
    texture {
        pigment {color rgb 1}
        finish {
            ambient 0 diffuse 1
            specular 1 roughness 0.01
        }
    }
    translate -x*1.1
}

isosurface {
    function {
        f_r(x, y, z) - 0.75 -
        pow(
            sin(atan2(sqrt(x*x + z*z), y)*12 + atan2(x, z)*8)*
            sin(atan2(sqrt(x*x + z*z), y)*12 - atan2(x, z)*8)
            , 4
        )*0.25
    }
    threshold 0
    max_gradient 5
    contained_by {sphere {0, 1}}
    texture {
        pigment {color rgb 1}
        finish {
            ambient 0 diffuse 1
            specular 1 roughness 0.01
        }
    }
    translate x*1.1
}

-- 
Christopher James Huff <cja### [at] earthlinknet>
http://home.earthlink.net/~cjameshuff/
POV-Ray TAG: chr### [at] tagpovrayorg
http://tag.povray.org/

Post a reply to this message