/* OpArt.pov 

Render the image to a size that fills your screen (don't worry, it's
pretty quick).

Your eye will want to find simple patterns in the arrangement but the
arrangement is derived from a bozo pigment pattern which isn't quite
simple enough for the eye to cope with.

Why not try some variations, such as:-
   Using an orhtographic camera (simplifies the image)
   Using different pigment pattern
   Using V to affect the size of the spots 
         e.g.    scale (1+V)/2
   Using different shaped spots
   
The scene can be animated. As 'clock' varies, the control information
is obtained from a different Y-plane cutting through the bozo pattern.
So the image changes smoothly, but non cyclically, as clock changes.
*/

camera { location  <0, 6, 0> look_at <0, 0, 0>}

light_source {<40,100,40> colour rgb 1.5}

background {rgb 1}

#declare p = pigment {
  bozo scale 3
  colour_map {[0 rgb 0.9][1 rgb 0.2]}
}

#declare D=0.25; // separation of spots 

#declare spot=box{-0.3*D,0.3*D pigment {rgb 0} no_shadow}

#declare X=-5;
#while (X<5)
  #declare Z=-4;
  #while (Z<4)
    #declare V = vlength(eval_pigment(p,<X,-1+clock*10,Z>));
    object {spot
       rotate <0,180*V,0>
       translate<X,-1,Z>
    }
    #declare Z=Z+D;
  #end
  #declare X=X+D;
#end

//Mike Williams

Post a reply to this message