I have double spaced each line, if any of the lines have wrapped around, 
unwrap them before running.


//**********************************************************

//

//  FILE : diamond.pov

//  SCENE: A diamond in it's best display of colors

//  DATE : Sept 2002  

//  EMAIL: marcch.AT.videotron.DOT.ca

//  Copyright 2002, Marc Champagne, Please ask!

//

//**********************************************************

 

#include "colors.inc"



/*******************/

/* SCENE QUALITIES */

/*******************/



#declare   PhotonCount = 9000;

#declare       Photons = yes;

#declare   Dispersions = yes;

#declare   Reflections = yes;

#declare          Iors = yes;

#declare     AreaLight = no;

#declare     FullScene = yes;



#declare  FilterAmount = .98;

#declare DiamondColor  = .98;



#declare    Dispersion = 1.02;

#declare           Ior = 2.417;





/*******************/

/* DEBUGGING STUFF */

/*******************/



#declare     DebugAxis = no;

#declare   DebugColors = no;

#declare  CrossSection = no;

#declare     DebugCuts = no;





/****************/

/* DIAMOND MATH */

/****************/



#declare                      Diameter = 1;

#declare                        Radius = Diameter    / 2;

#declare                   CrownHeight = Diameter    * ( 16.2 / 100 );

#declare                   GirdleDepth = Diameter    * ( 01.0 / 100 );

#declare                 PavillonDepth = Diameter    * ( 43.1 / 100 );

#declare                  OverallDepth = CrownHeight + GirdleDepth + 
PavillonDepth;

#declare                    TableWidth = Diameter    * ( 53.0 / 100 );

#declare                   TableRadius = TableWidth  / 2;

#declare          CrownBazelFacetAngle = 34.50;

#declare           CrownStarFacetAngle = 20.00;  // Ideal = 15.00, unable 
to find exact specs for placing these facets

#declare    CrownUpperGirdleFacetAngle = 39.22;  // Ideal = 42.00, unable 
to find exact specs for placing these facets

#declare                   GirdleAngle = 90.00;

#declare PavillonLowerGirdleFacetAngle = 42.75;

#declare            PavillonFacetAngle = 40.75;





/*******************/

/* GLOBAL SETTINGS */

/*******************/



global_settings {

  

  #if ( Photons )

    photons { count PhotonCount

              //save_file "diamond.ph"

              //load_file "diamond.ph"

            }

  #end

  

  max_trace_level 60

}

  

  



/*******************/

/* DEBUG STUFF     */

/*******************/



#declare Size = .002;

#if ( DebugAxis )

  object { cylinder { < -300,    0,    0 >, < 300,    0,   0 >, Size } 
pigment { color <1,0,0> } no_shadow }

  object { cylinder { <    0, -300,    0 >, <   0,  300,   0 >, Size } 
pigment { color <0,1,0> } no_shadow }

  object { cylinder { <    0,    0, -300 >, <   0,    0, 300 >, Size } 
pigment { color <0,0,1> } no_shadow }

  

  object { cylinder { < -300, OverallDepth,    0 >, < 300, OverallDepth,   
0 >, Size } pigment { color <1,0,0> } no_shadow }

  object { cylinder { < -300, PavillonDepth,   0 >, < 300, PavillonDepth,  
0 >, Size } pigment { color <1,0,0> } no_shadow }

  object { cylinder { < -300, PavillonDepth+GirdleDepth,    0 >, < 300, 
PavillonDepth+GirdleDepth,   0 >, Size } pigment { color <1,0,0> } 
no_shadow }  

                                                                    

  object { cylinder { <   .5, -300,    0 >, <  .5,  300,   0 >, Size } 
pigment { color <0,1,0> } no_shadow }

  object { cylinder { <  -.5, -300,    0 >, < -.5,  300,   0 >, Size } 
pigment { color <0,1,0> } no_shadow }

  

  object { cylinder { <  -.265, -300,    0 >, < -.265,  300,   0 >, Size } 
pigment { color <0,1,0> } no_shadow }

  object { cylinder { <   .265, -300,    0 >, <  .265,  300,   0 >, Size } 
pigment { color <0,1,0> } no_shadow }

#end





/************************/

/* DIAMOND CONSTRUCTION */

/************************/



#if ( DebugCuts )

  #declare Cut   = union        { sphere { 0, .02 } sphere { -y*.02, .01 } 
pigment { rgb <1,0,0> } no_shadow }  

  #declare Stone = union        {

#else

  #declare Cut   = object       { plane  { y, 0.00 } }

  #declare Stone = intersection {

#end





/*******************/

/* TABLE           */

/*******************/



  object {  Cut                               

    translate y * OverallDepth                #if ( DebugColors ) pigment { 
rgb <0,1,1> } #end

  }





/***********************/

/* CROWN - STAR FACET  */

/***********************/



  #declare Faces = 8;  

  #declare  Turn = 0;

  #while ( Turn < Faces )

    object { Cut

      rotate    -z * CrownStarFacetAngle

      translate  x * TableRadius

      translate  y * ( OverallDepth - .0075 )     // Unable to find exact 
data for these facets

      rotate     y * 360 / Faces / 2

      rotate     y * 360 / Faces * Turn       #if ( DebugColors ) pigment { 
rgb <0,1,0> } #end

    }

    #declare Turn=Turn+1;

  #end

  

  

/************************/

/* CROWN - BAZEL FACET  */

/************************/



  #declare Faces = 8;  

  #declare  Turn = 0;

  #while ( Turn < Faces )

    object { Cut

      rotate    -z * CrownBazelFacetAngle

      translate  x * Radius

      translate  y * ( PavillonDepth + GirdleDepth )

      rotate     y * 360 / Faces * Turn       #if ( DebugColors ) pigment { 
rgb <1,0,0> } #end

    }

    #declare Turn=Turn+1;

  #end





/******************************/

/* CROWN - UPPER GIRDLE FACET */

/******************************/



  #declare Faces = 16;  

  #declare  Turn = 0 ;

  #while ( Turn < Faces )

    object { Cut

      rotate    -z * CrownUpperGirdleFacetAngle

      translate  x * ( Radius -.01 )

      translate  y * ( PavillonDepth + GirdleDepth )

      rotate     y * 360 / Faces / 2

      rotate     y * 360 / Faces * Turn       #if ( DebugColors ) pigment { 
rgb <1,0,1> } #end

    }

    #declare Turn=Turn+1;

  #end





/*******************/

/* GIRDLE          */

/*******************/



  #declare Faces=32;  

  #declare Turn=0;

  #while (Turn<Faces)

    object { Cut

      rotate    -z * GirdleAngle      

      translate  x * ( Radius - .01 )

      rotate     y * 360 / Faces * Turn       #if ( DebugColors ) pigment { 
rgb <1,1,0> } #end

      translate  y * PavillonDepth    // not needed, only used for visual 
when Debug is ON

    }

    #declare Turn=Turn+1;

  #end





/*********************************/

/* PAVILLON - LOWER GIRDLE FACET */

/*********************************/



  #declare Faces = 16;  

  #declare  Turn = 0;

  #while ( Turn < Faces )

    object { Cut

      rotate    -z * ( ( 90 - PavillonLowerGirdleFacetAngle ) + 90 )

      rotate     y * 360 / Faces * Turn

      rotate     y * 360 / Faces / 2          #if ( DebugColors ) pigment { 
rgb <0,1,.5> } #end

      translate -y * .0225

    }

    #declare Turn=Turn+1;

  #end



/*********************/

/* PAVILLON - FACET  */

/*********************/



  #declare Faces = 8;  

  #declare  Turn = 0;

  #while ( Turn < Faces )

    object { Cut

      rotate     z * ( ( 90 - PavillonFacetAngle ) + 90 )

      rotate     y * 360 / Faces * Turn       #if ( DebugColors ) pigment { 
rgb <1,1,1> } #end

    }

    #declare Turn=Turn+1;

  #end



/*******************/

/* CULET           */

/*******************/



  object { Cut

    rotate     z * 180

    translate  y * .02

  }





/*******************/

/* DEBUG           */

/*******************/



  #if ( CrossSection ) object { Cut rotate -x*90 pigment { rgb <1,1,1> } } 
#end

  

} 





/************************/

/* DIAMOND'S PROPERTIES */

/************************/



#declare Diamond = object {



  Stone



  pigment  { rgb        DiamondColor

             filter     FilterAmount

           }

  finish   { ambient    0.1

             diffuse    0.4

             specular   0.8

             roughness  0.003

             phong      1

             phong_size 300

             #if ( Reflections ) reflection { 0.2, 0.1  fresnel  metallic }  
#end

           }

  interior { #if ( Iors )                  ior        Ior                             
  
#end

             #if ( Photons & Dispersions ) dispersion Dispersion  
dispersion_samples 10  #end

                }

                 

  #if ( Photons ) photons { target 1 refraction on reflection on } #end

        

  bounded_by {

    box { < -Radius-.1,    OverallDepth+.1, -Radius-.1 >,

          <  Radius+.1,                -.1,  Radius+.1 >

        }

  }

  

}





/***********************/

/* THE COMPLETED SCENE */

/***********************/



camera {

  location   < 0, 2, -4 > 

  look_at    < 0, 0, 0 >

  direction  z

}



#if ( FullScene )

  

  light_source { < -5, 30, -10 >, rgb 1      

                 #if ( AreaLight ) area_light x*4, y*4, 2, 2  adaptive 1  
jitter #end

                 parallel

                 point_at <0,0,0>

               }



  box          { <-15,-1,-15>, <15,0,15>

                 pigment { rgb <.3,.4,.5> }

                 finish  { ambient .3 diffuse .4 }

                 #if ( Photons ) photons { target 1 refraction off 
reflection off } #end

               }

               

#else



  light_source { < 25, 50, -100 >, White } 

  

#end



object { Diamond  rotate     z * PavillonFacetAngle   // Make it lean on 
its side (crown facing -x)

                  translate -x * 1

       }

object { Diamond  rotate    -x * PavillonFacetAngle   // Make it lean on 
its side (crown facing -z)

       }       

object { Diamond  rotate     x * PavillonFacetAngle   // Make it lean on 
its side (crown facing +z)

                  translate  x * 1.2

       }       

//**********************************************************


-- 
(MIKA) Marc Champagne
marcch.AT.videotron.DOT.ca
Montreal, CANADA

Post a reply to this message

"Marc Champagne" <nos### [at] pleasecom> wrote in message
news:Xns### [at] 204213191226...
>
> I have double spaced each line, if any of the lines have wrapped around,
> unwrap them before running.


Marc, I have sent you an email, but for the benefit of the Group, I though I
would post here as well.
I was a jeweler when I was younger, and came across the specs for a standard
round Brilliant Diamond with unstacked mains.  The link is to a 1meg
animation using Mega POV (3.1 back then).  I am also attaching the POV file
as well, but you will notice my lack of fancy POV coding, as I was a novice
at the time I developed it.  Perhaps this will help you with your diamond as
well, although I am interested in seeing it now...

http://winhunter.sourceforge.net/mega.avi


Group,

I am a novice POVRayer, and thus my scenefile reflects as such, in fact, it
was a scene file from an older version of POV which was brought up to speed
to run in MEGAPOV.

:o")



// Persistence of Vision Raytracer
// Standard Round Brilliant Diamond With Unstacked Mains
// by Andrew Reed

//#include "srb.inc"
#version unofficial MegaPov 0.7;  // version number may be different

#include "megashapes.inc"

global_settings {
  adc_bailout 0.003922
  ambient_light <1.0,1.0,1.0>
  assumed_gamma 1.9
  hf_gray_16 off
  irid_wavelength <0.247059,0.176471,0.137255>
  max_intersections 64
  max_trace_level 10
  number_of_waves 10
  photons {
    spacing 0.025*5
    autostop 0
  }
}

background { color <0.000,0.000,0.000> }




#declare ct1 = 25.0; //25.0
#declare ct2 = 15.0; //15.0
#declare ct3 = 3.0; //
#declare ct4 = -8; //-9
#declare pt1 = -76.8; //76.8
#declare pt3 = -77.5; //77.5
//#declare Start    = 19.0;
//#declare End      = 45.0;
//#declare My_Clock = Start+(End-Start)*clock;
#declare bendloc = .11;


camera {
 location  <0, 0, 0>
 direction <0, 0, 1>
 up        <0, 1, 0>
 right     <1.33, 0, 0>
 translate <1.0, 1.0, 0.0>
 look_at   <0.0, 0.0, 0.0>
 }

// light source
// light_source {
//    <25, 200, 0> colour  red 1.0 green 1.0 blue 1.0
//    spotlight
//    point_at <0, 0, 0>
//    tightness 50
//    radius 400
//    falloff 500
// }
//
// *******  L I G H T S *******
//

light_source {   // Light1
  <-12, 2, 2>
  color rgb <1.000, 0.000, 0.000>*200
  fade_distance 1
  fade_power 2
}
light_source {   // Light1
  <-12, 0, 2>
  color rgb <0.000, 1.000, 0.000>*200
  fade_distance 1
  fade_power 2
}
light_source {   // Light1
  <-12, -2, 2>
  color rgb <0.000, 0.000, 1.000>*200
  fade_distance 1
  fade_power 2
}


//
// ********  TEXTURES  *******
//

#declare Diamond1 =
   material  {// Diamond
      texture {
         pigment { color rgbf <1.0, 1.0, 1.0, 0.99> }
         finish {
            ambient 0.0
            diffuse 0.0
            specular 1.0
            roughness 0.001
            reflection 0.1
         }
      }
      interior { ior 2.47 }     // Diamond
   }













object {
 plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -320.0, 0.0> }
 texture {
  pigment { red 1.0 green 1.0 blue 1.0 }
  finish {
   diffuse 0.7
  }
  }
 }

object {
 plane { <0.0, -1.0, 0.0>, 0.0 translate <0.0, 320.0, 0.0> }
 texture {
  pigment { red 1.0 green 1.0 blue 1.0 }
  finish {
   diffuse 0.7
   ambient 0.4
  }
  }
 }


#declare Prong =
object {
  union {
    sphere { <0, 0.15, 0> .075 }
    cylinder { <0.0, -bendloc, 0.0>, <0.0, .15, 0.0>, .075 }
    sphere { <0, -bendloc, 0> .075 }
    cylinder { <0.0, -bendloc, 0.0>, <0.0, 1.5, 0.0>, .075 translate
<-bendloc, bendloc, 0.0> rotate <0.0, 0.0, 94.3> }//translate <0.0, -0.05,
0.0> }
  }
  texture {
    //pigment { color red 0.9 green 0.698039 blue 0.396078 }
    pigment { color red 0.71 green 0.65 blue 0.26 }
    finish {
      metallic
      ambient 0.5
      diffuse 0.8
      brilliance 6
      reflection 0.5
      phong 0.75
      phong_size 80
    }
  }
  rotate <0.0, 0.0, -42.3>
  translate <0.25, -1.0, 0.0>
  rotate <0.0, 0.0, 90.0>
}

#declare srb =
//object {
 difference {
  cylinder { <0, -90, 0>, <0, 10, 0>, 100 open  }
  // Crown facets C1 -16-
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 11.25, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 33.75, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 56.25, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 78.75, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 101.25, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 123.75, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 146.25, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 168.75, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 191.25, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 213.75, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 236.25, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 258.75, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 281.25, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 303.75, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 326.25, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <42.30, 0.0, 0.0> translate <0.0,
ct1, 0.0> rotate <0.0, 348.75, 0.0>  }
  // Crown facets C2 -8-
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <35.0, 0.0, 0.0> translate <0.0, ct2,
0.0> rotate <0.0, 45.0, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <35.0, 0.0, 0.0> translate <0.0, ct2,
0.0> rotate <0.0, 90.0, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <35.0, 0.0, 0.0> translate <0.0, ct2,
0.0> rotate <0.0, 135.0, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <35.0, 0.0, 0.0> translate <0.0, ct2,
0.0> rotate <0.0, 180.0, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <35.0, 0.0, 0.0> translate <0.0, ct2,
0.0> rotate <0.0, 225.0, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <35.0, 0.0, 0.0> translate <0.0, ct2,
0.0> rotate <0.0, 270.0, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <35.0, 0.0, 0.0> translate <0.0, ct2,
0.0> rotate <0.0, 315.0, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <35.0, 0.0, 0.0> translate <0.0, ct2,
0.0> rotate <0.0, 360.0, 0.0>  }
  // Crown facets C3 -8-
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <19.8, 0.0, 0.0> translate <0.0, ct3,
0.0> rotate <0.0, 22.5, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <19.8, 0.0, 0.0> translate <0.0, ct3,
0.0> rotate <0.0, 67.5, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <19.8, 0.0, 0.0> translate <0.0, ct3,
0.0> rotate <0.0, 112.5, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <19.8, 0.0, 0.0> translate <0.0, ct3,
0.0> rotate <0.0, 157.5, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <19.8, 0.0, 0.0> translate <0.0, ct3,
0.0> rotate <0.0, 202.5, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <19.8, 0.0, 0.0> translate <0.0, ct3,
0.0> rotate <0.0, 247.5, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <19.8, 0.0, 0.0> translate <0.0, ct3,
0.0> rotate <0.0, 292.5, 0.0>  }
  plane { <0.0, -1.0, 0.0>, 0.0 rotate <19.8, 0.0, 0.0> translate <0.0, ct3,
0.0> rotate <0.0, 337.5, 0.0>  }
  // Table facet C4
  plane { <0.0, -1.0, 0.0>, 0.0 translate <0.0, ct4, 0.0> }
  // Pavillion facets p1 -16-
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 11.25, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 33.75, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 56.25, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 78.75, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 101.25, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 123.75, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 146.25, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 168.75, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 191.25, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 213.75, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 236.25, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 258.75, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 281.25, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 303.75, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 326.25, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <40.1, 0.0, 0.0> translate <0.0, pt1,
0.0> rotate <0.0, 348.75, 0.0>  }
  // Pavillion facets p2 -16- edge
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 11.25, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 33.75, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 56.25, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 78.75, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 101.25, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 123.75, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 146.25, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 168.75, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 191.25, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 213.75, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 236.25, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 258.75, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 281.25, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 303.75, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 326.25, 0.0>  }
  plane { <0.0, 1.0, 0.0>, 0.0 translate <0.0, -47.0, 0.0> rotate <90.0,
0.0, 0.0> rotate <0.0, 348.75, 0.0>  }
  // Pavillion facets p3 -8-
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <39.0, 0.0, 0.0> translate <0.0, pt3,
0.0> rotate <0.0, 22.5, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <39.0, 0.0, 0.0> translate <0.0, pt3,
0.0> rotate <0.0, 67.5, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <39.0, 0.0, 0.0> translate <0.0, pt3,
0.0> rotate <0.0, 112.5, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <39.0, 0.0, 0.0> translate <0.0, pt3,
0.0> rotate <0.0, 157.5, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <39.0, 0.0, 0.0> translate <0.0, pt3,
0.0> rotate <0.0, 202.5, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <39.0, 0.0, 0.0> translate <0.0, pt3,
0.0> rotate <0.0, 247.5, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <39.0, 0.0, 0.0> translate <0.0, pt3,
0.0> rotate <0.0, 292.5, 0.0>  }
  plane { <0.0, 0.0, -1.0>, 0.0 rotate <39.0, 0.0, 0.0> translate <0.0, pt3,
0.0> rotate <0.0, 337.5, 0.0>  }
  }


object {
  srb
  material { Diamond1 }
  translate <0, 27, 0>
  scale <0.02, 0.02, 0.02>
  //rotate <0.0, My_Clock, 0.0>
  rotate <0.0, 12.5, 0.0>
  photons {
    target 0.7
    refraction on
  }
  bounded_by { sphere { <0, 0, 0> 1 } }
 }

//object {
//  Prong
//  rotate <0.0, 22.5, 0.0>
//}
//object {
//  Prong
//  rotate <0.0, 112.5, 0.0>
//}
//object {
//  Prong
//  rotate <0.0, 202.5, 0.0>
//}
//object {
//  Prong
//  rotate <0.0, 292.5, 0.0>
//}

Post a reply to this message

And yet another diamond... Not fully parameterized yet.  Don't change the
diameter just scale it.
#declare Diamond_Diameter = 2.0;
#declare Diamond =
difference {
// body
 cylinder {  <0,0,0>, <0,2,0>, Diamond_Diameter/2 }
//kite facets
#for (kiteangle,0,315,45)
  box { <-5.00, 0.00, -5.00>,< 5.00, 1.00, 5.00> rotate<0,0,34>
translate<-.54*Diamond_Diameter/2,2,0> rotate<0,kiteangle,0>     }
#end
// star facets
#for (starangle,22.5,360,45)
  box { <-5.00, 0.00, -5.00>,< 5.00, 1.00, 5.00> rotate<0,0,17>
translate<-.4989*Diamond_Diameter/2,2,0> rotate<0,starangle,0>    }
#end
// Upper Girdle Facets
#for (girdleangle,11.25,360,22.5)
  box { <-5.00, 0.00, -5.00>,< 5.00, 1.00, 5.00> rotate<0,0,38.37>
translate<-.589*Diamond_Diameter/2,2,0> rotate<0,girdleangle,0>    }
#end
//Pavilion main facets
#for (pavilionangle,0,360,45)
  box { <-5.00, -1.00, -5.00>,< 5.00, 0.00, 5.00> rotate<0,0,(-40.6)>
translate<.963*Diamond_Diameter/2,-.05,0> rotate<0,pavilionangle,0>    }
#end
//Lower Girdle Facets
#for (girdleangle,11.25,360,22.5)
  box { <-5.00, -1.00, -5.00>,< 5.00, 0.00, 5.00> rotate<0,0,-(40.6+4.37)>
translate<-1.2985*Diamond_Diameter/2,1.95,0> rotate<0,girdleangle,0>    }
#end
//Girdle Trim Facets
#for (girdleangle,11.25,360,22.5)
  box { <-5.00, -1.00, -5.00>,< 0.00, 2.00, 5.00> rotate<0,0,0>
translate<-0.98*Diamond_Diameter/2,0,0> rotate<0,girdleangle,0>    }
#end
}

Post a reply to this message

On 28-9-2018 5:46, Dan wrote:
> And yet another diamond... Not fully parameterized yet.  Don't change the
> diameter just scale it.

It took 14 years to grow? ;-)

-- 
Thomas

Post a reply to this message