Here is the code for "MIKA  Pink Floyd 2" in p.b.i

Have fun folks!

//// BEGIN ////

// Persistence of Vision Ray Tracer Scene Description File
// File: mc_prism2.pov
// Vers: 3.5
// Desc: Another attempt at the famous Prism (without any trickery)
//       ... Maybe Pink Floyd would like this on one of their albums :)
// Date: Sept 2002
// Auth: Marc Champagne

#declare PinkFloyd_DarkSideOfTheMoon_AlbumCover = no;

global_settings
   {  assumed_gamma 1
      photons  { count 10000000 jitter 0 }
      max_trace_level 60
   }

camera
   {  location < 1, 4, -.5 >
      look_at  < 1, 0, -.5 >
   }

// The Restricted Light Source (an upside-down cannal with a light
// inside the cannal)
union
   {  light_source
         { < .2, .35, .25 > rgb 50 }
      difference
         {  box      { <  0,  0,  0  >, < 1000, .5, .5  > }
            box      { < .1,-.1, .22 >, < 1001, .4, .28 > }
            pigment  { color rgb <0,1,0> } 
         }
      translate   -x * 1000
      translate   -x * 7
      rotate      -y * 13
      rotate      -z * 3
   }

// The Prism Object
#declare Prism =
   intersection
      {  plane       { -y,   0                                   }
         plane       {  y,  .4                                   }
         plane       { -z,   0                                   }
         plane       { -z,   0  rotate  y * 120                  }
         plane       { -z,   0  rotate -y * 120  translate x * 2 }
         pigment     {  color rgbf   .99 }      
         finish      {  ambient      0.2   diffuse     0.6
                        #if ( ! PinkFloyd_DarkSideOfTheMoon_AlbumCover )
                          reflection  0.2
                        #end
                     } 
         interior    {  ior                 1.4
                        dispersion          1.1  
                        dispersion_samples   30
                     }
         bounded_by  {  box { <-.1,-.1,-.1>, <2.1,.5,2.1> }  }
         photons     {  target  .5  refraction on  reflection on }
    	   translate   -x * 1 // center at origin
         translate   -z * 1 // center at origin
      }

// Prism Placement
object
   {  Prism    translate  z * .3
               translate  x *  1
   }

#if ( ! PinkFloyd_DarkSideOfTheMoon_AlbumCover )
   object
      {  Prism    scale           .5
                  rotate    -y *  15
                  translate -z * 1.1
                  translate -x *  .4
      }
   object
      {  Prism    scale           .5
                  rotate    -y *  28
                  translate  x * 2.6
                  translate  z * .07
      }
#end      

// Surface Under Prism(s)
plane
   {  y, 0
      pigment  { color rgb 1 }
      finish   { ambient 0 diffuse 1 }
   }
   
//// END ////   

-- 
(MIKA) Marc Champagne
marcch.AT.videotron.DOT.ca
Montreal, CANADA

Post a reply to this message