You probably have to adapt some of the photon stuff to MegaPov 0.7.

---%<------%<---
// Persistence of Vision Ray Tracer Scene Description File
// File: projector.pov
// Vers: 3.1
// Desc: Slide projector
// Auth: Ingo Janssen
//
#version unofficial MegaPov 0.6;
#include "glass.inc"

global_settings {
   assumed_gamma 1.0
   max_trace_level 10
   photons {    
      gather 30,100    
      radius .025,1//,.1
      jitter 0.4    
  }
}

background{rgb 0.25}

camera {
  location  < 5, 0,-15.0>
  look_at   <-30, 0, 0.0>
  angle 10
}

light_source {
   <9, 0, 0>
   color rgb 1
}  

#declare Lens = difference {  // f=5 units
   sphere{0,2.5}
   box{<0,-3,-3>,<3,3,3>}
   texture{T_Glass1}
   interior{ior 1.5}
}   

object {  //condensor
   Lens
   photons {
      photons_pass_through
   }
   translate <4,0,0>
}

box {
   <0,0,0>, <1,1,0.0001>
   pigment {
      image_map {
         gif
         "image.gif"
         filter all 1
      }
   }
   interior {ior 1.5}
   photons{
      photons_pass_through
   }
   translate <-0.5,-0.5,0>
   rotate <0,90,0>
}

object {    // projection lens
   Lens 
   photons {
      density 0.015
      refraction on
   }
   translate <-6,0,0>
}

box {                   //screen
   <0,-1,0>, <1,1,0.1>
   translate <-0.5,0,0>
   scale <6,8,1>
   rotate <0,90,0>
   translate <-30,0,0>
   pigment {rgb 1}
}
---%<------%<---

Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message