Scenefile that goes with:
Newsgroups: povray.binaries.images
Subject: Another Something - 1 attachments
From: ingo
Message-ID: <Xns### [at] povrayorg>


// Persistence of Vision Ray Tracer Scene Description File
// File: Construct.pov
// Vers: 3.1
// Desc: construction of patches
// Date: 2001/01/02
// Auth: ingo

#version unofficial MegaPov 0.6;

global_settings {
   assumed_gamma 1.0
   ini_option "+QR"
   radiosity{
      pretrace_start 0.08
      pretrace_end   0.04
      count 80             
      nearest_count 5      
      error_bound 2        
      recursion_limit 2    
      low_error_factor .5  
      gray_threshold 0.0   
      minimum_reuse 0.015  
      brightness 1         
      adc_bailout 0.01/0.5 
   }
}

#default{
   texture{
      pigment{rgb 1}
      finish{ambient 0 diffuse 1}
   }
}
/*
light_source {
   < 500, 500,-500>
   rgb 1
}
light_source {
   < 0, 0, 50>
   rgb <1,0.8,0.5>
} */
 
light_source {
  0*x 
  color rgb 1.0 
  area_light
  <50,0,0> <0,0,50> 
  10,10
  adaptive 2
  jitter
  translate <500,500,-500>
  orient
}

light_source {
  0*x 
  color rgb <1,0.8,0.5>
  area_light
  <8,0,0> <0,0,8>
  6,6
  adaptive 3 
  jitter
  translate <0,0,50>
  orient
}

camera {
   location  <0,0,-34.5>
   look_at   <0,0,0>
}

#declare Bic=bicubic_patch {
   type 1 
   flatness 0 
   u_steps 5 
   v_steps 5 
   <-3, 1, 3>, <-1, 0, 3>, <1, 0, 3>, <3, 1, 3>
   <-3, 0, 1>, <-1, 0, 1>, <1, 0, 1>, <3, 0, 1>
   <-3, 0,-1>, <-1, 0,-1>, <1, 0,-1>, <3, 0,-1>
   <-3, 1,-3>, <-1, 0,-3>, <1, 0,-3>, <3, 1,-3>
   pigment {rgb 1} 
   double_illuminate
   no_shadow
}

#declare Bic4=union {
   object {Bic translate <0, 1.8,0>}
   object {Bic rotate <180,0,0> translate <0,-1.8,0>}
   object {Bic rotate <0,0,90> translate <-1.8,0,0>}
   object {Bic rotate <0,0,-90> translate <1.8,0,0>}
}

#declare xBic4 =union {
   #declare Nr=9;
   #declare Trans=4;
   #declare Start=(-1*(Nr-1)/2)*Trans;
   #declare I=0;
   #while (I<Nr)
      object{ Bic4 translate <Start+(I*Trans),0,0> }
      #declare I=I+1;
   #end
}
#declare xyBic4 =union {
   #declare Nr=7;
   #declare Trans=4;
   #declare Start=(-1*(Nr-1)/2)*Trans;
   #declare I=0;
   #while (I<Nr)
      object{ xBic4 translate <0,Start+(I*Trans),0> }
      #declare I=I+1;
   #end
}

object {xyBic4}
object {Bic4 scale<9,7,1> translate <0,0,-4>}
object {Bic4 scale<9,7,1> translate <0,0,4>}

box {
   <-4,-4,-0.001>,<4,4,0.001>
   translate <0,0,-13.5>
   texture {
      pigment {rgbft 0.85}
      normal {
         granite 0.5
         scale 1
         sine_wave 
      }
      finish {ambient 0 diffuse 0 reflection 0}
   }
   interior {ior 1.5}
}

Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message