// sunset3, 2001 by Lutz-Peter Hooge
// Media scene
// render time approx. 15 min on Athlon 500 
// +w640 +h480 +a 0.3

#version 3.5;

camera
{
        location <0,.63,0>
        look_at <0,.5,1>
}

global_settings
{
	max_trace_level 20
}

sky_sphere
{      
        pigment
        {       
        	gradient y
        	color_map
        	{
			[0.0 color rgb <0,.1,.3>]
			[1.0 color rgb <0,.1,.3>*0]
        	}
        }
}

light_source
{
        <0,0,1>
        color rgb 1        
        looks_like
        {
                sphere
                { 
                        0,.05
                	hollow
                        pigment {color rgbt 1}
			interior
			{
				media
				{
					emission .00000015
					density
					{
						spherical
						color_map
						{
							[0.0 color rgb 0]
							[0.2 color rgb .1]
							[0.5 color rgb 0.75]
							[1.0 color rgb 1]
						}
					}
				}
			}
			scale <1,0.9,1>
                }
        }
        scale 6000*1000*10        
        rotate -x*5
}

#declare rad=1000*1000;

sphere
{       
        0,rad
        hollow
        translate y*-rad
        
        texture
        {
                pigment{color rgbt 1}
                finish
                {
                	specular .5 roughness .005
                	reflection{.5,1 falloff 4 fresnel}
                	conserve_energy
                }
                normal{bozo scale .5}
        }
        interior
        {
        	ior 1.3
        	media
        	{
        		absorption .009
        	}
        }
}

sphere
{       
        0,rad-10
        translate y*-rad
        
        texture
        {
                pigment{color rgb <1,.5,0>*1}
                normal{granite .2 scale <1,2,2> rotate y*45}
        }
}

sphere
{       
        0,1
  	hollow
  	no_shadow
        pigment{color rgbt 1}
        
        interior
        {       
	        media
	        {
	        	scattering{5,color rgb <1,.66,.33>*.0000015*.15 
eccentricity .85 extinction 10}
	        	
	        	density
	        	{
	        		spherical
	        		color_map
	        		{
	        			[0.0 color rgb 0]
	        			[1-(rad/(rad+10000)) color rgb 1]
	        			[1.0 color rgb 1]
	        		}
	        	}
	        }  
	}

	scale rad+10000
 	translate y*-rad
}
sphere
{       
        0,1
  	hollow
  	no_shadow
        pigment{color rgbt 1}
        
        interior
        {       
	        media
	        {
	        	scattering{5,color rgb 1*.00015*.15 eccentricity 0 
extinction 1}
	        	
	        	density
	        	{
	        		spherical
	        		color_map
	        		{
	        			[0.0 color rgb 0]
	        			[1-(rad/(rad+10)) color rgb 1]
	        			[1.0 color rgb 1]
	        		}
	        	}
	        }  
	}

	scale rad+10
 	translate y*-rad
}


sphere
{
	0,1
	hollow
	no_shadow 
	#local scl = <500,100,450>;

	scale scl
	
	pigment{color rgbt 1} 
	
	interior
	{
		media
		{
			scattering{5,color rgb <1,.8,.8>*.05 eccentricity .2 
extinction 2}
			intervals 10
			density
			{
				spherical
				color_map
				{
					[0.0 color rgb 0]
					[0.5 color rgb 1]
					[1.0 color rgb 1]
				}
				scale scl
			}
			
			density
			{
				spherical
				color_map
				{
					[0.0 color rgb 0]
					[0.3 color rgb .05]
					[0.5 color rgb .9]
					[1.0 color rgb 1]
				}
				scale scl
				scale <1,200,1>
			}

			density
			{       
				

				wrinkles
				color_map
				{
					[0.0 color rgb 0]
					[0.59 color rgb 0]
					[0.6 color rgb 1]
					[1.0 color rgb 1]
				}
				scale <1,1,1>
				translate <1,0,1>
				scale 75
			}
		}
	}
	scale <1,-1,1>
	
	translate <-400,75,100>
}

Post a reply to this message