/* unofficial POV-Ray aerobics, left-handed coordinate system diagram */
/* NOT, I repeat, NOT the original POV aerobics scene file for the picture 
in the docs! */

camera
{
        location <14,16,-21>
        direction 1.5*z
        look_at <3,1,0>
}

light_source
{
        <-24,10,-25>,
        0.4
}
light_source
{
        <12,14,-25>,
        0.8
}

background
{
        rgb <0,0.75,1>
}

#declare ThumbSegment=
union
{
        sphere
        {
                0, 1
        }
        cylinder
        {
                0, 2*y, 1
        }
        sphere
        {
                2*y, 1
        }
}

#declare FingerSegment=
union
{
        sphere
        {
                4*y, 1
        }
        cylinder
        {
                0, 4*y, 1
        }
}

#declare Finger=
union
{
union
{
        object
        {
                FingerSegment
        }
        object
        {
                FingerSegment
                rotate 30*x
                translate 4*y
        }
                rotate 60*x
                translate 4*y
}
        object
        {
                FingerSegment
        }
        sphere
        {
                0,1.333
        }
        rotate 15*x
}

#declare LeftHand=
union
{
object
{
        Finger
        scale 0.9
        rotate 5*z
        translate -3.45*x
}
object
{
        Finger
        scale 0.95
        rotate 2*z
        translate -1.2*x
}
object
{
        Finger
        scale 1
        rotate -2*z
        translate 1.15*x
}
object
{
        Finger
        scale 0.95
        rotate -5*z
        translate 3.3*x
}
union
{
object
{
        ThumbSegment
}
object
{
        ThumbSegment
        translate 3.5*y
}
        scale 1.2
        rotate <5,-10,-70>
        translate <5.25,-5,0>
}
union
{
        box
        {
                <-4.3,-10,-1>,<4.3,0,1>
        }
        cylinder
        {
                -4.3*x,4.3*x,1
        }
}
        pigment
        {
                blue 1
        }
        finish
        {
                ambient 0 diffuse 0.6
                specular 1 roughness 0.005
        }

}

// left hand showing +x direction and rotation
object
{
        LeftHand
}

// straight arrow showing +x direction on x axis
union
{
        cylinder
        {
                -40*x,8*x,1.25
        }
        cone
        {
                8*x,2,15*x,0
        }
        translate <0,-3,6>
        pigment
        {
                green 1
        }
}

// red curved arrow showing rotate +x direction
union
{
        torus
        {
                6,0.4
                clipped_by
                {
                        box
                        {
                                <-2,-1,-2>,<7,1,7>
                                inverse
                        }
                }
        }
        cone
        {
                0,1,3*z,0
                translate 6*x
                rotate 18*y
        }
        rotate 90*z
        translate <-12,-3,6>
        pigment
        {
                red 1
        }
}

Post a reply to this message