See post with same title in p.a-u.

Feel free to use this however you want...

---- cut here ----

#include "colors.inc"

global_settings {
   assumed_gamma 1.0
}

camera {
   location <0, 10, -10>
   look_at <0, 0, 0>
}

// Normal lightsource
light_source { <-20, 20, 0>, White }

plane { y, 0
   pigment { checker Gray50 White }
}

cylinder { <5, 0, -3>, <5, 30, -3>, 1
   pigment { White }
}

// This is a normal plain white sphere
sphere { <0, 3, 0>, 3
   pigment { White }
}

// Everything in this light group is lit only by "black light"
light_group {
   // This is the ultra violet light source
   light_source { <20, 20, -20>, rgb <0.5, 0, 1.5> }
   // This is a sphere with a checker pattern only visible in uv-light.
   // It's in the same place and slightly larger than the plane sphere.
   sphere { <0, 3, 0>, 3.01
     // This pigment is the trick:
     // It is very close to 100% transparent but still "emits" light
     // where lit by a light source.
     #declare trans = 0.9999;            // Close to 1.0 transmit
     #declare mult = 1 / (1 - trans);    // Color multipyer
     pigment { checker
       color White * mult transmit trans
       color Gray50 * mult transmit trans
     }
     finish {
       ambient 0
     }
   }
   global_lights off
}

---- cut here ----

-- 
Daniel Nilsson

Post a reply to this message