|
 |
//The code for "It's geting worse"
// Persistence of Vision Scene Description File
// Title: PlaneSphere2a.pov
// Author: John Guthkelch (Doctor John) <doc### [at] linuxmail org>
// Date: 25 September 2005
// Description: Reflective Sphere on Checkered Plane using isosurfaces
#include "functions.inc"
#include "metals.inc"
global_settings {
assumed_gamma 1.0
max_trace_level 15
radiosity {
pretrace_start 0.08
pretrace_end 0.01
count 80
nearest_count 7
error_bound 0.8
recursion_limit 1
low_error_factor 0.5
gray_threshold 0
minimum_reuse 0.015
brightness 1.0
adc_bailout 0.01/2
}
}
/***********************************************************************
Two isosurfaces as the main compositional elements in the scene. Both
have been negated with a crackle function to give the impression of
having
been eaten by numerous bugs. The spherical function has
additionally
been differenced with another sphere to hollow it out.
***********************************************************************/
#declare F_Munch=function{
pattern{
crackle
form <1, 0, 1>
turbulence 0.7
}
}
isosurface {
function{
max(f_sphere(x, y, z, 0.5)-(F_Munch(x*3, y*3, z*3)*0.5),
(-f_sphere(x, y, z, 0.99)))
}
threshold 0
contained_by {
sphere {
0, 1.0
}
}
max_gradient 25.555
all_intersections
texture {
T_Chrome_5D
finish {
ambient 0
}
}
scale 2
}
isosurface {
function {
(y+2.3)-(F_Munch(x*0.5, y*0.5, z*0.5)*0.3)
}
threshold 0
contained_by {
box {
<-100, -2, -100>, <100, -2.01, 100>
}
}
max_gradient 1.918
texture {
pigment {
checker
rgb <1, 1, 0>, rgb <0, 1, 0>
scale 2
}
finish {
ambient 0
}
}
}
/***********************************************************************
Without these we don't have much of a scene :-)
***********************************************************************/
camera {
location <0, 2, -6.6>
right x*image_width/image_height
look_at <0, 0, 0>
}
light_source {
<500, 200, -500>
rgb 1
}
sky_sphere {
pigment {
gradient y
color_map {
[0.0 color rgb <0.8, 0.8, 1>]
[1.0 color rgb <0, 0, 1>]
}
scale 2
translate -1
}
}
/**************************************************************/
John
--
Run Fast
Run Free
Run Linux
Post a reply to this message
|
|
