Scene Source Follows

// -w1152 -h864
global_settings
{
     max_trace_level 20
}

camera
{
     location <0, 0.2, -1>
     look_at <0.4, 0.3, 3>

     focal_point <0.4, 0.3, 2.2>
     blur_samples 128
     confidence .9
     variance 1/64
     aperture 0.2
}

global_settings
{
     radiosity
     {
         pretrace_end 0.003
         //normal on
        // media on
     }
}

default { finish { ambient 0 diffuse 0.7 } }


light_source
{
     <-7, 3,-7>, rgb 120
     fade_power 2
     fade_distance 1
     spotlight radius 5 falloff 15 tightness 50 point_at <0,1,3>
     area_light x*2,y*2,2,2 circular orient adaptive 1
}

light_source
{
     <5, -.5,-20>, rgb 200
     fade_power 2
     fade_distance 1
     spotlight radius 35 falloff 45 tightness 0 point_at <0,1,3>
     area_light x*10,y*10,2,2 circular orient adaptive 1
}

//light_group
//{

light_source
{
     <4, 5, 9>, rgb 180
     fade_power 2
     fade_distance 1
     spotlight radius 5 falloff 10 tightness 50 point_at <0,.5,3>
     area_light x*.5,y*.5,2,2 circular orient adaptive 1
}

     sphere{
      0,1

      hollow

      texture
      {
         pigment {

               checker rgb 0.25 filter 1 rgb 0.75 filter 1
             scale <.5,1,1>*0.075
             warp { spherical }
         }
         finish
         {
             specular 0.7 roughness 0.001
             reflection { 0.3, 1.0 fresnel on }
             conserve_energy
         }

      }
      interior
      {
         //ior 1.5

         media { scattering {4,rgb <0.70,0.85,1>*10} samples 15 
intervals 1}
         media { absorption rgb <0.5,0.8,1>*120 samples 25 intervals 1
                 density {
                     agate
                     //turbulence 1
                     scale .15
                     density_map
                     {
                         [0.00 rgb 0.0]
                         [0.01 rgb 0.5]
                         [0.99 rgb 0.8]
                         [0.99 rgb 1.0]
                         [1.00 rgb 1.0]
                     }

                 }

             }
      }

      rotate x*12
      rotate z*35
      rotate y*15
      translate z*3+y*.5
     }

    // global_lights 1}

plane { y, -0.50000000001 texture {
         checker
             texture {
                 pigment {
                     wood  rotate x*.5 translate x*10 turbulence 0.1 
scale 0.005
                     color_map
                     {
                         [0.0 rgb <0.3, 0.2, 0.1>*2.2]
                         [1.0 rgb <0.2, 0.1, 0.0>*2.2]
                     }

                     warp { repeat x*0.20 offset 0.002}
                 }
                 normal {
                     gradient x 1.0 scale <0.2,1,1>
                     slope_map {
                         [0.00 <0.0, 0.0>]
                         [0.05 <0.05, 0.0>]
                         [0.95 <0.05, 0.0>]
                         [1.00 <0.0, 0.0>]
                     }
                 }

                 finish {
                     phong 1.0 phong_size 50
                     reflection {0.2, 1 falloff 2}
                 }
             }
             texture {
                 pigment {

                     wood  rotate x*.5 translate x*10 turbulence 0.1 
scale 0.005
                     color_map
                     {
                         [0.0 rgb <0.3, 0.2, 0.1>*3]
                         [1.0 rgb <0.2, 0.1, 0.0>*3]
                     }

                     warp { repeat x*0.20 offset 0.002}
                 }
                 normal {
                     gradient x 1.0 scale <0.2,1,1>
                     slope_map {
                         [0.00 <0.0, 0.0>]
                         [0.05 <0.05, 0.0>]
                         [0.95 <0.05, 0.0>]
                         [1.00 <0.0, 0.0>]
                     }
                 }
                 finish {
                     phong 1.0 phong_size 50
                     reflection {0.2, 1 falloff 2}
                 }
                 rotate y*90
             }
         scale 0.7
         rotate y*-18
     }

}

-- 
~Mike

Post a reply to this message