See p.b.i for an image

#############################################

#declare lampenkoerper =
union {
    difference {
        cylinder { <-33,-3.75,0> <33,-3.75,0> .75 }
        plane { -y,0 rotate 45*z translate <-33,-4.5,0> }
        plane { y,0 rotate 45*z translate <33,-3,0> }
    }
    cylinder { <-27,-3.75,0> <-27,-8,0> .75 }
    cylinder { <-9,-3.75,0> <-9,-8,0> .75 }
    cylinder { <9,-3.75,0> <9,-8,0> .75 }
    cylinder { <27,-3.75,0> <27,-8,0> .75 }
    sphere { <-27,-8,0> .75 }
    sphere { <-9,-8,0> .75 }
    sphere { <9,-8,0> .75 }
    sphere { <27,-8,0> .75 }
    union {
        cylinder { <0,0,0> <0,-3,0> 3 }
        cylinder { <0,0,0> <0,-2.75,0> 3.25 }
        torus { 3, .25 translate <0,-2.75,0> }
        scale <1.7,1,1>
    }
    pigment { rgb .7 }
    finish { reflection .4}
}

#declare strahler =
union {
    cylinder { <0,0,0> <0,-1.5,0> .4 pigment { rgb .7 } finish { reflection .4 }}
    difference {
        sphere { <0,0,0> 2 scale <1,2.75,1> translate <0,-6.5,0> }
        plane { y,-6.5 }
        pigment { rgb .7 }
        finish { reflection .4}
    }
    difference {
        sphere { <0,0,0> 3 scale <1,1.5,1> translate <0,-10,0> }
        sphere { <0,0,0> 2.8 scale <1,1.5,1> translate <0,-10,0> }
        plane { y,-10 }
        pigment { rgb <1,.95,.9>*1.5 }
    }
    difference {
        sphere { <0,0,0> 2.8 scale <1,1.5,1> translate <0,-10,0> }
        plane { y,-10 }
        pigment { rgb <1,1,.95> }
        finish { ambient .7 }
    }
    light_source {
        <0,-10.01,0>
        rgb <1,1,.95>*.5
        spotlight
        point_at <0,-100,0>
        radius 0
        falloff 70
        tightness 1
        fade_power 2
        fade_distance 200
    }
}

#declare lampe=
union {
    object { lampenkoerper }
    object { strahler rotate <65,25,0> translate <-27,-8,0>}
    object { strahler rotate <-85,-10,0> translate <-9,-8,0> }
    object { strahler rotate <20,-85,0>translate <9,-8,0> }
    object { strahler rotate <-85,45,0> translate <27,-8,0> }
    rotate y*-90
}

#############################################

Post a reply to this message