// Military texture by Txemi Jendrix
// www.txemijendrix.com

global_settings {
   assumed_gamma 1.5
   noise_generator 2
}

camera {
   perspective
   location <1, 1.7, -1.7>
   sky y
   direction z
   right x*1.33333
   up y
   look_at y*0.5
}

light_source {
   <4, 5, -5>, rgb 1.2
}

// *** Color declarations *** //

#declare verdeo = // Dark green
  color rgb <0.215, 0.385, 0.11>;
#declare Trans = // Clear
  color rgbf 1;
#declare verdec = // Light green
  color rgb <0, 0.6, 0>;
#declare marron = // Brown
  color rgb <0.55, 0.294, 0.24>;

// *** Textured box *** //

box {   -0.5, 0.5
   material {

 texture { // 1st texture
     pigment {color verdeo}
      }
      
    texture { // 2nd texture
     pigment {
      agate
       agate_turb 0.5
        turbulence <0.6, 0.5, 0.4>
            
        color_map {
         [ 0 color Trans]
         [ 0.2 color Trans]
         [ 0.2 color verdec]
         [ 0.4 color verdec]
         [ 0.4 color Trans]
         [ 0.6 color Trans]
         [ 0.6 color verdec]
         [ 0.8 color verdec]
         [ 0.8 color Trans]
         [ 1 color Trans]
            }
         }
         scale <0.7, 0.5, 0.6>
      }
      
    texture { // 3rd texture
     pigment {
      bumps
       turbulence <0.6, 0.5, 0.4>
    
  color_map {
         [ 0 color Trans]
         [ 0.2 color Trans]
         [ 0.2 color marron]
         [ 0.4 color marron]
         [ 0.4 color Trans]
         [ 0.6 color Trans]
         [ 0.6 color marron]
         [ 0.8 color marron]
         [ 0.8 color Trans]
         [ 1 color Trans] 
            }
         }
         scale 0.1
         translate <0.5, 0.2, 0.1>
      }
   }
   translate y*0.5
}

Post a reply to this message