Here's the source for the scene.... It's actually very simple:

-------------8<-------------------------------------------

camera
{
    location <0, 0.2, -1>
    look_at <0.4, 0.3, 1>
}

light_source
{
    <-10, 10,-5>, rgb 1.5
    area_light x*2,y*2,7,7 orient adaptive 2
}

light_source
{
    <5, -.5,-10>, rgb 1.5
    area_light x*10,y*10,5,5 orient adaptive 1
}

light_source
{
    <5, 3, 6>, rgb 0.3
    area_light x*.5,y*.5,5,5 orient adaptive 1
}

sphere{ <0, 0, 1>, 0.5 pigment {color rgb <0.7,0.85,1>*0.5}
    finish {
        metallic phong 1.0 phong_size 100
        reflection {0.2, 1 falloff 2 metallic}
        irid { 0.1 thickness 0.5 turbulence 0.5 }
    }

    normal {
        spotted
        scale 0.5
        normal_map
        {
            [0.0 granite 0.1 scale 0.2/0.5]
            [0.7 granite 0.0]
            [1.0 granite 0.0]
        }
    }

}

plane { y, -0.5 texture {
        checker
            texture {
                pigment {
                    wood  rotate x*.5 translate x*10 turbulence 0.1 scale
0.005
                    color_map
                    {
                        [0.0 rgb <0.3, 0.2, 0.1>*2.2]
                        [1.0 rgb <0.2, 0.1, 0.0>*2.2]
                    }

                    warp { repeat x*0.20 offset 0.002}
                }
                normal {
                    gradient x 1.0 scale <0.2,1,1>
                    slope_map {
                        [0.00 <0.0, 0.0>]
                        [0.05 <0.05, 0.0>]
                        [0.95 <0.05, 0.0>]
                        [1.00 <0.0, 0.0>]
                    }
                }

                finish {
                    phong 1.0 phong_size 50
                    reflection {0.2, 1 falloff 2}
                }
            }
            texture {
                pigment {

                    wood  rotate x*.5 translate x*10 turbulence 0.1 scale
0.005
                    color_map
                    {
                        [0.0 rgb <0.3, 0.2, 0.1>*3]
                        [1.0 rgb <0.2, 0.1, 0.0>*3]
                    }

                    warp { repeat x*0.20 offset 0.002}
                }
                normal {
                    gradient x 1.0 scale <0.2,1,1>
                    slope_map {
                        [0.00 <0.0, 0.0>]
                        [0.05 <0.05, 0.0>]
                        [0.95 <0.05, 0.0>]
                        [1.00 <0.0, 0.0>]
                    }
                }
                finish {
                    phong 1.0 phong_size 50
                    reflection {0.2, 1 falloff 2}
                }
                rotate y*90
            }
        scale 0.7
    }
}

Post a reply to this message