// Isosurface Mystery Object...
// See corresponding thread in povray.binaries.images

global_settings{
  assumed_gamma 1
  max_trace_level 2
}

#default{finish{ambient 0}}

camera{
  fisheye
  right x*.5*1.33 up y*.5
  location<0,.2,-120>
  look_at 0
  angle 15
}

sky_sphere{
  pigment{
   planar poly_wave 1.5
   color_map{[0 rgb 0][1 rgb .5]}
  }
}

light_source{<-2,1,0>*100000,<1 1 .9>*3 }


#declare radial_zones=
  function{
   pigment{
    pigment_pattern{cylindrical scale 10}
    pigment_map{
     #local spikes=
      pigment{
       boxed scale .5 translate<.5,0,.5>
       warp{repeat x} warp{repeat z}
       scale<1,100,1>
       color_map{[0 rgb .1][.5 rgb .102]}
      }
     [0 rgb 0]
     [.01
      radial frequency 48 triangle_wave
      color_map{[0 rgb 0][.5 rgb 1][1 rgb 1]}
     ]
     [.02
      radial frequency 48 triangle_wave
      color_map{[0 rgb .875][.5 rgb 1][1 rgb 1]}
     ]
     [.05 rgb 1]
     [.075 rgb .25]
     [.1
      radial frequency 4 triangle_wave
      pigment_map{[.95 spikes][.975 rgb .65]}
     ]
     [.3
      radial frequency 4 triangle_wave
      pigment_map{[.95 spikes][.975 rgb .65]}
     ]
     [.32 rgb .5]
     [.475 rgb .5]
     [.5
      radial frequency 24 triangle_wave
      color_map{[0 rgb 0][.5 rgb .25][1 rgb .75]}
     ]
     [.525 rgb 0]
    }
   }
  }

isosurface {
  function{
   -radial_zones(x,y,z).grey
   +(y*y*y*y)*.25
   +.1
  }
  accuracy .01
  max_gradient 10
  contained_by{
   box{
    <-10,-2,-10>,
    <10,2,10>
   }
  }
  rotate x*270+<45,35,0>
  pigment{rgb .75}
  finish{
   reflection .75
   brilliance 8
   specular .5 roughness .08
   phong 2 phong_size 100
  }
}

Post a reply to this message