This is the source for the image that I posted recently on PBI, "Creation."

Andy

// Persistence of Vision Ray Tracer Scene Description File
// File: ?.pov
// Vers: 3.5
// Desc: Basic Scene Example
// Date: mm/dd/yy
// Auth: ?
//

#version 3.5;

#include "colors.inc"
#include "metals.inc"
#include "textures.inc"
#include "rand.inc"

global_settings
{
  assumed_gamma 1.0
}

// ----------------------------------------

#switch (1)      // Select a view point from 1 to 2

  // Scenic View
  #case (1)
  camera
  {
    location  <0.0, 1.7, -2.5>
    direction 1.5*z
    right     x*image_width/image_height
    look_at   <0.0, 0.2,  0.0>
  }

  #break

  // Close Up
  #case (2)
  camera
  {
    location  <0.0, 0.3, -1.0>
    direction 1.5*z
    right     x*image_width/image_height
    look_at   <0.0, 0.0, 0.0>
  }
  #break
#end

sky_sphere
{
  pigment
  {
    marble
    turbulence 1.0
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

light_source
{
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 30, -30>
}

// ----------------------------------------

plane
{
  y, 0
  texture
  {
    T_Silver_2D
    normal { waves 0.3 scale 0.2}
  }
}

#declare n = 0;
#while (n < 1.0)
union
{
  sphere { <0.1, n, 0.0>, 0.08 * (1 - n) texture { Polished_Chrome pigment
{ colour DarkOrchid } } rotate 0 * y  }
  sphere { <0.1, n, 0.0>, 0.08 * (1 - n) texture { Polished_Chrome pigment
{ colour OrangeRed } } rotate 120 * y }
  sphere { <0.1, n, 0.0>, 0.08 * (1 - n) texture { Polished_Chrome pigment
{ colour SlateBlue } } rotate 240 * y }
  torus { 0.08 * (n - 1.0), 0.01 * (n - 1.0) rotate 90 * x translate 0.05 *
x + n * z  rotate 0 * y texture { Polished_Chrome pigment { colour
DarkOrchid } } }
  torus { 0.08 * (n - 1.0), 0.01 * (n - 1.0) rotate 90 * x translate 0.05 *
x + n * z  rotate 120 * y texture { Polished_Chrome pigment { colour
OrangeRed } } }
  torus { 0.08 * (n - 1.0), 0.01 * (n - 1.0) rotate 90 * x translate 0.05 *
x + n * z  rotate 240 * y texture { Polished_Chrome pigment { colour
SlateBlue } } }

  rotate 500 * n * y
}
#declare n = n + 0.002;
#end

#declare n = 0;
#while (n < 100)
#declare rad = RRand(0.01, 0.05, RdmA);
sphere
{
  RRand(-3.97, 4.03, RdmA) * x + rad * y + RRand(-1.9, 8.1, RdmA) * z, rad
  texture { Polished_Chrome pigment { colour Cyan } }
}
#declare n = n + 1;
#end

light_source
{
  <0.0, 1.0, 0.0>
  colour Yellow
  looks_like
  {
    torus { 0.05, 0.008
            texture { Polished_Chrome pigment { colour Yellow } }
            // rotate 90 * x
          }
  }
}


sphere
{
  <0.0, 0.0, 0.0>, 0.09
  pigment { color rgbf<1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior
  {
    media
    {
      emission 4.0
      scattering { 1.0, colour Yellow extinction 0.0 }
      intervals 1
      samples 5
      method 3
      density
      {
        spherical
        ramp_wave
        colour_map
        {
          [0.90 colour Black ]
          [1.0 colour Yellow ]
        }
      }
    }
  }
  hollow
  translate y
}

cylinder
{
  <0.0, 0.0, 0.0>, <0.0, 0.9, 0.0>, 0.02
  pigment { colour rgbf<1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior
  {
    media
    {
      emission 4.0
      scattering { 1.0, colour Yellow extinction 0.0 }
      intervals 1
      samples 5
      method 3
      density
      {
        cylindrical
        ramp_wave
        colour_map
        {
          [ 0.0 colour Black transmit 1.0 ]
          [ 0.6 colour Yellow transmit 0.2]
          [ 1.0 colour Yellow ]
        }
        scale 0.02
      }
    }
  }
  hollow
}

Post a reply to this message