 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Hi
I'm new to this group (but not new to Povray) and I have just started to get
back
into raytracing after a long break from it.
I recently stumbled across this wonderfully revolting texture, a derivative
of the lightning
texture, and I thought I would share it with you all. Please don't trace
this if you
have a weak stomach! It certainly looks very organic at any rate.
Andy
<Source>
// Persistence of Vision Ray Tracer Scene Description File
// File: giblet.pov
// Vers: 3.5
// Desc: Uggh!
// Date: 23/01/03
// Auth: Andy Le Couteur Bisson
//
#version 3.5;
#include "colors.inc"
#include "textures.inc"
#include "rand.inc"
global_settings {
assumed_gamma 1.0
}
// ----------------------------------------
camera {
location <0.0, 0.0, -4.0>
direction 1.5*z
right x*image_width/image_height
look_at <0.0, 0.0, 0.0>
}
background { colour White }
light_source {
<0, 0, 0> // light's position (translated below)
color rgb <1, 1, 1> // light's color
translate <-30, 30, -30>
}
// ----------------------------------------
#declare Entrails =
color_map {
[0.00 rgbf <0.20, 0.00, 0.50, 0.00>]
[0.10 rgbf <0.99, 0.81, 0.00, 0.65>]
[0.20 rgbf <0.99, 0.81, 0.00, 0.65>]
[0.30 rgbf <0.98, 0.48, 0.00, 0.85>]
[0.45 rgbf <0.98, 0.30, 0.00, 0.85>]
[0.65 rgbf <0.96, 0.16, 0.00, 0.95>]
}
#declare n = 1;
blob
{
threshold 0.6
#while (n < 300)
sphere
{
VRand_On_Sphere(RdmA),
RRand(0.1, 0.5, RdmA),
0.4
}
#declare n = n + 1;
#end
texture
{
pigment
{
marble
color_map { Entrails }
turbulence 1.0
scale 0.3
rotate 90 * z
}
finish { ambient 0.1 diffuse 0.5 phong 0.75 }
}
normal
{
marble
turbulence 1.0
scale 0.3
rotate 90 * z
}
}
<End of Source>
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
A J Le Couteur Bisson wrote:
>Hi
>I'm new to this group (but not new to Povray) and I have just started to get
>back
>into raytracing after a long break from it.
Welcome!
>I recently stumbled across this wonderfully revolting texture, a derivative
>of the lightning
>texture, and I thought I would share it with you all. Please don't trace
>this if you
>have a weak stomach! It certainly looks very organic at any rate.
>
As soon as I get home tonight, I'll be testing it out.
<Wonders> Is it better to eat first and have something to throw up, or
suffer the pain of attempting to throw up on an empty stomach </Wonders>
John
--
Run Fast
Run Free
Run Linux
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Doctor John" <jgu### [at] netscape net> wrote >
> As soon as I get home tonight, I'll be testing it out.
>
Yukk!
:-)
Can't think of a use for it ATM, tho'
John
--
Run Fast
Run Free
Run Linux
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
A J Le Couteur Bisson wrote:
> Hi
Hi.
Did someone ask for a brain? (I had the model around, but your texture
inspired me to "spruce up" the pigment.)
// Persistence of Vision Ray Tracer Scene Description File
// File: brainobj.pov
// Vers: 3.5
// Desc: Gimme da brain!
// Date: 03/02/21
// Auth: Tom A.
//
#version 3.5;
#include "colors.inc"
#include "textures.inc"
#include "rand.inc"
global_settings {
assumed_gamma 1.0
}
// ----------------------------------------
camera {
location <0.0, 0.0, -4.0>
direction 1.5*z
right x*image_width/image_height
look_at <0.0, 0.0, 0.0>
}
background { colour White }
light_source {
<0, 0, 0> // light's position (translated below)
color rgb <1, 1, 1> // light's color
translate <-30, 30, -30>
}
// ----------------------------------------
#declare brain1 =
normal {
quilted
turbulence .9
bump_size 1.5
slope_map {
[0 <0, 1>] // start at bottom and slope up
[0.5 <1, 1>] // halfway through reach top still climbing
[0.5 <1,-1>] // abruptly slope down
[1 <0,-1>] // finish on down slope at bottom
} scale <.1,.3,.5>
}
#declare braincoral1 = // long lines, but not much wiggle
normal {
marble turbulence .755
// bump_size 1.5
slope_map {
[0 <0, 1>] // start at bottom and slope up
[0.5 <1, 1>] // halfway through reach top still climbing
[0.5 <1,-1>] // abruptly slope down
[1 <0,-1>] // finish on down slope at bottom
} scale <.1,.3,.5>
}
#declare base = rgb<.7,.55,.45>;
#declare BrainMap =
color_map {
[0.00 rgbf Red]
[0.15 base ]
[0.35 base ]
[0.40 rgbf Red]
[0.45 base ]
[0.65 base ]
[0.70 rgbf Red]
[0.75 base ]
}
#declare pig1 =
pigment
{
marble
color_map { BrainMap }
turbulence 1.0
scale 0.3
rotate 90 * z
}
#declare fin1 = finish { ambient 0.3 diffuse 0.5 phong 0.75 }
#macro brain(norm)
union{
difference{
union{
sphere { 0.0, 1
texture
{ pigment {pig1}
normal{norm }
finish{fin1}
}
scale <.5,1,1> translate<.25,0,0>
}
sphere { 0.0, 1
texture
{ pigment {pig1}
normal{norm }
finish{fin1}
}
scale <.5,1,1> translate<-.25,0,0>
}
}
box{<-2,0,-2>,<2,-2,2>}
}
union{
sphere { 0.0, 1
texture {pigment {pig1} normal{norm } finish{fin1}}
scale <.5,.5,1> translate<.25,0,0>
}
sphere { 0.0, 1
texture {pigment {pig1} normal{norm } finish{fin1}}
scale <.5,.5,1> translate<-.25,0,0>
}
}
union{
sphere { 0.0, 1
texture {pigment {pig1} normal{norm } finish{fin1}}
scale <.35,.5,.5> translate<.15,-.25,.5>
}
sphere { 0.0, 1
texture {pigment {pig1} normal{norm } finish{fin1}}
scale <.35,.5,.5> translate<-.15,-.25,.5>
}
}
}
#end // brain
object{ brain(braincoral1) translate -x+y scale .65 }
object{ brain(braincoral1) rotate y*90 translate -x-y scale .65 }
object{ brain(brain1) translate x+y scale .65}
object{ brain(brain1) rotate y*90 translate x-y scale .65}
--
Tom A.
Abbie Someone. - Igor _Young Frankenstein_
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
