Here's the source for creating a cratered terrain using pigments only. I'll
also post an improved version next...
--
-David
-----------------------------------------
#include "colors.inc"

global_settings {
   hf_gray_16
} //global_settings

camera {
   location <0, 0, -20>
   look_at 0
} //camera

light_source {<0, 20, -100> color White * 1.2}

#local Terrain = object {
   plane {
      z, 0
      texture {
         pigment {
            bumps //Start out with gentle hills
            color_map {
               [0 Black]
               [1 White * 1.2]
            } //color_map
         } //pigment
         scale 5
      } //texture
      texture {
         pigment {
            granite //Roughen up the terrain
            color_map {
               [0 rgbt <0, 0, 0, .9>]
               [1 rgbt <1, 1, 1, .7>]
            } //color_map
         } //pigment
         scale 6
      } //texture
      texture {
         pigment {
            bumps //Add some craters
            color_map {
               [0 rgbt <0, 0, 0, .2>]
               [.25 rgbt <1, 1, 1, .4>]
               [.5 rgbt <0, 0, 0, .8>]
               [.7 rgbt <0, 0, 0, 1>]
               [1 rgbt <0, 0, 0, 1>]
            } //color_map
         } //pigment
         scale 3
      } //texture
   } //plane
} //object

object {Terrain}
-----------------------------------------

Post a reply to this message