// Was "Just playing with radiosity"
// The Orbs
// Copyright (left, up, and down too)
// Anthony L. Bennett
// October 28 - 29, 2002

// INI FILE
// Width=800
// Height=400
// Display_Gamma=1

#version 3.5;

#default {pigment {rgb 1} finish {ambient 0 diffuse 0.8}}

#declare Pass = 2;

global_settings
{
  ambient_light 0
  assumed_gamma 1
  max_trace_level 15
  radiosity
  {
    pretrace_start 1
    pretrace_end   1
    count 200
    nearest_count 5
    error_bound 0.1
    recursion_limit 4
    low_error_factor 0.5
    gray_threshold 0.0
    minimum_reuse 0.015
    brightness 1.0
    adc_bailout 0.01/2
    normal off
    #if (Pass = 1)
      save_file "28102002.rad"
    #else
      load_file "28102002.rad"
      always_sample off
    #end
  }
}

sky_sphere
{
  pigment
  {
    planar
    color_map {[0 rgb 1][1 rgb <1,2,3>/3]}
  }
}

camera
{
  up y right x*2
  location <1,1,-1.1>*9
  look_at 0
  // Focal blur may be unnecessary for
  // the first pass, I'm not sure.
  focal_point vrotate(<0,2.6,9>,y*60)
  aperture 0.9
  #if (Pass = 1)
    blur_samples 15
  #else
    blur_samples 150
  #end
  confidence 0.9999999
  variance   0.0000001
}

light_source
{
  <-10,15,-10> <1,1,0.5>*0.55
  area_light x,z 5,5
  circular orient
}

plane {y,0 finish {brilliance 0}}

#declare Reflective_Black =
texture
{
  pigment {rgb 0.01}
  #if (Pass = 2)
  finish
  {
    reflection {4,5 fresnel metallic}
    irid {0.4 thickness 0.8 turbulence 0.05}
  }
  #end
}

#declare BlurAmount = 0.2;
#declare BlurSamples = 10;

#declare Blurred_Reflective_Black =
texture
{
  average texture_map
  {
    #declare Ind = 0;
    #declare S = seed(7);
    #while(Ind < BlurSamples)
      [1 Reflective_Black
         normal
         {
           bumps BlurAmount
           translate <rand(S),rand(S),rand(S)>*10
           scale 1000
         }
      ]
      #declare Ind = Ind+1;
    #end
  }
}

#declare Egg =
difference
{
  sphere {0,2 scale <1,1.3,1>}
  sphere {0,2 translate y-z}
}

#declare J = 0;
#while (J < 360)
object
{
  Egg
  texture {Reflective_Black}
  // Blurred version way too slow on my puny 1.6GHz P4m.
  //texture {Blurred_Reflective_Black}
  interior {ior 1.5}
  translate <0,2.6,10>
  rotate y*J
}
#declare J = J + 60;
#end

--
Anthony Bennett

Post a reply to this message