As requested by Tim Nikias

// Begin POV code
// Persistence of Vision Ray Tracer Scene Description File
// File: Sphere Room.pov
// Vers: 3.5
// Desc: Basic Scene Example
// Date: 04/04/02
// Auth: Andrew Cocker
//
// Excuse messy code ;-)

// +h480 +w960

#version 3.5;

#include "colors.inc"
#include "textures.inc"

#declare RadOn=1;
#declare FocBlur=1;
#declare Sky=1;

global_settings {
  assumed_gamma 1.0
  #if (RadOn)
        radiosity{
        pretrace_start 1
        pretrace_end   1
        count 700
        nearest_count 10
        error_bound 0.1
        recursion_limit 3
        low_error_factor 1
        gray_threshold 0.5
        minimum_reuse 0.015
        brightness 1.2

        }
#end
}

// ----------------------------------------
#if (Sky)
sky_sphere{
 pigment{
  gradient y  color_map{
   [0 White*1][1 SummerSky]
  }
   translate -z*0.5 scale 2
   }
}

#end



camera {
  location  <2,5,-14>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0,2,0>

#if (FocBlur)
  focal_point <0,0.8,0>
  aperture 0.3
  blur_samples 40
  variance 0
  confidence 0.9999
#end
}



light_source {
  0*x
  color rgb <1,.8,.6>*8
  area_light
  <2, 0, 0> <0, 0, 2>
  8, 8
  adaptive 0
  jitter
  circular
  orient
  translate <53, 30, 0>
}


plane {
  y, -1.2
  texture {pigment {checker color rgb <1,0.7,0.4>,color rgb <1,0.7,0.4>*.5
scale .5} finish { reflection 0.4 diffuse .5 ambient 0}  }

}

#declare ForRad=
texture {
pigment {rgb 1}
finish { ambient 0.0 }
}

#declare ForRad_Blue=
texture {
pigment {rgb <.6,.6,1>}
finish { ambient 0.0 }
}

#declare Room=
difference{
        union {
        box {<-3.5,-2,-20>,<-3,10,11>} // Left wall
        box {<-3.5,-2,10>,<30,10,11>}// Back Wall
        box {<-4,10,-20>,<16,10.1,11>} // Roof
        box {<8,-2,-20>,<9,3,11>} // Right Side Little Wall
        box {<-3.5,-2,-21>,<20,10,-20>} //Behind Wall
        box {<-3,3,8>,<-1,3.1,10>} // Shelf
        cylinder {<-3.6,1.6,0>,<-2.9,1.6,0>,3.1}
        }
cylinder {<-3.7,1.6,0>,<-2.6,1.6,0>,3}
texture {ForRad }}

#declare Other_Room=
        union {
        box {<-14,-2,10>,<-3.5,10,11>} // Back Wall
        box {<-14,-2,-12>,<-13,10,11>} // Left Wall
        box {<-14,-2,-21>,<-3.5,10,-20>} //Behind Wall
texture { ForRad_Blue}
}

#declare MyThing=
texture {
pigment {rgb 1}
finish { ambient 0 reflection 0 specular 1 roughness 0.005}
}



#declare tt=seed(7);

#declare Lots=
union {
#declare Count=0;
#while (Count<=200)

sphere { 0,0.1 translate <2,0,0> rotate
<rand(tt)*360,rand(tt)*360,rand(tt)*360>
                                pigment { rgb <rand(tt),rand(tt),rand(tt)>}
finish {ambient 0} }
#declare Count=Count+1;
#end
texture { MyThing}
}


#declare SHAPE=
union {
sphere {0,2 }
object {Lots}
texture { MyThing}}

object {SHAPE translate <0,0.8,0>}
object {SHAPE rotate <rand(tt)*360,rand(tt)*360,rand(tt)*360> translate
<5,0.8,6>}
object {SHAPE rotate <rand(tt)*360,rand(tt)*360,rand(tt)*360> translate
<1,0.8,8>}
object {SHAPE rotate <rand(tt)*360,rand(tt)*360,rand(tt)*360> translate
<-6,0.8,2>}
object {SHAPE rotate <rand(tt)*360,rand(tt)*360,rand(tt)*360> scale 0.4
translate <-2,3.8,8.6>}




object {Room}
object {Other_Room}
//End POV Code

Post a reply to this message