#include "colors.inc"
#include "woods.inc"

// #version unofficial megapov 0.6;
#version 3.5;

camera {
 location <-1.5, 1.2, -7>
 look_at < 1.3, 0.4, 4>
 angle 36
}

global_settings {
 max_trace_level 40
 adc_bailout 1/255
 photons {
  spacing 0.004
  radius 0.6
  autostop 0
  jitter 0.75
  max_trace_level 4
 }
}

#declare Jewel = intersection {
 #declare Around=0;
 #while (Around<360)
  plane { x, 1  rotate z*25 rotate y*Around}
  plane { x, 1  rotate z*-45 rotate y*Around}
  plane { x ,1.15 rotate y*Around}
  #declare Around=Around+(360/7);
 #end
 bounded_by {cylinder {<0,-2,0>,<0,2,0>,1.5}}
 translate <0 ,2*sin(45), 0>
}

// scene

box {
 <-50,-8,15>,<50,20,15.5>
 pigment {White}
}

cylinder {
 <0,-0.1,-1>,<0,0.1,-1>,3
 texture {T_Wood28 rotate y*-67 translate <50,0,-10> scale 2.5}
}

union {
 object {
  Jewel
  photons { target reflection on refraction on}
  material {
   texture  {
    pigment {rgbf <0.9,0.9,1,0.975>}
    finish {
     specular 0.25
     roughness 0.02
     //reflection_type 1
     //reflection_max 0.35
     //reflection_min 0
     reflection {0 0.35 fresnel}
     conserve_energy
    }
   }
   interior {
    ior 1.9
    dispersion 1.05
    //disp_nelems 17
    dispersion_samples 17
   }
  }
  rotate y*41
  scale 0.1
  translate y*1.94
 }
 cylinder {
  <0,0,0>,<0,2,0>,0.065
  pigment { rgb<0.60, 0.35, 0.20>}
 }
 rotate z*-90
 rotate y*-20
 rotate z*20
 translate <-1.5,0.6,-2.5>
}

light_source {
 vrotate (<2.25,0,0>,<0,-20,20>)+<-1.5,0.6,-2.5>
 color White*0.75
 photons {
  reflection on
  refraction on
 }
 fade_distance 15
 fade_power 2
}

light_source {
 vrotate (<2.25,0,0>,<0,-20,10>)+<-1.5,0.4,-2.5>
 color White*0.45
 photons {
   reflection off
   refraction off
 }
 fade_distance 15
 fade_power 2
}

// scene end

Gail
--
#macro G(H,S)disc{0z.4pigment{onion color_map{[0rgb<sin(H/pi)cos(S/pi)*(H<6)
cos(S/pi)*(H>6)>*18][.4rgb 0]}}translate<H-5S-3,9>}#end G(3,5)G(2,5.5)G(1,5)
G(.6,4)G(.5,3)G(.6,2)G(1,1)G(2,.5)G(3,.7)G(3.2,1.6)G(3.1,2.5)G(2.2,2.5)G(9,5
)G(8,5.5)G(7,5)G(7,4)G(7.7,3.3)G(8.3,2.7)G(9,2)G(9,1)G(8,.5)G(7,1)//GS

Post a reply to this message