One of the features not included in 3.5 were glows. Of course it's a pitty
because they are so useful, but the code was so incomplete and it was such
a late addition that it wasn't included.
  If you miss glows but want to use 3.5 anyways, you can replace them with
media.
  Of course using media is a lot slower (because media sampling is slower and
because the containers increase the need of a high max_trace_level), so
forget adding tens of thousands of glows to your scene, but at least you
can get something.
  Here is an example of how to achieve this:

----------8<------------8<-------------8<-------------8<-------------8<-----
#macro Glow(GlowColor, Scale)
  sphere
  { 0, 1 hollow no_shadow
    pigment { rgbt 1 }
    interior
    { media
      { emission 1/Scale
        density
        { spherical density_map
          { [0 rgb 0][.5 rgb GlowColor*.5][1 rgb 1]
          }
        }
        samples 1,1 intervals 1 confidence .1 // quite fast settings
        method 3
      }
    }
    scale Scale
  }
#end

camera { location -z*10 look_at 0 angle 35 }
plane { y,-2 pigment { checker rgb 1, rgb .5 } }

light_source
{ <-1.5,1,0>, <1,.5,0>
  looks_like { Glow(<1,.5,0>, .5) }
}
light_source
{ <2,.5,0>, <0,.5,1>
  looks_like { Glow(<0,.5,1>, 1) }
}
----------8<------------8<-------------8<-------------8<-------------8<-----

-- 
#macro N(D,I)#if(I<6)cylinder{M()#local D[I]=div(D[I],104);M().5,2pigment{
rgb M()}}N(D,(D[I]>99?I:I+1))#end#end#macro M()<mod(D[I],13)-6,mod(div(D[I
],13),8)-3,10>#end blob{N(array[6]{11117333955,
7382340,3358,3900569407,970,4254934330},0)}//                     - Warp -

Post a reply to this message

Yeah ! Good ! Thanks

--
Martial
http://martial.rameaux.free.fr

Post a reply to this message

news:3ba1fac9@news.povray.org...
>   One of the features not included in 3.5 were glows. Of course it's a
pitty
> because they are so useful, but the code was so incomplete and it was such
> a late addition that it wasn't included.
>   If you miss glows but want to use 3.5 anyways, you can replace them with
> media.
> ............
>   Here is an example of how to achieve this:

Thanks Warp !, I've tried it and works fine. Now we have "glows" also in
3.5.

Txemi Jendrix

Post a reply to this message

I have liked the fade_power option in glows, and a simple modification
of the macro accomodates this. Excellent idea Warp.

MJL

#macro Glow(GlowColor, Fade_Power, Scale)
  sphere
  { 0, 1 hollow no_shadow
    pigment { rgbt 1 }
    interior
    { media
      { emission 1/Scale
        density
        { spherical poly_wave Fade_Power density_map
          { [0 rgb 0][1 rgb GlowColor]
          }
        }
        samples 1,1 intervals 1 confidence .1 // quite fast settings
        method 3
      }
    }
    scale Scale
  }
#end

Post a reply to this message

thanks and i have a question!! this is only for lights.. is there a way for
making surface glow over objects??

Post a reply to this message

ahmet oktar <ahm### [at] yahoocom> wrote:
: thanks and i have a question!! this is only for lights.. is there a way for
: making surface glow over objects??

  You can make instances of the glows alone like this:

object { Glow(<0,.5,1>, 1) translate whatever }

or attach it to an object like:

union
{ object { MyObject }
  object { Glow(<0,.5,1>, 1) }
  translate whatever
}

  And you can of course scale and rotate glows as well.

-- 
#macro N(D,I)#if(I<6)cylinder{M()#local D[I]=div(D[I],104);M().5,2pigment{
rgb M()}}N(D,(D[I]>99?I:I+1))#end#end#macro M()<mod(D[I],13)-6,mod(div(D[I
],13),8)-3,10>#end blob{N(array[6]{11117333955,
7382340,3358,3900569407,970,4254934330},0)}//                     - Warp -

Post a reply to this message

In article <3ba1fac9@news.povray.org>, "Warp" <war### [at] tagpovrayorg> wrote:
Hi, I am running pov-ray 3.1, and it bombs on teh method 3 command in the
macr below.

Is this a failing of 3.1 or is somethng else wrong?

> ----------8<------------8<-------------8<-------------8<-------------8<-----
> #macro Glow(GlowColor, Scale)
>   sphere
>   { 0, 1 hollow no_shadow
>     pigment { rgbt 1 }
>     interior
>     { media
>       { emission 1/Scale
>         density
>         { spherical density_map
>           { [0 rgb 0][.5 rgb GlowColor*.5][1 rgb 1] }
>         }
>         samples 1,1 intervals 1 confidence .1 // quite fast settings
>         method 3
>       }
>     }
>     scale Scale
>   }
> #end
> 
> camera { location -z*10 look_at 0 angle 35 } plane { y,-2 pigment {
> checker rgb 1, rgb .5 } }
> 
> light_source
> { <-1.5,1,0>, <1,.5,0>
>   looks_like { Glow(<1,.5,0>, .5) }
> }
> light_source
> { <2,.5,0>, <0,.5,1>
>   looks_like { Glow(<0,.5,1>, 1) }
> }
> ----------8<------------8<-------------8<-------------8<-------------8<-----
> 


-- 

  Rob Brown-Bayliss
 ---======o======---

Post a reply to this message

The media "methods" are not supported in 3.1. Either use the beta of 3.5 or
wait until it's final release. You could also use MegaPov from Nathan Kopp
 http://nathan.kopp.com/patched.htm) but if you choose this option, you can
as well use the real "glows" instead of this macro.

HTH,

Marc-Hendrik

Rob Brown-Bayliss schrieb in Nachricht <3bb9942c@news.povray.org>...
>In article <3ba1fac9@news.povray.org>, "Warp" <war### [at] tagpovrayorg> wrote:
>Hi, I am running pov-ray 3.1, and it bombs on teh method 3 command in the
>macr below.

Post a reply to this message

Rob Brown-Bayliss <on_### [at] clearnetnz> wrote:
: Hi, I am running pov-ray 3.1, and it bombs on teh method 3 command in the
: macr below.

  Did you read the subject of my message?

  Ok, it doesn't *technically* say that it's a 3.5 macro, but I think it
implies it well enough.

-- 
#macro N(D,I)#if(I<6)cylinder{M()#local D[I]=div(D[I],104);M().5,2pigment{
rgb M()}}N(D,(D[I]>99?I:I+1))#end#end#macro M()<mod(D[I],13)-6,mod(div(D[I
],13),8)-3,10>#end blob{N(array[6]{11117333955,
7382340,3358,3900569407,970,4254934330},0)}//                     - Warp -

Post a reply to this message

You can also try and disect this and see if you can come up with anything(Hint,
start at the pigment statement):

--
/* Nekar Xenos */#local N=<-20,40,100>;#local K=<20,-40,100>;#local R=seed(0);
blob{#while((K-N).x>0)#local X=N;#local N=N+<rand(R),rand(R),1>/3;#local N=(
vlength(N-K)<vlength(X-K)?N:2*X-N);sphere{<N.y,-N.x,N.z>,1,1 scale .02}sphere{N
,1,1 scale.02}sphere{<-N.x-40,N.y,N.z>1,1 scale.01}sphere{<N.x+40,-N.y,N.z>1,1
scale.01 }#end pigment{rgbt 1}interior{media{emission <2,4,5>*5}}hollow}

Post a reply to this message