// Persistence of Vision Ray Tracer Scene Description File
// File: sun behind cloud.pov
// Vers: MegaPOV 0.7 (POV-Ray 3.1g if media method 2 removed)
// Desc: sunlight shining from behind a single cloud
// Date: 01.55
// Auth: Bob Hughes
// Mail: omn### [at] charternet?Subject=POV-Scene
// Note: this scene is oriented so as to look straight up (y axis)

/* Set the Sun color */

// choose preset sunlight color
#declare SL=2;
#switch (SL)
 #case (0)
  #declare SLC=1; // white
 #break
 #case (1)
  #declare SLC=<1.5,.75,.25>; // very red (sunset?)
 #break
 #case (2)
  #declare SLC=<1.5,1,.5>; // red (late afternoon?)
 #break
 #case (3)
  #declare SLC=<1.25,1,.75>; // orange (early morning?)
 #break
 #case (4)
  #declare SLC=<1.125,1.125,.75>; // yellow (noon sun?)
 #break
 #case (5)
  #declare SLC=<.75,1.25,.75>; // green (?)
 #break
 #case (6)
  #declare SLC=<.75,1,1.25>; // blue (?)
 #break
 #case (7)
  #declare SLC=<1.125,.75,1.125>; // violet (?)
 #break
#end

global_settings {
        assumed_gamma 2.1
        ambient_light 1
        radiosity {}
}

union {

light_source { // sunlight
  0,SLC
  looks_like {disc {0,y,1,0 pigment {onion color_map {
        [.75 rgb SLC*3]
        [1 rgbt 1]
        }}
   finish {ambient SLC*2} scale 20 hollow}}
 // media_attenuation on // slow
 translate 777*y rotate <-5,0,-20>
}

plane {y,999 // sky (for diffusion around light source)
   pigment {rgb <.3,.5,.8>}
   finish {ambient .7 diffuse 2}
 hollow
}

  rotate 0*x
}

camera {location -111*y angle 60 look_at y}

    media { // atmosphere (more diffusion, shadow of cloud)
        method 2 // remove if using official version
      absorption <.15,.1,.075>/4
      scattering {1,<.03,.025,.02> extinction .9}
      intervals 6
      samples 1, 9
      density {
        gradient y
        density_map {
          [0 rgb <.25,.2,.15>]
          [.15 rgb 0]
        } translate -.1*y scale 1111
      }
    }

// cloud
#declare D1=
  density {
    spherical
    color_map {
      [0 color rgb 0]
      [.05 color rgb .05]
      [.1 color rgb .1]
    } turbulence .5 scale .9
  }

#declare D2=
  density {
    spherical
    color_map {
      [0 color rgb 0]
      [.05 color rgb .025]
      [.1 color rgb .075]
    } turbulence .25 scale .9
  }

sphere {0,2
  pigment {rgbf 1}
  finish {ambient 0 diffuse 0}
  interior {
    media {
        method 2 // remove if using only official version
      emission .15
      absorption <.3,.4,.39>
      scattering {5,.2 eccentricity .67}
      intervals 6
      samples 1, 9
      density {
        boxed
        density_map {
          [.45 D1]
          [.55 D2]
        } turbulence .125
      }
    }
  }
  scale 33
 hollow
}

Post a reply to this message