// Persistence of Vision Ray Tracer Scene Description File
// File: media clouds test scene
// Vers: MegaPOV
// Desc: Some nice fluffy media clouds,
// Desc: I'm still working on some stormy weather ones
// Date: 20-11--00
// Auth: Kevin Ellis
// Mail: kev### [at] libertysurfcouk
// Webp: http://web.libertysurf.co.uk/kevin.ellis

#version unofficial MegaPov 0.6;

#declare Rad=1;

global_settings {

  #if(Rad)
  ini_option "+QR"

  radiosity{
    pretrace_start 0.08
    pretrace_end   0.04
    count 40             // CHANGE range from 20 to 150
    nearest_count 5      // CHANGE range from 3 to 10
    error_bound 0.1        // CHANGE - range from 1 to 3 - should correspond
with pretrace_end
                         // you can go lower than 1, but then you probably
will want to set
                         // pretrace_end to 0.01, which is really slow
    recursion_limit 1    // CHANGE

    low_error_factor .5  // leave this
    gray_threshold 0.0   // leave this
    minimum_reuse 0.015  // leave this
    brightness 0.5         // leave this

    adc_bailout 0.01/2   // CHANGE - use adc_bailout = 0.01 /
brightest_ambient_object
    normal on
    media on
  }
  ambient_light 0

  #end

  max_trace_level 10

}

#declare Clouds=
box {
  <-30000,700,-30000>
  <30000,900,30000>
  material {
    texture {
      pigment {
        rgbf 1
      }
    }
    interior {
      media {
        scattering {5, 0.0045 extinction 1 eccentricity 0.1}
        method 2
        intervals 20
        aa_level 4
        jitter 0.1
        density {
          wrinkles
          octaves 4
          lambda 1
          omega .5
          turbulence .1
          color_map{
           [0.0 rgb 0]
           [0.55 rgb 0]
           [0.55 rgb 1]
           [1.0 rgb <1,1,1.1> ]
          }
          translate <0,800,0>
          scale <500*1.2,500,500*1.2>
        }
      }
    }
  }
  hollow
  scale 0.8
}

object {Clouds}

fog {
  fog_type 2
  distance 2000
  fog_offset 0
  fog_alt 400
  color rgb <0.8,0.85,0.9>
}


camera {
  location <0,5,0>
  look_at <0,4,100>
}

light_source {
  <20000,20000000,-10000>
  color rgb <1,0.94,0.9>*1.5
  media_attenuation on
  media_interaction on
}

sky_sphere {
  pigment {rgb <0.5,0.7,0.8>}
}

Post a reply to this message