// Persistence of Vision Ray Tracer Scene Description File
// File: galileo thermometer.pov
// Vers: MegaPov 0.6a
// Desc: A Galileo thermometer, with lathe "bug" perhaps as noted by KalleK in p.b.i.
group
// Date: 2000.87
// Auth: Bob Hughes
// Note: checkered plane for floor is speckled for unknown reason. Beware: Slow to
render!

#version unofficial MegaPov 0.6;

global_settings {
        assumed_gamma 2.4
        max_trace_level 16
}

light_source { <500,1000,-750> color rgb <1,1.1,1.125>}
light_source { <-25,150,50> color rgb <.5,.33,.25> shadowless}

camera
{
  location  <0,7.5,-30>
  angle 34
  look_at   <0,5.75,0>
  rotate -5*y
}

/*
// a heat wave effect (not any good)

#declare HotWave=
texture {pigment {rgbf 1} normal {wrinkles .8} scale .01}
#declare CoolWave=
texture {pigment {rgbf 1} normal {wrinkles .2} scale .015}
#declare NoWave=
texture {pigment {rgbf 1} normal {wrinkles 0} scale 1}

plane {z,-25
        material {
        texture {gradient y texture_map {
                [.05 HotWave] [.33 CoolWave] [.5 NoWave]
        } scale 2.5 translate -1.75*y}
        interior {ior 1.01}
        }
   rotate -5*y
}
*/

// problem with this part?
plane {y,-.01 pigment {checker color rgb .67 color rgb .75 scale 10}
 clipped_by {box {<-100,-1,-100>,<100,1,100>}}
}

sky_sphere // rain shower clouds
{
    pigment
  {
    gradient y
    color_map { [0 color rgb<.7,.8,.9>] [.1 color rgb<.1,.5,.9>] }
  }
    pigment
  {
    bozo  turbulence .7
 color_map {
 [0.0,0.4 color rgbt<.6,.65,.675,0> color rgbt<.65,.65,.675,.7>]
 [0.4,0.5 color rgbt<.65,.65,.675,.7> color rgbt<1,1,1,1>]
 [0.5,0.7 color rgbt<1,1,1,1> color rgbt<1,1,1,1>]
 [0.7,1 color rgbt<.9,.925,.975,.8> color rgbt<.925,.95,.95,0>]
  } scale <1,.33,2>
  }
    pigment
  {
    granite  turbulence .1
 color_map {
 [0.0,0.4 color rgbt<.3,.35,.375,0> color rgbt<.35,.325,.375,.9>]
 [0.4,0.5 color rgbt<1,1,1,1> color rgbt<1,1,1,1>]
 [0.5,0.7 color rgbt<1,1,1,1> color rgbt<1,1,1,1>]
 [0.7,1 color rgbt<.55,.525,.6,.8> color rgbt<.5,.525,.55,0>]
  } scale <1,1.25,2>
  }
    pigment
  {
    gradient y
    color_map { [0 color rgbt<.725,.7,.8,.6>] [1 color rgbt<.9,.925,.95,.9>] }
  }
}

// bright single rainbow
  rainbow {
    direction <.1,-.36,.8>
    angle 30
    width 5
    distance 15
    color_map {
  [0.0,0.19 color rgbt<2,0,2,1> color rgbt<0,0,3,.975> ]
  [0.19,0.33 color rgbt<0,0,3,.975> color rgbt<0,2,2,.925> ]
  [0.33,0.475 color rgbt<0,2,2,.925> color rgbt<0,3,0,.95>]
  [0.475,0.6 color rgbt<0,3,0,.95> color rgbt<2,2,0,.925>]
  [0.6,0.75 color rgbt<2,2,0,.925> color rgbt<2.5,1.5,0,.9125>]
  [0.75,1.0 color rgbt<2.5,1.5,0,.9125> color rgbt<3,0,0,1>]
 }
    jitter 0.02
    up <0,1,-.2>  // 1*y is normal up (any x or z value will tilt)
    arc_angle 100
    falloff_angle 40
  }

// end sky

#declare Outside=
lathe {
  cubic_spline
  11,
  <0, 0>, <1.5, .0125>, <1.1, .05>, <1, .15>, <1, .95>, <.85, 1.075>, <.5, 1.1125>,
<.2, 1.133>, <.1, 1.145>,
<.005, 1.16>, <0, 1.167>
 // sturm
}

#declare Inside=
lathe {
  cubic_spline
  12,
  <0, .067>, <0, .05>, <.9, .03>, <.9, .05>, <.9, .15>, <.9, .9333>, <.775, 1.06>,
<.475, 1.09>, <.175, 1.1>,
<.08, 1.125>, <.005, 1.133>, <0, 1.15>
 // sturm
}

#declare GlassTubeAndLiquid=
union {
//intersection {
difference {
        object {Outside}
        object {Inside}
 texture {
 pigment {rgbft <.975,.9825,.99,.95,.075>}
 normal {wrinkles .008 scale .12}
 finish {ambient 0 diffuse .05 specular .8 roughness .0025
         reflection_type 1 reflection_min .0333 reflection_max .333
         conserve_energy
         }
 }
 interior {ior 1.5 caustics 1 fade_distance .75 fade_power 1 fade_color <.6,.7,.67>
        dispersion 1.1 disp_nelems 9 }
  scale <1,10,1>
}

difference {
object {Inside scale 1.001}
superellipsoid {<1,.15> scale 1.0225 rotate 90*x translate 2.02*y}
 texture {
 pigment {rgbft <.99,.99,.99,.925,.125>}
 finish {ambient 0 diffuse .025 specular .6 roughness .005
         reflection_type 1 reflection_min .005 reflection_max .15
         conserve_energy
         }
 }
 interior {ior 1.35 caustics 1 fade_distance .5 fade_power 1 fade_color <.67,.67,.6>
        dispersion 1.05 disp_nelems 9 }
  scale <1,10,1>
}
}

GlassTubeAndLiquid


#declare Temp60Tab=
difference {
union {
        torus {.123,.02 rotate 90*z translate -.85*y
     pigment {rgb <.9,.7,.5>*1.5}
                }
        cylinder {-.025*z,.025*z,.234 translate -1.125*y}
}

text {ttf "arialbd.ttf", "60", .0333, 0 align_center
        pigment {rgb <.8,.825,.825>}
         scale .3 translate <0,-1.23,-.0251>}

     pigment {rgb <.9,.9125,.925>*1.5}
      finish {ambient .05 diffuse .5 specular .75 roughness .025 metallic brilliance 1
reflection .125}
}

#declare Temp65Tab=
union {
        torus {.123,.02 rotate 90*z translate -.85*y
     pigment {rgb <.9,.7,.5>*1.5}
                }
difference {
        cylinder {-.025*z,.025*z,.234}
text {ttf "arialbd.ttf", "65", .0333, 0 align_center
        pigment {rgb <.8,.825,.825>}
         scale .3 translate <0,-.13,-.0251>}
 rotate -7.5*x translate -1.125*y
}
     pigment {rgb <.9,.9125,.925>*1.5}
      finish {ambient .05 diffuse .5 specular .75 roughness .025 metallic brilliance 1
reflection .125}
}

#declare Temp70Tab=
union {
        torus {.123,.02 rotate 90*z translate -.85*y
     pigment {rgb <.9,.7,.5>*1.5}
                }
difference {
        cylinder {-.025*z,.025*z,.234}
text {ttf "arialbd.ttf", "70", .0333, 0 align_center
        pigment {rgb <.8,.825,.825>}
         scale .3 translate <0,-.13,-.0251>}
 rotate 10*x translate -1.125*y
}
     pigment {rgb <.9,.9125,.925>*1.5}
      finish {ambient .05 diffuse .5 specular .75 roughness .025 metallic brilliance 1
reflection .125}
}

#declare Temp75Tab=
difference {
union {
        torus {.123,.02 rotate 90*z translate -.85*y
     pigment {rgb <.9,.7,.5>*1.5}
                }
        cylinder {-.025*z,.025*z,.234 translate -1.125*y}
}

text {ttf "arialbd.ttf", "75", .0333, 0 align_center
        pigment {rgb <.8,.825,.825>}
         scale .3 translate <0,-1.23,-.0251>}

     pigment {rgb <.9,.9125,.925>*1.5}
      finish {ambient .05 diffuse .5 specular .75 roughness .025 metallic brilliance 1
reflection .125}
}

#declare Temp80Tab=
difference {
union {
        torus {.123,.02 rotate 90*z translate -.85*y
     pigment {rgb <.9,.7,.5>*1.5}
                }
        cylinder {-.025*z,.025*z,.234 translate -1.125*y}
}

text {ttf "arialbd.ttf", "80", .0333, 0 align_center
        pigment {rgb <.8,.825,.825>}
         scale .3 translate <0,-1.23,-.0251>}

     pigment {rgb <.9,.9125,.925>*1.5}
      finish {ambient .05 diffuse .5 specular .75 roughness .025 metallic brilliance 1
reflection .125}
}

#declare Temp85Tab=
difference {
union {
        torus {.123,.02 rotate 90*z translate -.85*y
     pigment {rgb <.9,.7,.5>*1.5}
                }
        cylinder {-.025*z,.025*z,.234 translate -1.125*y}
}

text {ttf "arialbd.ttf", "85", .0333, 0 align_center
        pigment {rgb <.8,.825,.825>}
         scale .3 translate <0,-1.23,-.0251>}

     pigment {rgb <.9,.9125,.925>*1.5}
      finish {ambient .05 diffuse .5 specular .75 roughness .025 metallic brilliance 1
reflection .125}
}

#declare FloatOutside=
lathe {
  cubic_spline
  11,
  <0, 0>, <.001, .001>, <.125, .0225>, <.275, .067>, <.5125, .225>, <.59, .4>, <.567,
.475>, <.45, .67>, <.15,
.825>, <.1, 1>, <0, 1.1>
 // sturm
}

#declare FloatInside=
lathe {
  cubic_spline
  11,
  <0, 0>, <.001, .0025>, <.1125, .025>, <.25, .075>, <.5, .25>, <.55, .4>, <.525,
.425>, <.4, .6>, <.125, .67>,
<.05, .75>, <0, .8>
 // sturm
}

#declare GlassFloatAndLiquid=
union {
difference {
        object {FloatOutside}
        object {FloatInside}
 texture {
 pigment {rgbft <.975,.9825,.99,.875,.075>}
 normal {wrinkles .008 scale .12}
 finish {ambient .5 diffuse 1.1 specular .8 roughness .0025
         reflection_type 1 reflection_min .0333 reflection_max .333
         conserve_energy
         }
 }
 interior {ior 1.5 caustics 1 fade_distance .25 fade_power 1 fade_color <.6,.67,.67>
        dispersion 1.1 disp_nelems 9 }
}

difference {
object {FloatInside scale 1.001}
superellipsoid {<1,.15> scale 1.025/2 rotate 90*x translate -.375*y}
}
  scale <1,1.25,1>*.67
 rotate 180*z

}

union {
object {GlassFloatAndLiquid
 texture {
 pigment {rgbft <.099,.099,.99,.9,.05>}
 finish {ambient 0 diffuse .3 specular .6 roughness .005
         reflection_type 1 reflection_min .0025 reflection_max .125
         conserve_energy
         }
 }
 interior {ior 1.3 caustics 1 fade_distance .25 fade_power 1 fade_color <.1,.1,.8>}
}
 object {Temp60Tab}
      rotate 10*y translate <.25,9,.25>
}

union {
object {GlassFloatAndLiquid
 texture {
 pigment {rgbft <.099,.99,.99,.9,.05>}
 finish {ambient 0 diffuse .3 specular .6 roughness .005
         reflection_type 1 reflection_min .0025 reflection_max .125
         conserve_energy
         }
 }
 interior {ior 1.3 caustics 1 fade_distance .25 fade_power 1 fade_color <.1,.8,.8>}
}
 object {Temp65Tab}
      rotate 5*y    translate <.125,7.25,-.25>
}

union {
object {GlassFloatAndLiquid
 texture {
 pigment {rgbft <.099,.99,.099,.9,.05>}
 finish {ambient 0 diffuse .3 specular .6 roughness .005
         reflection_type 1 reflection_min .0025 reflection_max .125
         conserve_energy
         }
 }
 interior {ior 1.3 caustics 1 fade_distance .25 fade_power 1 fade_color <.1,.8,.1>}
}
 object {Temp70Tab}
      rotate -45*y translate <.125,6,-.125>
}

union {
object {GlassFloatAndLiquid
 texture {
 pigment {rgbft <.99,.99,.099,.9,.05>}
 finish {ambient 0 diffuse .3 specular .6 roughness .005
         reflection_type 1 reflection_min .0025 reflection_max .125
         conserve_energy
         }
 }
 interior {ior 1.3 caustics 1 fade_distance .25 fade_power 1 fade_color <.8,.8,.1>}
}
 object {Temp75Tab}
      rotate 50*y translate <-.25,5,.125>
}

union {
object {GlassFloatAndLiquid
 texture {
 pigment {rgbft <.99,.099,.099,.9,.05>}
 finish {ambient 0 diffuse .3 specular .6 roughness .005
         reflection_type 1 reflection_min .0025 reflection_max .125
         conserve_energy
         }
 }
 interior {ior 1.3 caustics 1 fade_distance .25 fade_power 1 fade_color <.8,.1,.1>}
}
 object {Temp80Tab}
      rotate -40*y translate <-.125,3,-.25>
}

union {
object {GlassFloatAndLiquid
 texture {
 pigment {rgbft <.99,.099,.99,.9,.05>}
 finish {ambient 0 diffuse .3 specular .6 roughness .005
         reflection_type 1 reflection_min .0025 reflection_max .125
         conserve_energy
         }
 }
 interior {ior 1.3 caustics 1 fade_distance .25 fade_power 1 fade_color <.8,.1,.8>}
}
 object {Temp85Tab}
      rotate 20*y translate <.25,1.5,-.125>
}

// omniVerse http://users.aol.com/persistenceofv/all.htm

Post a reply to this message

Hi Bob!

(Thanks! I'll keep that rainbow and skysphere.)

> // problem with this part?
> plane {y,-.01 pigment {checker color rgb .67 color rgb .75 scale 10}
>  clipped_by {box {<-100,-1,-100>,<100,1,100>}}
> }
It's exactly that part. Your plane is too close to the x-z-plane. (if you
change -.01 into -.02 there are no speckles)
Guess:
The checker-pattern changes in the height of 0. If you get too close to this
change, this effect appaers. And because of the 'scale 10' in the
pigmentstatement you are "in reality" 0.001 povunits appart from zero.

I'm a bit astonished at the fact, that the precission problem is that big
(0.001 is a huge number in this case)!

I came across this checkered-precission-problem in former times. When I
layered a checker and a scale-2-checker, the changes where not the same
place. (I made an animation in which I cut a box with a moving plane and the
different scaled checkers jumped in different times.
Once more shall we say: is it a bug?
But my effect was without speckles, maybe the errors got nothing todo with
eachother.

cukk

Post a reply to this message

"KalleK" <kal### [at] gmxde> wrote in message news:3a152b70$1@news.povray.org...
>
> (Thanks! I'll keep that rainbow and skysphere.)

YW

> > // problem with this part?
> > plane {y,-.01 pigment {checker color rgb .67 color rgb .75 scale 10}
> >  clipped_by {box {<-100,-1,-100>,<100,1,100>}}
> > }
> It's exactly that part. Your plane is too close to the x-z-plane. (if you
> change -.01 into -.02 there are no speckles)
> Guess:
> The checker-pattern changes in the height of 0. If you get too close to this
> change, this effect appaers. And because of the 'scale 10' in the
> pigmentstatement you are "in reality" 0.001 povunits appart from zero.

I hadn't thought of that.  Thanks much.

> I'm a bit astonished at the fact, that the precission problem is that big
> (0.001 is a huge number in this case)!

Well, yeah, I knew that number tends to be at a lower limit for some things.  It is
something I try to keep in
mind but I still often use such low scales/numbers in defiance of such limitations. 
Texture is not the usual
thing I consider though, out of habit I guess.

> I came across this checkered-precission-problem in former times. When I
> layered a checker and a scale-2-checker, the changes where not the same
> place. (I made an animation in which I cut a box with a moving plane and the
> different scaled checkers jumped in different times.
> Once more shall we say: is it a bug?
> But my effect was without speckles, maybe the errors got nothing todo with
> eachother.

That is good to know about.  Bad, but good to know.

Bob

Post a reply to this message