// Persistence of Vision Ray Tracer Scene Description File
// File: isowater test scene
// Vers: MegaPOV
// Desc: Ridged Multifractal Isosurfave Water and sand bed
// Date: 5-1--00
// Auth: Kevin Ellis
// Mail: kev### [at] libertysurfcouk
// Webp: http://web.libertysurf.co.uk/kevin.ellis
// Note: This scene looks much better with radiosity turned on
//       The current Radiosity settings are low because of my P133 machine
//       For even more realism add some reflection blur, but only if you
have a cray machine

#version unofficial Megapov 0.6;

#declare Rad=1;  // Radiosity on or off, much, much better with it on

global_settings {

  #if(Rad)
  ini_option "+QR"

  radiosity{  // Low Quality
    pretrace_start 0.08
    pretrace_end   0.04
    count 45             // CHANGE range from 20 to 150
    nearest_count 5      // CHANGE range from 3 to 10
    error_bound 1        // CHANGE range from 1 to 3
    recursion_limit 1    // CHANGE

    low_error_factor .5  // leave this
    gray_threshold 0.0   // leave this
    minimum_reuse 0.015  // leave this
    brightness 1         // leave this

    adc_bailout 0.01/2   // CHANGE use adc_bailout = 0.01 /
brightest_ambient_object
    normal on
    media on
  }
  #end

  max_trace_level 10 // depends on how many 'waves' the ray passes through,
lower values for more vertical viewpoints
}

#if(Rad)
  default {
    finish {ambient 0}
  }
#end

camera {
  location < -0.1863 , 0.566185 ,-0.6 >
  look_at < -0.1863 , 0.466185 , 0 >
  //rotate <0,45,0>
}

light_source {
  <-20000,10000,-3000>
  rgb <1,0.99,0.95>*1.5
}

sky_sphere {
  pigment {rgb <0.4,0.6,0.8>}
}

#macro InvVector(Vector) // Makes Media easier to set up
  <1/(Vector.x),1/(Vector.y),1/(Vector.z)>
#end

#declare Func1=
function {
  "ridgedmf" <0.95,1.2,8,0.9,20>
}

//water

isosurface {
  function
{y-0.013*Func1((x+8)*5,y,(z+8)*5)-0.001*Func1((x+8)*25,y,(z+8)*25)-0.25} //
water plane at a height of y=0.25
  contained_by {
    box {
      <-3000,-1,-3000>
      <3000,0.3,3000>
    }
  }
  material {
    texture {
      pigment {rgbf <1,1,1,0.95>}
      finish {
        reflection_type 1
        reflection_max 0.912
        reflection_min 0.106
        reflection_falloff 2
        conserve_energy
        specular 0.8
        roughness 0.02
        brilliance 3.22
      }
    }
    interior {
      ior 1.33
      media {
        absorption InvVector(<0.2,0.769,0.72>) // Water Color
        method 2
        intervals 1
        density {
          rgb 0.01
        }
      }
    }
  }
  hollow
}

// Sand bed

isosurface {
  function {y-0.006*Func1((x+8)*3,y,(z+8)*3)}  // Sand plane at height y=0
  contained_by {
    box {
      <-3000,-2,-3000>
      <3000,0.05,3000>
    }
  }
  pigment {rgb <0.7,0.69,0.5>*1.6}
  normal {bumps 0.5 scale 0.0001}
  finish {specular 1 roughness 0.02}
}

Post a reply to this message