See corresponding image in povray.binaries.images

#version 3.5;

global_settings{
  assumed_gamma 1
  photons{count 500000}
}

#declare R=seed(12345);

#default{finish{ambient 0}}

camera{
  fisheye
  right x*.5*1.33 up y*.5
  location<0,-20,-100>
  look_at<0,-30,100>
  angle 60
}

sky_sphere{
  pigment{
   spherical scale 2 translate x*1 rotate z*-22
   color_map{[.1 rgb<.4 .3 .4>][.5 rgb 2]}
  }
}

fog{rgb<1 1 1.3> distance 1000 fog_type 2 fog_alt 100 fog_offset 0}

light_source{<2,1,0>*100000,<1.8 1.6 1.1>*1.5 }
light_source{y*100000,<.5 .4 .3>*1.5 shadowless}

#declare large_displacement=
  function{
   pigment{bumps scale<40,40,40>
    translate<150,0,0>
    turbulence .025 lambda 3
    warp{turbulence .3 lambda 1}
    cubic_wave
    color_map{
     #local V=0;
     #while(V<=1)
      #local rv=rand(R)*.1;
      [V rgb V]
      #local V=V+rv;
     #end
    }
   }
  }

#include"functions.inc"

isosurface{
  function{
   y
   +large_displacement(x,0,z).grey*40
   +f_noise3d(x/100,y/2,z/100)*7
  }
  accuracy .001
  evaluate 5,1.3,.95
  contained_by{box{<-1000,-100,-100>,<1000,0,1000>}}
  pigment{
   slope y
   color_map{
    [.6 rgb<.6 .55 .3>]
    [.7 rgb 1]
   }
  }
  normal{
   slope y
   normal_map{
    [.6 crackle -.2 form x*1 scale<1,100,1> accuracy .001]
    [.7 granite .2 scale .5 accuracy .001]
   }
  }
}

-- 
Samuel Benge

stb### [at] hotmailcom

Post a reply to this message