|
 |
Anybody,
I've taken out all the dead wood (forgive the pun) out of the following source,
but I still have a problem rendering this wood texture with v3.5 BETA 6 and BETA
7.
The code below renders the same in v3.1g and MegaPOV v0.7, but v3.5 BETA 6/7 is
different.
However if you add the #version directive, it will render the same, what I
don't understand is why the code below would produce such a difference, I can't
see any specific piece of code that is pre v3.5 only.
Any comments?
Colin ;)
// ======1=========2=========3=========4=========5=========6=========7
camera {
location <-20, 400, -2000>
direction z*3
up y
right x*1.333
look_at <-20, 20, 0>
}
light_source { <220, 700, -1500> color rgb 1 }
light_source { <-1220, 500, -900> color rgb 1 }
light_source { <-200, 250, -900> color rgb 1 }
light_source { <1200, 1200, -900> color rgb 1 }
// ======1=========2=========3=========4=========5=========6=========7
#declare br01 = color rgb <1.00, 0.94, 0.71>;
#declare br02 = color rgb <1.00, 0.88, 0.65>;
#declare br03 = color rgb <0.94, 0.80, 0.59>;
#declare br03 = color rgb <0.94, 0.80, 0.59>;
#declare br04 = color rgb <0.80, 0.69, 0.52>;
#declare br05 = color rgb <0.72, 0.63, 0.46>;
#declare br06 = color rgb <0.78, 0.63, 0.46>;
#declare br07 = color rgb <0.74, 0.59, 0.49>;
#declare br08 = color rgb <0.66, 0.51, 0.41>;
#declare br09 = color rgb <0.61, 0.50, 0.42>;
#declare br10 = color rgb <0.58, 0.45, 0.32>;
#declare br11 = color rgb <0.65, 0.45, 0.32>;
#declare br12 = color rgb <0.65, 0.41, 0.28>;
#declare br13 = color rgb <0.58, 0.41, 0.28>;
#declare br14 = color rgb <0.57, 0.37, 0.24>;
#declare br15 = color rgb <0.60, 0.37, 0.24>;
#declare br16 = color rgb <0.54, 0.35, 0.25>;
#declare br17 = color rgb <0.56, 0.31, 0.21>;
#declare br18 = color rgb <0.45, 0.31, 0.16>;
#declare br19 = color rgb <0.45, 0.31, 0.21>;
#declare br20 = color rgb <0.41, 0.27, 0.17>;
#declare br21 = color rgb <0.40, 0.24, 0.14>;
#declare br22 = color rgb <0.37, 0.24, 0.11>;
#declare br23 = color rgb <0.37, 0.24, 0.18>;
#declare br24 = color rgb <0.34, 0.21, 0.15>;
#declare br25 = color rgb <0.40, 0.21, 0.15>;
#declare br26 = color rgb <0.32, 0.19, 0.07>;
#declare br27 = color rgb <0.30, 0.14, 0.02>;
#declare br28 = color rgb <0.30, 0.14, 0.10>;
#declare br29 = color rgb <0.24, 0.16, 0.12>;
#declare br30 = color rgb <0.25, 0.13, 0.09>;
#declare br31 = color rgb <0.21, 0.09, 0.05>;
// ======1=========2=========3=========4=========5=========6=========7
#declare pop_wood =
texture {
pigment {
marble
turbulence 0.4
color_map {
[0.0 0.2 color br16 color br16]
[0.2 0.4 color br16 color br14]
[0.4 0.6 color br14 color br17]
[0.6 0.8 color br17 color br17]
[0.8 0.9 color br17 color br14]
[0.9 1.01 color br14 color br16]
}
}
finish {
ambient 0.8
phong 0.5
}
scale <13, 13, 1>
}
texture {
pigment {
wood
turbulence 0.5
color_map {
[0.0 0.05 color br25 color br25 filter 0.5]
[0.05 0.2 color br25 filter 0.5 color br21 filter 1.0]
[0.2 0.7 color br21 filter 1.0 color br21 filter 0.8]
[0.7 0.8 color br27 filter 0.7 color br27 filter 1.0]
[0.8 0.9 color br27 filter 1.0 color br27 filter 0.7]
[0.9 1.01 color br27 filter 1.0 color br30 filter 0.5]
}
}
finish {
ambient 0.9
phong 1.0
}
scale <5, 15, 1>
}
// ======1=========2=========3=========4=========5=========6=========7
#declare zeb_wood =
texture {
pigment {
marble
turbulence 0.25
color_map {
[0.0 0.2 color br16 color br16]
[0.2 0.4 color br16 color br14]
[0.4 0.6 color br14 color br17]
[0.6 0.8 color br17 color br17]
[0.8 0.9 color br17 color br14]
[0.9 1.01 color br14 color br16]
}
}
finish {
ambient 0.2
diffuse 0.8
}
scale <13, 13, 1>
}
texture {
pigment {
wood
turbulence 0.3
color_map {
[0.0 0.05 color br25 color br25 filter 0.7]
[0.05 0.2 color br25 filter 0.7 color br21 filter 1.0]
[0.2 0.7 color br21 filter 1.0 color br21 filter 0.8]
[0.7 0.8 color br27 filter 0.7 color br27 filter 1.0]
[0.8 0.9 color br27 filter 1.0 color br27 filter 0.7]
[0.9 1.01 color br27 filter 1.0 color br30 filter 0.7]
}
}
finish {
ambient 0.2
diffuse 0.7
}
scale <5, 15, 5>
}
texture {
pigment {
wood
turbulence 0.2
color_map {
[0.0 0.05 color br25 color br25 filter 0.4]
[0.05 0.2 color br25 filter 0.4 color br21 filter 0.8]
[0.2 0.7 color br21 filter 0.8 color br21 filter 0.9]
[0.7 0.8 color br27 filter 0.8 color br27 filter 0.6]
[0.8 0.9 color br27 filter 0.6 color br27 filter 0.4]
[0.9 1.01 color br27 filter 0.5 color br30 filter 0.8]
}
}
finish {
diffuse 0.7
ambient 0.2
}
scale <4, 20, 4>
}
// ======1=========2=========3=========4=========5=========6=========7
#declare WT =
texture {
zeb_wood
finish {
phong 0.25
phong_size 50
reflection 0.3
}
scale <15, 35, 20>
}
// ======1=========2=========3=========4=========5=========6=========7
#declare Plank1 =
object {
box { -1, 1 }
scale <30, 450, 10>
texture { WT }
}
#declare Plank2 =
object {
box { -1, 1 }
scale <30, 450, 10>
texture {
WT
rotate z*10
translate <20, 100, 10>
}
}
#declare Plank3=
object {
box { -1, 1 }
scale <30, 450, 10>
texture {
WT
rotate z*-5
translate <10, -30, 5>
}
}
#declare Plank_A =
union {
object { Plank1 }
object { Plank2 translate y*902 }
object { Plank3 translate y*-902 }
}
#declare Plank_B =
union {
object { Plank3 }
object { Plank1 translate y*902 }
object { Plank2 translate y*-902 }
}
#declare Plank_C =
union {
object { Plank2 }
object { Plank3 translate y*902 }
object { Plank1 translate y*-902 }
}
// ======1=========2=========3=========4=========5=========6=========7
object {
union {
object { Plank_A rotate x*90 translate <-74, -10, -538> }
object { Plank_B rotate x*90 translate <-136, -10, -438> }
object { Plank_C rotate x*90 translate <-198, -10, -338> }
object { Plank_B rotate x*90 translate <-260, -10, -38> }
}
rotate y*-30
}
Post a reply to this message
|
|
