// BEGIN pov-code  

// Persistence of Vision Ray Tracer Scene Description File
// File: rad_iso_01a.pov
// Desc: isosurface & radiosity test
// Date: July 2001
// Auth: Christoph Hormann 

#version unofficial MegaPov 0.7;  
          
global_settings {    
  assumed_gamma 1.0
         
  radiosity {
    pretrace_start 0.08
    pretrace_end 0.004
    count 300
    error_bound 0.1      
    recursion_limit 1   
    
    low_error_factor .5 
    gray_threshold 0.0  
    minimum_reuse 0.015  
    brightness 1       
    
    adc_bailout 0.01/2 
  }     
} 
                                       
camera {
  location  <10.0, 10.0, 2.0> 
  direction y
  sky       z
  up        z
  right     x*1.333333
  look_at   <0.0, 0.0, 1.0>  
  angle     40.0      
}                        

// Based on Kari Kivisalo's lighting configuration
// modified in both color and intensity

#macro G(Color,g)
  rgb<pow(Color.x,g),pow(Color.y,g),pow(Color.z,g)>
#end


#declare Gamma=2.2;
#declare SkyColor=G(<132,164,255>/255,Gamma);  // @ 15000K rgb white=6500K
//#declare SunColor=G(<255,235,197>/255,Gamma);  // @ 5400K  rgb
white=6500K
#declare SunColor=G(<255,184,130>/255,Gamma);  // changed   

#declare EnergyRatio=9;  // sun/sky energy ratio
#declare EQ=1.18;        // normalisation for sun-sky colors

   
light_source {     
  <-8000.0, 8000.0, 4000.0>
  color rgb 0.5*SunColor*EnergyRatio/EQ   // changed  
  area_light 90*x 90*y  5,5 
  jitter 
  orient   
}           


#declare Sky_Bckg_12 = texture {
   pigment {
     gradient z
     color_map {         
       [0.40 color rgb < 0.880, 0.935, 0.976 >]
       [0.95 color rgb < 0.400, 0.500, 0.900 >]   
     }   
   }
   finish {
     diffuse 0
     ambient 1
   }       
   rotate 27*x       
}    

                 
sphere { 
  <0, 0, 0>, 1      
  texture { 
     Sky_Bckg_12     
  }  
  scale<100000, 100000, 20000>     
  no_shadow 
  hollow on 
}                 
     

#declare fn_sphere=function{"sphere",<0.2>}  

#declare fn_Noise=function {
  pigment {
    agate
    color_map {
      [0 rgb 0]
      [1 rgb 1]
    }              
    translate -0.25*z
  }
}

  
#declare Mountains_01=        
isosurface{
  function {
    ((1+0.1)
     - 0.1^(fn_sphere(x, y, z-0.3))
     - 0.1^(z)) - (fn_Noise(x*3,y*3,z*3))*0.26
  }  
  method 2    
  //eval 
  max_gradient 20 
  accuracy 0.001  
  contained_by{box{<-2.7, -2.7, -0.1>, <1.7, 1.7, 1>}}                
  texture {
    pigment { color rgb <0.78, 0.58, 0.42> }  
    finish { ambient 0.0 diffuse 0.6 }
  } 
  scale 5
}   

object { Mountains_01 }    
                                  
// END pov-code          

-- 
Christoph Hormann <chr### [at] gmxde>
IsoWood include, radiosity tutorial, TransSkin and other 
things on: http://www.schunter.etc.tu-bs.de/~chris/

Post a reply to this message