This is the pigment code for the pictures posted in p.b.i.

You can play around with nearly everything in those pigments to get new
interesting results.  

Christoph

// Begin POV-Code

// Christoph Hormann, December 2000 <chr### [at] gmxde>
     
#declare P_Base_1=      
    pigment {        
      spherical   
      scallop_wave
      pigment_map {         
        [ 0.00 quilted 
               color_map {        
                 [ 0.0 color rgb<0.100, 0.000, 0.200> ] 
                 [ 0.3 color rgb<0.000, 0.000, 0.300> ]   
                 [ 0.6 color rgb<0.000, 0.000, 0.000> ]
               } 
               scale 0.8                   
        ] 
        [ 0.005 quilted 
               color_map {
                 [ 0.0 color rgb<0.200, 0.100, 0.500> ]   
                 [ 1.0 color rgb<0.000, 0.000, 0.100> ]
               }  
               scale 0.8
        ]  
        [ 0.50 quilted 
               color_map {
                 [ 0.0 color rgb<1.000, 0.456, 0.456> ]   
                 [ 1.0 color rgb<0.000, 0.000, 0.100> ]
               }   
               scale 0.8
        ]  
        [ 0.60 quilted 
               color_map {
                 [ 0.0 color rgb<0.256, 0.230, 0.800> ]   
                 [ 1.0 color rgb<0.000, 0.000, 0.100> ]
               }   
               scale 0.8
        ] 
        [ 0.80 quilted 
               color_map {
                 [ 0.0 color rgb<1.000, 0.800, 0.200> ]   
                 [ 1.0 color rgb<0.000, 0.000, 0.100> ]
               }   
               scale 0.8
        ]       
      }
      scale 5.4
    }     
    
    

#declare P_Warped_1=  
    pigment {       
      P_Base_1       
      
      warp {
        black_hole 0, 3
        strength 1
        falloff 3 
      }    
      warp {
        black_hole 0, 4
        strength 1
        falloff 3 
      }
      warp {
        black_hole 0, 5
        strength 1
        falloff 3 
      }                   
                            
      warp {
        displace {  
          spiral1 6  
          sine_wave 
          color_map {
            [0.0 color rgb -10 ] 
            [1.0 color rgb 16 ]  
          } 
          scale 5            
          type 1
        }  
      }   
          
      warp {
        displace {  
          spiral1 6  
          sine_wave 
          color_map {
            [0.0 color rgb -10 ] 
            [1.0 color rgb 16 ]  
          } 
          scale 5            
          type 1
        }  
      }      
         
    } 
    
    
#declare P_Warped_2=  
    pigment {       
      P_Base_1                       
                            
      warp {
        displace {  
          spiral1 7 
          color_map {
            [0.0 color rgb -10 ] 
            [1.0 color rgb 16 ]  
          } 
          scale 5            
          type 1
        }  
      }   
          
      warp {
        displace {  
          spiral1 7
          color_map {
            [0.0 color rgb 16 ] 
            [1.0 color rgb -10 ]  
          } 
          scale 5            
          type 1
        }  
      }      
         
    }  
    
    
#declare P_Warped_3=  
    pigment {       
      P_Base_1                        
                            
      warp {
        displace {  
          spiral1 7 
          triangle_wave
          color_map {
            [0.0 color rgb -10 ] 
            [1.0 color rgb 16 ]  
          }   
          rotate 180*x
          scale 6           
          type 1
        }  
      }   
          
      warp {
        displace {  
          spiral1 7
          color_map {
            [0.0 color rgb 16 ] 
            [1.0 color rgb -10 ]  
          } 
          scale 5            
          type 1
        }  
      }
           
         
    }             
                  
     
        
     
#declare P_Warped_4=  
    pigment {  
      P_Base_1               
      
      scale 0.6
                            
      warp {
        displace {  
          spiral2 5 
          color_map {
            [0.0 color rgb -1 ] 
            [1.0 color rgb 16 ]  
          }    
          scale 5            
          type 1
        }  
      }   
      
      warp {
        displace {  
          spiral2 5  
          color_map {
            [0.0 color rgb -1 ] 
            [1.0 color rgb 16 ]  
          } 
          scale 5            
          type 1
        }  
      } 
      
      scale 1/0.6     
         
    } 

// End POV-Code

-- 
Christoph Hormann <chr### [at] gmxde>
IsoWood include, radiosity tutorial, TransSkin and other 
things on: http://www.schunter.etc.tu-bs.de/~chris/

Post a reply to this message