// Persistence of Vision Ray Tracer Scene Description File
// File: sfshield.pov
// Vers: 3.1
// Desc: A shot at the Star Fleet Shield
// Date: 14 Nov '00
// Last: 15 Nov '00
// Auth: Dawn McKnight
//
// You need Chris Colefax's "Galaxy.inc" package to render this scene as
I've written it.
// It's available at http://www.geocities.com/ccolefax/
// If you don't have it, and don't wish to use it, comment out all the
includes except 
// colors and metals.
//

#include "colors.inc"
#include "metals.inc"
#declare star_color_turb = 1
#declare star_brightness_turb = 1
#include "galaxy.sf"
#declare galaxy_object_name = "Nebula3" 
#declare galaxy_cluster_name = "Star4" 
#include "GALAXY.OBJ" 
#declare galaxy_object_name = "Comet2" 
#declare galaxy_cluster_name = "" 
#include "GALAXY.OBJ" 


light_source { <0, 300, 0> White }

camera {
	location <-3, 20, 0>
	look_at <-3, 0, 0>
	}
	

#declare BaseSFShield = // the familiar delta shield
prism {
  linear_sweep 
  cubic_spline 
  -0.5,        // height 1
   0.5,        // height 2
  10,          // number of points
	<-4, 4>, // control point 1
	<5, 0>, // this is the point that has to match
	<-0.6, -3>,
	<-8, -4.9>,
	<-9.8, -4.8>,
	<-5, -1>,
	<-11, 5>,
	<-4, 4>,
	<5, 0>, // matched.
	<-0.6, -3> // control point 2
   sturm
   scale 0.9*z
	} // close prism

#local BSFS1 = // The beginning of doing the fancy badge.  Identical
shape as above, but conic_sweep
prism {
  conic_sweep // or conic_sweep for tapering to a point
  cubic_spline // linear_spline | quadratic_spline | cubic_spline
  0,        // height 1
  1,        // height 2
  10,          // number of points
  // the <u,v> points
	<-4, 4>, // control point 1
	<5, 0>, // this is the point that has to match
	<-0.6, -3>,
	<-8, -4.9>,
	<-9.8, -4.8>,
	<-5, -1>,
	<-11, 5>,
	<-4, 4>,
	<5, 0>, // matched.
	<-0.6, -3> // control point 2
   sturm
   scale 0.9*z
	} // close prism BSFS1

#local BSFS2 = // this one is mirrored by z, so that when it's rotated
for the effect of the conic
				// sweep, it'll end up with the same outline as the first one.
prism {
  conic_sweep // or conic_sweep for tapering to a point
  cubic_spline // linear_spline | quadratic_spline | cubic_spline
  0,        // height 1
  1,        // height 2
  10,          // number of points
  // the <u,v> points
	<-4, -4>, // control point 1
	<5, 0>, // this is the point that has to match
	<-0.6, 3>,
	<-8, 4.9>,
	<-9.8, 4.8>,
	<-5, 1>,
	<-11, -5>,
	<-4, -4>,
	<5, 0>
	<-0.6, 3> // control point 2
   sturm
   scale 0.9*z
	} // close prism BSFS2

#local BSFS3 = merge {
	object { BaseSFShield translate 1.49999*y }
	object { BSFS1 }
	} // close merge BSFS3

#local FancySFS = 
difference {
	object { BSFS2 rotate 180*x translate 1*y }
	object { BSFS3 translate -0.75*y }
	}//close difference FancySFS

#local FBP = // fancy base plate... or half of it, anyway.
prism {
  linear_sweep 
  linear_spline 
  0,        // height 1
  -1,        // height 2
  5,          // number of points
  // the <u,v> points
  <4.5, 0.25>, <-13, 0.25>, <-11, 4>, <2.5, 4>, <4.5, 0.25>
} // close prism FBP

#declare ComBadge = union {
	object { FancySFS texture { T_Silver_3C } }

	difference {

		object { FBP texture { T_Gold_3A } }
		object { 
			FBP 
			scale <0.95, 0.95, 0.93> 
			texture { pigment { color NavyBlue } finish { F_MetalC } } 
			translate <-0.2, 0.1, 0.15>
			} // close object FBP

		} // close difference

	difference {
		object { FBP rotate 180*x scale 0.95*x translate <.5, -1, 0> texture {
T_Gold_3A } }
		object { 
			FBP 
			rotate 180*x 
			scale 0.95*x 
			translate <.5, -1, 0> 
			texture { pigment { color NavyBlue } finish { F_MetalC } }  
			scale <0.95, 0.95, 0.93> 	
			translate <-0.2, 0.1, -0.15>	
			} // close object FBP
		} // close difference

	} // close union ComBadge 

object { ComBadge }

-- 
Dawn McKnight      | "Who cares what the hipbone's connected to? I'm in Neurology!"
McK### [at] maccom   |					-- Justine Devlin, M.D.

Post a reply to this message