Image posted 29. October to povray.binaries.images:

news://news.povray.org/39F9EFE2.77F7FD7A%40online.no


To Mick Hazelgrove:

I'm looking forward to see your architectural fantasy !


Regards,

Tor Olav


// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7
// Copyright 2000 by Tor Olav Kristensen
// mailto:tor### [at] hotmailcom
// http://www.crosswinds.net/~tok/tokrays.html
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7

#version unofficial MegaPov 0.5;

#include "colors.inc"

global_settings { ambient_light color White }

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7

$ AgateFunction =
function { pigment { agate color_map { [ 0 rgb 0 ] [ 1 rgb 1 ] } } }

$ SphereFunction = function { sqrt(x^2 + y^2 + z^2) }

$ ManyCylinders =
function {
  SphereFunction(
    x - floor(x) - 0.5,
    0,
    z - floor(z) - 0.5
  )
}

$ MidOfAgateSquare =
function {
  AgateFunction(
    3*floor(x),
    3*(y + 0.3*noise3d(5*x, 5*y, 5*z)),
    3*floor(z)
  )
}

isosurface {
  function {
    - 0.30
    + ManyCylinders(x, y, z)
    - 0.05*MidOfAgateSquare(x, y, z)
    + y*(0.04 + 0.04*noise3d(4*x + 3, 0, 4*z))
    + 5.00/(y^2 + 1.00)
    + noise3d(x/10, y/10, z/10)
  }
  contained_by { sphere { <0, 0, 0>, 200 } }
  method 2
  pigment { color White + Blue }
  no_shadow
}

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7

light_source {
  80*< -3,  1, -1>
  color White
}

camera {
  location < 3.038, -6.7, -5.002>
  look_at < 2.530,  -6.7,  1.540>
//  angle 120
}

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7

Post a reply to this message