// Radiosity test file #2
// Gilles Tran - august 2000
#version unofficial Megapov 0.5;
#include "colors.inc"
global_settings{
        ini_option "+QR"
        radiosity{recursion_limit 5 brightness 1.2 normal on}
}
camera
{
  location  <0.0, 6, -21.0>
  direction 1*z
  right     4/3*x
  look_at   <0, 1.0,  2>
}

#declare Bleu=rgb<55,105,201>/255;
#declare Jaune=rgb<243,199,107>/255;
sky_sphere{
  pigment{
        gradient y
        color_map{
                [0 White]
                [1 Bleu]
        }
  }
}


#declare PdV=<-1,0.5,-0.5>*1000 ;
light_source{PdV color Jaune fade_power 2 fade_distance 2000
area_light 100*x 100*z  5,5 jitter orient
}
#declare txt1=texture{
        pigment{crackle solid color_map{[0 color White*0.7][1 color
White*1.3]}}
        normal{agate 0.4}
        finish{ambient -0.3 diffuse 0.8 specular 0.1 roughness 0.1
metallic brilliance 1}
        scale 0.3
}

#declare rd=seed(3);
#declare dis=35;
union{
        #declare i=1;
        #while (i<100)
                #declare j=0.5-rand(rd);
                #declare k=0.5-rand(rd);
                #declare l=0.5-rand(rd);
                #declare m=0.5-rand(rd);
                #declare n=1+rand(rd);
                union{
                        sphere{0,1}
                        cylinder{0,y*15,0.5}
                        sphere{0,2 scale <1,0.1,1> translate y*6}
                        sphere{0,1.5 scale <1,0.2,1> translate y*15}
                        scale n*0.3
                        translate <j,0,k>*dis
                }
                union{
                        cylinder{0,y*(k+0.5)*10,1}
                        torus{0.8,0.2  translate y*(k+0.5)*10}
                        superellipsoid{<0.2,0.2> scale 0.7 translate
y*(k+0.5)*10}
                        scale n*0.3
                        translate <l,0,m>*dis
                }
                #declare i=i+1;

        #end
        texture{txt1}
}

box{<-100,-1,-200>,<100,0,50> texture{txt1}}

Post a reply to this message

Gilles Tran <tra### [at] inapginrafr> wrote:
:         radiosity{recursion_limit 5 brightness 1.2 normal on}

  Deducing from my own tests, using a brightness other than 1 gives usually
unrealistic (but perhaps artistic) results.
  Perhaps you should try playing with diffuse values instead (if I remember
correctly that's what tells the amount of light reflected from a surface in
megapov).

  Is there some way of specifying a general diffuse value, just like the
general ambient_light value in global_settings?

-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):_;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

Warp wrote:
> 
> Gilles Tran <tra### [at] inapginrafr> wrote:
> :         radiosity{recursion_limit 5 brightness 1.2 normal on}
> 
>   Deducing from my own tests, using a brightness other than 1 gives usually
> unrealistic (but perhaps artistic) results.
>   Perhaps you should try playing with diffuse values instead (if I remember
> correctly that's what tells the amount of light reflected from a surface in
> megapov).
> 
>   Is there some way of specifying a general diffuse value, just like the
> general ambient_light value in global_settings?
> 
#default{
  finish { diffuse 0.7 }
}

	You can put anything texture-related in the default block
an it will be used unless you override it in the object's
texture.

		Jerome
-- 

* Doctor Jekyll had something * mailto:ber### [at] inamecom
* to Hyde...                  * http://www.enst.fr/~jberger
*******************************

Post a reply to this message

Jerome M. Berger <ber### [at] inamecom> wrote:
: #default{
:   finish { diffuse 0.7 }
: }

  Does it work if I specify a finish (which hasn't a diffuse) in the object?

-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):_;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

Warp wrote:
> 
> Jerome M. Berger <ber### [at] inamecom> wrote:
> : #default{
> :   finish { diffuse 0.7 }
> : }
> 
>   Does it work if I specify a finish (which hasn't a diffuse) in the object?
> 
	Yes, as long as you don't define a diffuse it should work.


-- 

* Doctor Jekyll had something * mailto:ber### [at] inamecom
* to Hyde...                  * http://www.enst.fr/~jberger
*******************************

Post a reply to this message