//Ok. Psycomek here it is. Regards, Alberto.

#version unofficial MegaPov 0.5;

#declare wineflag = on;
#declare photflag = on;

global_settings{max_trace_level 40 adc_bailout .01	}

#if(photflag)
global_settings {
	photons {
		count 1e3 //6.3e6
		max_trace_level 40
		adc_bailout .01
	}
}
#end

camera{location <0,80,-100> look_at 11*y angle 17}

light_source{500*<2,5,-5> rgb 1
spotlight falloff .3  radius 0 tightness 1 point_at 8*y
	#if(photflag)
		photons {
			reflection on
			refraction on
		}
	#end
}

sky_sphere{pigment{rgb .7*<1,.5,0>}}

disc{-.01*y y 100
	pigment{
		crackle form <1,1,-1>
		color_map{[0 rgb<1,.5,0>][1 rgb.7*<1,.5,0>]}
		scale 6 rotate 30*y
	}
}

#declare wglass = lathe{bezier_spline 52
	<0, 1.> <1., 1.> <5.8, 0> <6., 0> 
	<6., 0> <6.2, 0> <6.2, 0.2> <6., 0.2> 
	<6., 0.2> <5.8915, 0.2> <4.3695, 0.6699> <3., 1.1> 
	<3., 1.1> <1.8458, 1.4624> <0.8, 1.7713> <0.8, 2.> 
	<0.8, 2.> <0.8, 2.4> <0.8, 7.3> <0.8, 7.4> 
	<0.8, 7.4> <0.8, 7.6> <1., 8.> <1.4, 8.> 
	<1.4, 8.> <1.5, 8.> <1.9, 8.> <2., 8.> 
	<2., 8.> <6., 8.> <9.8, 12.4> <8., 16.> 
	<8., 16.> <7.9, 16.2> <5.1, 21.8> <5., 22.> 
	<5., 22.> <5., 22.> <4.9, 22.> <4.9, 22.> 
	<4.9, 22.> <5., 21.8> <7.8, 16.2> <7.9, 16.> 
	<7.9, 16.> <9.7, 12.4> <5.9, 8.1> <2., 8.1> 
	<2., 8.1> <1.9, 8.1> <0, 8.1> <0, 8.1> 
}

object{wglass
	finish {diffuse .6  ambient 0
		phong .1  phong_size 40 reflection .0175
		specular 1 roughness .0002
	}
	pigment{rgbf<1,1,1,.98>}
	interior{ior 1.5}
	#if(photflag)
		photons {
			target 1
			reflection on
			refraction on
			ignore_photons
		}
	#end
}

#if(wineflag)

#declare wine = lathe{bezier_spline 16
	<0, 11.9> <0, 11.9> <7.7, 11.9> <7.7, 11.9> 
	<7.7, 11.9> <7.8, 11.9> <7.8, 11.9> <7.8906, 12.> 
	<7.8906, 12.> <6.8968, 9.8226> <4.4684, 8.1> <2., 8.1> 
	<2., 8.1> <1.9, 8.1> <0, 8.1> <0, 8.1> 
	translate -8.1*y  scale .98  translate 8.11*y
}


object{wine hollow
	pigment{rgbft <1,1,1,1,.04>}
	finish{ambient 0 diffuse 0
	specular .7 roughness .001 reflection .01}
	interior{ior 1.3 caustics 1
		media{absorption rgb <.4,1,1>}
	}
	#if(photflag)
		photons {
			target 1
			reflection on
			refraction on
			ignore_photons
		}
	#end
}
#end //wineflag

Post a reply to this message