// Persistence of Vision Ray Tracer Scene Description File
// File: tornado.pov
// Vers: unofficial MegaPov 0.4
// Desc: tornado-like object, dust-devil
// Date: 00.3
// Auth: Bob Hughes
// Mail: inv### [at] aolcom?Subject=Pov-Scene
// Note: although this uses media method 2 it can use official POV-Ray media

#version unofficial MegaPov 0.4; // 3.1;

global_settings {
        max_trace_level 7
}

light_source {<10,50,-100>, 1.5}

camera {
  location  <0,5,-50>
  angle 45
  look_at   <0, 15, 0>
}

sky_sphere {
    pigment { gradient y
    color_map { [0 color rgb<.7,.8,1>] [1 color rgb<.3,.6,.9>] }
  }
    pigment { granite
 color_map {
 [0.2,0.5 color rgbt<.93,.92,.94,0> color rgbt<1,1,1,1>]
 [0.6,1.0 color rgbt<1,1,1,1> color rgbt<.9,.92,.94,0>]
  } scale <2,.66,2>
  }
}

plane {y,0 pigment {rgb<.9,.8,.6>}}

union { // simple funnel shape
cone {-y,3,y*30,6}
torus {6,3 scale <1,1.5,1> translate 4.5*y}
 hollow
  texture {
   pigment { rgbf 1 }
    finish { ambient 0 diffuse 0 }
  }
   interior {
        media { // the plume and spin
                method 2 // comment out if using only v3.1
                intervals 3 // increase if using method 1 or v3.1
                samples 1,1
                absorption <.15,.2,.3>
                scattering {3,<.2,.175,.125>}
                density {spiral1 3 turbulence .3
                        density_map {
                                [0 rgb 0]
                                [.5 rgb .1]
                                [1 rgb .4]
                                } rotate 60*x} scale <3,5,3>
                }
        media { // the core
                method 2 // comment out if using only v3.1
                intervals 3 // increase if using method 1 or v3.1
                samples 1,1
                absorption <.15,.2,.3>
                scattering {2,<.4,.3,.25>}
                density {cylindrical turbulence .15
                        density_map {
                                [0 rgb 0]
                                [.67 rgb .2]
                                [1 rgb .6]
                                }} scale <12,1,12>
                }}
}

// omniVerse http://users.aol.com/persistenceofv/all.htm

Post a reply to this message