For the "rust and sky" scene recently posted in binaries.images.


/*
    By popular request, my "Rust and Sky" scene, with
    the extraneous bits (like radiosity settings and
    stuff that was commented out) removed. This scene
    requires the Megapatch, but only for the "reset
    children" warp in the rusted iron texture; if
    you're not using that texture, you could just as
    easily remove it and use the official compile.
    
    The rusted iron texture needs work, but I never
    got around to fixing it; specifically, any iron
    that badly weathered will look kind of brownish to
    start with, and so it would be better to mix the
    rust with a "weathered iron" texture of some sort.
    I leave it as an exercise for the reader.
*/

#version unofficial MegaPov 0.4;

// GLOBALS
global_settings
	{
	assumed_gamma 1.8
	}
	
// CAMERA 1
camera
	{
	location <0, 3, -7>
	look_at <0, 2, 0>
	}
	
// LIGHT
light_source
	{
	<-3, 10, -4>
	rgb 1
	fade_power 2
	fade_distance 10
	}
	
// LIGHT
light_source
	{
	<1, 1, -4>
	rgb .5
	fade_power 2
	fade_distance 10
	}
	
// RUST
#declare rust = texture
	{
	pigment
		{
		granite
		color_map 
			{
			[ 0.0 rgb <0.809995, 0.299123, 0.113405>*.8 ]
			[ 0.4 rgb <0.209995, 0.096941, 0.031510>*1.2 ]
			[ 0.6 rgb <0.209995, 0.096941, 0.031510>*1.2 ]
			[ 1.0 rgb <0.569986, 0.052720, 0.005707>*.9 ]
			}
		scale .5
		turbulence 1
		}
	normal { wrinkles }
	}
	
// IRON
#declare iron = texture
	{
	pigment { color rgb .25 }
	normal { granite .3  scale .2 }
	finish { roughness .01 specular .5 reflection .05 diffuse .8 }
	}
	
// RUSTY IRON
#declare rusty_iron = texture
	{
	bozo
	texture_map
		{
		[ 0.0 rust ]
		[ 1.0 iron ]
		}
	turbulence 1
	omega .3
	lambda 4
	warp { reset_children }
	}
	
// STEEL
#declare steel = texture
	{
	pigment { color rgb .5 }
	normal { wrinkles .02 scale .1 }
	finish
		{
		roughness .001
		specular 1
		diffuse .2
		reflection .5
		}
	}
	
// RUSTY STEEL
#declare rusty_steel = texture
	{
	bozo
	texture_map
		{
		[ 0.0 rust ]
		[ 0.2 rust ]
		[ 0.5 iron ]
		[ 0.6 steel ]
		[ 1.0 steel ]
		}
	turbulence 1
	omega .6
	lambda 4
	warp { reset_children }
	}
	
// SPHERE
sphere
	{
	<0, 2, 0>, 2
	texture { rusty_steel }
	}
	
// PLANE
plane
	{
	y,0
	pigment { color rgb <.5, .4, .3> }
	}
	
cylinder 
	{
	<2.5, -10, -3>, <2.5, 10, -3>, .7
	texture { rusty_iron }
	}
	
light_source
	{
	<0, 517440000000, 0>
	rgb <1, 1, 1>*1
	media_attenuation
	rotate <0, 0, 0>
	}
	
sphere
	{
	<0.0, -21120000, 0.0>, 21151680
	hollow
	pigment { color rgbt <1,1,1,1> }
	interior
		{
		media
			{
			emission rgb <.1, .3, 1>*.000003
			scattering { 4, rgb <.1, .3, 1>*.000002 extinction 0 }
			method 3
			}
		}
	}
	
// HAZE
sphere
	{
	<0.0, -21120000, 0.0>, 21122000
	hollow
	pigment { color rgbt <1,1,1,1> }
	interior
		{
		media
			{
			scattering { 3,	rgb <.2, .1, .3>*.0001 extinction 1 }
			scattering { 1,	rgb <.5, .5, .5>*.0001 extinction 1 }
			absorption rgb <1, 1, .1>*.000003
			method 3
			}
		}
	}

Post a reply to this message