This is the source for Bug.jpg in p.b.i
I needed a quick meal for my pet spider, larder was empty, so came up with this. Wings
were responsible for most of the 20 minuits or so it took.

Seasons Greetings from Alf

http://www.peake42.freeserve.co.uk
http://ourworld.compuserve.com/homepages/Alf_Peake/

//  File start
//  Makes a Fly or Bug, around 4*2 excluding wings,
//  on z-plane, with head towards +x.

#version 3.1;
global_settings { assumed_gamma 1 }
#include "colors.inc"
camera{ location -20*z angle 28 }
light_source{ <50,50,-200> color White }
background{ SkyBlue }  // Will influence wing colour
plane{ z, 1.5 pigment{ checker rgb 0.3, rgb 0.5 } hollow }

#local BodyT =
texture{ pigment{ gradient x
                  colour_map{ [0.81 rgb 0.05 ]
                              [0.85 rgb <0.2,0.1,0.1> ] }
                  scale 0.4 }
         finish{ phong 0.3 phong_size 10 ambient 0.25 }
         normal{ bumps 2 scale <0.02,1,1> }
         translate x
       }

#local PairLeg =
difference{ box{ <-0.03,-1,-1>,<0.03,1,1> }
            box{ -1, 1 scale 0.95 }
            rotate x*45
            scale <1,1,0.5>
          }

#local Wing =
disc{ -2*x, z, 2
      pigment{ rgbf <0.75,0.8,1,0.95> }
      finish{ phong 0.6 phong_size 80 diffuse 0.5 reflection 0.15
              irid{ 0.35 thickness 0.35 turbulence .25 } }
      normal{ crackle 0.6 scale 0.3 }
      scale <1,0.3,1>
      hollow
    }

#declare Bug =
union{
   object{ Wing rotate <15,0,-35> translate <0.95,0.2,-0.55> }
   object{ Wing rotate <-15,0,35> translate <0.95,-0.2,-0.55> }
   object{ Wing scale 1.3 rotate <10,0,-60> translate <0.95,0.2,-0.55> }
   object{ Wing scale 1.3 rotate <-10,0,90> translate <0.94,-0.2,-0.53> }
   // Abdomen, head, head, antennae. Wot? No thorax?
   union{ sphere{ 0,1 scale <1.5,1,0.7> }
          sphere{ 0,0.7 translate x*1.5 }
          sphere{ 0,0.4 scale <1,0.4,1> translate x*2 }
          cylinder{ <2.3,0,-0.25>, <2.7, 0.3,-0.4>, 0.03 }
          cylinder{ <2.3,0,-0.25>, <2.7,-0.3,-0.4>, 0.03 }
          texture{ BodyT }
         }
   union{ object{ PairLeg }
          object{ PairLeg rotate z*40 }
          object{ PairLeg rotate -z*40 }
          texture{ BodyT }
          translate <1,0,1>
         }
   union{ sphere{ 0,0.4 translate <2,-0.2,0> }  // Eyes
          sphere{ 0,0.4 translate <2, 0.2,0> }
          pigment{ Black }
          finish{ phong 0.75 phong_size 24 }
        }
}

object{ Bug rotate z*42 }

// Alf### [at] compuservecom
// alf### [at] peake42freeservecouk
// eof

Post a reply to this message