Hi

Several people have asked for the grass texture in Mountain Valley, so here
it is.

#declare Base_Tex =
texture {
  pigment {
    granite
    turbulence 3
    color_map {
      [0.000 color rgb <0.5, 0.5, 0.2>]
      [0.25 color rgb <0.7, 1, 0.2>]
      [0.5 color rgb <1, 0.4, 0.2>]
      [0.75 color rgb <.5, 0.9, 0.2>]
      [1 color rgb <0.3, 0.9, 0.2>]
    }
    scale 0.035
  }
  finish{specular .25 }
          normal{
            average normal_map{
                [0.0 bumps 150 scale 30]
                [0.2 dents 50 scale 12.5 turbulence .3]
                [0.6 bump_map{ gif "GBM4.gif" bump_size 50} rotate x*90
rotate y*45 scale 30 ]
                [1.0 wrinkles 25 scale 5 scallop_wave rotate z*30]
                }//end of normal map
                rotate z*15 turbulence .4
              }//end of normal dec
}

Post a reply to this message

Attachments:
Download 'GBM4.gif' (62 KB)

Preview of image 'GBM4.gif'

Hi, 

I just read this and liked your rendering very much. What I like best about 
it though is your sky & clouds. Any chance you'd be willing to share your 
cloud code with the rest of the world? 

Thanks/Greetings
--> R

Mick Hazelgrove wrote:
> Hi
> 
> Several people have asked for the grass texture in Mountain Valley, so
> here it is.
> 
> #declare Base_Tex =
> texture {
>   pigment {
>     granite
>     turbulence 3
>     color_map {
>       [0.000 color rgb <0.5, 0.5, 0.2>]
>       [0.25 color rgb <0.7, 1, 0.2>]
>       [0.5 color rgb <1, 0.4, 0.2>]
>       [0.75 color rgb <.5, 0.9, 0.2>]
>       [1 color rgb <0.3, 0.9, 0.2>]
>     }
>     scale 0.035
>   }
>   finish{specular .25 }
>           normal{
>             average normal_map{
>                 [0.0 bumps 150 scale 30]
>                 [0.2 dents 50 scale 12.5 turbulence .3]
>                 [0.6 bump_map{ gif "GBM4.gif" bump_size 50} rotate x*90
> rotate y*45 scale 30 ]
>                 [1.0 wrinkles 25 scale 5 scallop_wave rotate z*30]
>                 }//end of normal map
>                 rotate z*15 turbulence .4
>               }//end of normal dec
> }

Post a reply to this message

Hi

Gosh That's and old picture!

I use Jaimes layered planes method or media for clouds:

here's the plane method

#declare Cheight=2800;
#declare Bdist=30;
#declare Tdist=30;
#declare Nboxes=30;
#declare Count=1;

#while (Count<=Nboxes)

#declare CldtopCol = color rgbt<1,1,.9,.1>;
#declare BaseCol = color rgbt<.75,.6,.98,.125>*1.5;

#declare FBaseCol=BaseCol*(1-(Count/Nboxes))+CldtopCol*(Count/Nboxes);

 box{<-100000,-0.0000001,-100000><10,0.0,100000>
  texture{
   pigment{
    spotted
    octaves 9
    lambda 2.3
    omega 0.575
    turbulence 3
    color_map{
     [0.0 rgbt 1]
     [0.5 rgbt 1]
     [1.0 FBaseCol filter .75*(Count/Nboxes)]

    }
   scale 10000/2
   scale <1.5,1,1>
   }
   translate <0,(Cheight+Tdist*Count),0>
  }
  translate <-2000,(Cheight+Bdist*Count),0>

  finish{ambient .45+(1.25*((Count/Nboxes)/1.875)) specular 1}
  rotate y*90
  rotate x*2.5
  hollow
 }
 #declare Count=Count+1;
#end

Here's an example of media clouds developed from code by Kevin Ellis:

#declare Rad = 2500000 / (2 * pi);
difference {
  sphere { 0,Rad}
  sphere {0,Rad-15000}
  material{
    texture{
      pigment{ rgbf 1}
    }
    interior{
      media{
        scattering {2,<.01,.012,.01>/2.75 extinction 1/2.75 }
        method 3
        samples 15,15
        intervals 1

         density { //one
          wrinkles
          ramp_wave
          color_map {
            [0 rgb 0]
            [0.4 rgb 0]
            [0.6 rgb 0.275]
            [1 rgb 0.475]
          }//colmap
          scale <10000,5000,9000>/1.5
          rotate y*25
         translate <1000,Rad-30000,0>
        }//density

        density {//2
          marble
          triangle_wave
          turbulence 1.5
          color_map {
            [0 rgb 0]
            [0.3 rgb 0] //was 3
            [0.75 rgb 0.25] //0.2
            [1 rgb 0.5]   //0.4
          }//colmap
          scale <10000,5000,7500>*10  //10
          rotate y*-25
         translate <0,Rad-30000,0>
        }//density

      }//media
    }//interior
  }//material
  hollow
  rotate y*70
  rotate z*15
  translate <0,32000-Rad,0>
}//difference


Mick

Post a reply to this message