|
 |
Here's the source for the image I posted in pbi on th 16th. Actually I
improved a little on it (it had been thrown together in half an hour
after all), you can see the result of this one at:
http://www.enst.fr/~jberger/images.html
>------------------------- begin code -------------------
#include "colors.inc"
global_settings { max_trace_level 100 }
background { color red 0.025 green 0.025 blue 0.025 }
#declare CameraPos = <6, 5, -10>*0.6 ;
camera {
location CameraPos
look_at y
angle 40
}
#declare LightPos = <-50, 80, -100> ;
light_source {
LightPos
color White
}
cylinder {
-y, 0, 5
pigment {
checker
pigment { color Gray90 }
pigment { color Gray70 }
}
bounded_by { sphere { CameraPos, 0.01 } }
}
box {
<-1, 0, -1>, <1, 2, 1>
pigment { color rgbf 1 }
finish { reflection 1 }
}
box {
<-1.01, -0.01, -1.01>, <1.01, 2.01, 1.01>
pigment { color rgbf 0.7 }
bounded_by { sphere { LightPos, 0.01 } }
}
sphere {
y, 0.2
pigment { color Green }
finish { specular 0.8 ambient 0.3 }
}
union {
cylinder { <-1, 0, -1>, <1, 0, -1>, 0.05 }
cylinder { <1, 0, -1>, <1, 0, 1>, 0.05 }
cylinder { <1, 0, 1>, <-1, 0, 1>, 0.05 }
cylinder { <-1, 0, 1>, <-1, 0, -1>, 0.05 }
cylinder { <-1, 2, -1>, <1, 2, -1>, 0.05 }
cylinder { <1, 2, -1>, <1, 2, 1>, 0.05 }
cylinder { <1, 2, 1>, <-1, 2, 1>, 0.05 }
cylinder { <-1, 2, 1>, <-1, 2, -1>, 0.05 }
cylinder { <-1, 0, -1>, <-1, 2, -1>, 0.05 }
cylinder { <1, 0, -1>, <1, 2, -1>, 0.05 }
cylinder { <1, 0, 1>, <1, 2, 1>, 0.05 }
cylinder { <-1, 0, 1>, <-1, 2, 1>, 0.05 }
sphere { <-1, 0, -1>, 0.05 }
sphere { <1, 0, -1>, 0.05 }
sphere { <-1, 0, 1>, 0.05 }
sphere { <1, 0, 1>, 0.05 }
sphere { <-1, 2, -1>, 0.05 }
sphere { <1, 2, -1>, 0.05 }
sphere { <-1, 2, 1>, 0.05 }
sphere { <1, 2, 1>, 0.05 }
pigment { color (Red+White)/2 }
}
>------------------------- end code -------------------
Enjoy,
Jerome
--
*******************************
* they'll tell you what can't * mailto:ber### [at] iname com
* be done and why... * http://www.enst.fr/~jberger
* Then do it. *
*******************************
Post a reply to this message
|
|
